批处理之家 - Powered by Discuz! Board

标题: [注册表类] [已解决]有没什么批处理变量能set获得所在计算机SID？ [打印本页]

作者: 1139054012 时间: 2015-2-28 18:14 标题: [已解决]有没什么批处理变量能set获得所在计算机SID？

本帖最后由 1139054012 于 2015-3-1 13:15 编辑

请各位指导

作者: pcl_test 时间: 2015-2-28 19:06

回复 1# 1139054012
没懂你什么意思
批处理获取SID的两种方法

@echo off
for /f "tokens=*" %%a in ('REG QUERY "HKEY_USERS" /s /v USERNAME ^| find /i "Volatile Environment"') do (
    for /f "tokens=*" %%1 in ('REG QUERY "%%a" /v USERNAME ^| find /i "%username%"') do (
    SET "SID=%%a"
    )
)
for /f "tokens=1-4,* delims=\" %%i in ('echo %SID%') do (
SET "SID=%%j"
)
echo %SID%
pause
复制代码

@echo off
for /f "delims=" %%a in ('wmic userAccount where "Name='%userName%'" get SID /value') do call set %%a >nul
echo %sid%
pause
复制代码

作者: 1139054012 时间: 2015-2-28 19:40

本帖最后由 1139054012 于 2015-2-28 20:15 编辑

回复 2# pcl_test

谢谢，正需要这代码。
但是导出时SID后面多出个空格

HKEY_USERS\【SID】  \Software
复制代码

请问怎么办才能导出时没有空格

HKEY_USERS\【SID】 \Software
复制代码

这样呢

作者: pcl_test 时间: 2015-2-28 20:43

回复 3# 1139054012
你是怎么输出的？把完整代码发下，一般末尾有空格的话可以使用截取，如

for /f "delims=" %%a in ('wmic userAccount where "Name='%userName%'" get SID /value') do call set %%a >nul
>1.txt echo %sid:~0,-1%
复制代码

作者: Batcher 时间: 2015-3-1 09:48

@echo off
set "rpath=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"
for /f "delims=" %%a in ('reg query "%rpath%" ^| findstr "S-1-5-21-"') do (
    reg query "%%a" /v ProfileImagePath | findstr "%username%" >nul 2>&1 && set RegPath=%%a
)
set SID=%RegPath:*ProfileList\=%
echo,%SID%
pause
复制代码

@echo off
for /f "delims=" %%i in ('reg query "HKEY_USERS" /s /v USERNAME ^| find /i "Volatile Environment"') do (
    for /f "tokens=*" %%j in ('reg query "%%i" /v USERNAME ^| find /i "%username%"') do (
        set "SID=%%i"
    )
)
for /f "tokens=2 delims=\" %%i in ("%SID%") do (
    set "SID=%%i"
)
echo,%SID%
pause
复制代码

作者: 1139054012 时间: 2015-3-1 13:17

回复 4# pcl_test

谢谢了，问题已自行解决。已经好了。第二个会输出时默认SID后面会添加空格，第一个就没有了。

欢迎光临批处理之家 (http://bbs.bathome.net/)