批处理之家 - Powered by Discuz! Board

标题: [日期时间] 批处理删除指定天数日期之前的文件夹（2023-10-08） [打印本页]

作者: Batcher 时间: 2009-2-27 22:06 标题: 批处理删除指定天数日期之前的文件夹（2023-10-08）

【方案一】BAT + PowerShell

1-1-以文件夹的修改日期为准.bat

@echo off
REM ----------------------------------------------------------------------------------------
REM 如果显示的待删除文件夹列表正确无误
REM 把 Select-Object FullName 修改成 Remove-Item -Force -Recurse 再次执行即可真正删除文件夹
REM Win7/Win10/Win11等系统自带PowerShell
REM ----------------------------------------------------------------------------------------

REM 指定待删除文件夹所在的路径
set "SrcDir=E:\Test"
REM 指定天数
set "DaysAgo=7"

powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.LastWriteTime)).days -gt %DaysAgo% -and $_.PsISContainer -eq $True)} | Select-Object FullName"
复制代码

1-2-以文件夹的创建日期为准.bat

@echo off
REM ----------------------------------------------------------------------------------------
REM 如果显示的待删除文件夹列表正确无误
REM 把 Select-Object FullName 修改成 Remove-Item -Force -Recurse 再次执行即可真正删除文件夹
REM Win7/Win10/Win11等系统自带PowerShell
REM ----------------------------------------------------------------------------------------

REM 指定待删除文件夹所在的路径
set "SrcDir=E:\Test"
REM 指定天数
set "DaysAgo=7"

powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.CreationTime)).days -gt %DaysAgo% -and $_.PsISContainer -eq $True)} | Select-Object FullName"
复制代码

【方案二】以文件夹的修改日期为准 forfiles

@echo off
REM ------------------------------------------------------------------------------
REM 演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件夹。
REM 如果演示结果无误，把rd前面的echo去掉，即可实现真正删除。
REM Win7/Win10/Win11等系统自带forfiles命令
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=7"

forfiles /p "%SrcDir%" /m * /d -%DaysAgo% /c "cmd /c if @isdir==TRUE (echo rd /s /q @path)"
pause
复制代码

【方案三】BAT + REG + VBS

@echo off
REM ----------------------------------------------------------------------------------------
REM 演示：删除指定路径下指定天数之前（以文件夹的最后修改日期为准）的文件夹。
REM 如果演示结果无误，把rd前面的echo去掉，即可实现真正删除。
REM 本例调用了临时VBS代码进行日期计算
REM 本例为兼容不同的日期格式，调用reg命令统一设置日期格式，
REM 处理完毕之后再把日期格式恢复成原来的状态。
REM ----------------------------------------------------------------------------------------

REM 指定待删除文件夹的存放路径
set "SrcDir=E:\Test"
REM 指定天数
set "DaysAgo=7"

for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
    set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /d %%a in ("%SrcDir%\*.*") do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a\" (
            echo rd /s /q "%%a"
        )
    )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
复制代码

【方案四】BAT + REG + Ritchie Lawrence 日期函数

@echo off
REM ----------------------------------------------------------------------------------------
REM 演示：删除指定路径下指定天数之前（以文件夹的最后修改日期为准）的文件夹。
REM 如果演示结果无误，把rd前面的echo去掉，即可实现真正删除。
REM 本例调用了 Ritchie Lawrence 的日期函数进行日期计算
REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
REM 本例为兼容不同的日期格式，调用reg命令统一设置日期格式，
REM 处理完毕之后再把日期格式恢复成原来的状态。
REM ----------------------------------------------------------------------------------------

REM 指定待删除文件夹的存放路径
set "SrcDir=E:\Test"
REM 指定天数
set "DaysAgo=7"

for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set "RegDateOld=%RegDateOld:~-8%"
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set "DstDate=%DstYear%%DstMonth%%DstDay%"
set "DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%"
for /d %%a in ("%SrcDir%\*.*") do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a\" (
            echo rd /s /q "%%a"
        )
    )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

【方案五】BAT + VBS

@echo off
REM ----------------------------------------------------------------------------------------
REM 演示：删除指定路径下指定天数之前（以文件夹的最后修改日期为准）的文件夹。
REM 如果演示结果无误，把rd前面的echo去掉，即可实现真正删除。
REM 本例调用了临时VBS代码进行日期计算，并统一设置系统日期格式，处理完毕
REM 之后再把日期格式恢复成原来的状态。摆脱了对reg命令的依赖。
REM ----------------------------------------------------------------------------------------

REM 指定待删除文件夹的存放路径
set "SrcDir=E:\Test"
REM 指定天数
set "DaysAgo=7"

>"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
    set "RegDateOld=%%a"
)
>"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
cscript /nologo "%temp%\UnifyDate.vbs"
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
    set "DstDate=%%a"
)
set "DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%"
for /d %%a in ("%SrcDir%\*.*") do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a\" (
            echo rd /s /q "%%a"
        )
    )
)
>"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
cscript /nologo "%temp%\RecoverDate.vbs"
pause
复制代码

【方案六】字符串截取

根据日期出现在文件夹名称中的具体位置，调整第24行字符串截取。
具体语法请参考参考set命令教程第8页
http://bbs.bathome.net/thread-31727-1-1.html

@echo off
REM ----------------------------------------------------------------------------------------
REM 演示：删除指定路径下指定天数之前（以文件夹名中包含的日期字符串为准）的文件夹。
REM 如果演示结果无误，把rd前面的echo去掉，即可实现真正删除。
REM 本例假设文件夹名中包含的日期字符串（比如：Archive-2009-12-25）
REM ----------------------------------------------------------------------------------------

REM 指定待删除文件夹的存放路径
set "SrcDir=E:\Test"
REM 指定天数
set "DaysAgo=7"

>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  set "DstDate=%%a"
)
set "DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%"

setlocal enabledelayedexpansion
for /d %%a in ("%SrcDir%\*.*") do (
    set "FolderDate=%%~na"
    set "FolderDate=!FolderDate:~8,10!"
    if "!FolderDate!" leq "%DstDate%" (
        if exist "%%a\" (
            echo rd /s /q "%%a"
        )
    )
)
endlocal
pause
复制代码

作者: defanive 时间: 2009-2-27 22:23

还是VBS方便吧，用那个VBS外部命令。。。

作者: Batcher 时间: 2009-2-27 22:27 标题: 回复 2楼的帖子

萝卜青菜，各有所爱^_^

作者: Batcher 时间: 2009-5-13 16:54 标题: 回复 4楼的帖子

“取不到时间的阴气的”是什么意思？

不要双击运行
把代码保存为C:\test.bat
把@echo off删除
在合适的地方加上pause
开始
运行
cmd
C:\test.bat
看看执行过程是哪一步出错了？

作者: Batcher 时间: 2009-5-14 12:25 标题: 回复 10楼的帖子

2003系统中的reg命令返回值和XP的略有不同，我马上去修改一下顶楼的代码。

顶楼代码已更新，把skip=4改成skip=3即可。请重新测试。

作者: Batcher 时间: 2009-5-14 15:42 标题: 回复 12楼的帖子

能看看执行过程吗？像7楼那种

作者: Batcher 时间: 2009-5-18 16:31 标题: 回复 14楼的帖子

感谢测试，顶楼代码已再次更新。

作者: Batcher 时间: 2009-5-21 13:04 标题: 回复 16楼的帖子

1、请把@echo off删除，贴出完整过程。
2、我的代码用的是for /d，你的测试结果是for /r，你确定自己测试是顶楼的代码？

作者: Batcher 时间: 2009-5-21 19:49 标题: 回复 18楼的帖子

1、请你回头看看7楼你贴的内容到底是for /r还是for /d
2、17楼是希望你能够删除@echo off，贴出完整执行过程，你是不是贴错了？

作者: thth 时间: 2009-6-3 10:51 标题: 回复 15楼的帖子

楼主你好，刚刚在自动删除文件上得到可用的代码，非常感谢！
不过自动删除文件夹上，这3个方案在xp系统下cmd下运行时都是：
命令语法不正确
不知道什么原因！

作者: Batcher 时间: 2009-6-3 10:52 标题: 回复 20楼的帖子

请参考5楼

作者: thth 时间: 2009-6-3 11:00 标题: 回复 21楼的帖子

楼主，我把运行的结果拷贝贴图如下：

作者: clonecd 时间: 2012-5-20 13:07

这个也需要慢慢学习一下。

作者: 一坑坑兔一 时间: 2012-11-22 16:09

回复 22# thth

你和我运行的结果一样，不知道为为什么```希望楼主给我们解答一下```

作者: 一坑坑兔一 时间: 2012-11-22 16:20

回复 21# Batcher

我和22楼运行的结果一样，貌似是缺个“（”吧？希望楼主帮个忙`

作者: Batcher 时间: 2012-11-22 16:31

回复 25# 一坑坑兔一

第几行少了括号？

作者: xksu 时间: 2013-1-11 16:28

我这边XP测试可以用

但是放在windows2008 64位上就不行了

'cscript' is not recognized as an internal or external command, operable program or batch file

这是为什么阿，刚开始接触这个，还不懂，请指教

作者: xksu 时间: 2013-1-11 17:14

我这边XP测试可以用

但是放在windows2008 64位上就不行了

'cscript' is not recognized as an intern ...
xksu 发表于 2013-1-11 16:28

嘎嘎，可以了，

for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
set "DstDate=%%a"
)

在cscript前加上路径： C：\windows\system32\

作者: lovehome 时间: 2013-1-14 10:07

如果是w2k3的系统，可以直接用forfiles命令来查找指定日期的文件，然后再删除，
如：
forfiles /P "D:\root" /s /d -7 /c "cmd /C echo y|del /f @path"

作者: Batcher 时间: 2013-1-14 10:42

回复 29# lovehome

顶楼讨论的是删文件夹，不是文件

作者: manwxm 时间: 2013-2-18 14:21

我用第三个，win7系统下，也是不行啊，求指导
D:\test>批删文件夹.bat

D:\test>rem 指定待删除文件夹的存放路径

D:\test>set SrcDir=D:\test

D:\test>rem 指定天数

D:\test>set DaysAgo=1

D:\test>echo Set WshShell = WScript.CreateObject("WScript.Shell") 1>"C:\Users\ADMINI~1\AppData\Local\Temp\BackupDate.vbs"

D:\test>echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate") 1>>"C:\Users\ADMINI~1\AppData\Local\Temp\BackupDate.vbs"

D:\test>for /F %a in ('cscript /nologo "C:\Users\ADMINI~1\AppData\Local\Temp\BackupDate.vbs"') do (set "RegDateOld=%a" )

D:\test>(set "RegDateOld=yyyy-M-d" )

D:\test>echo Set WshShell = WScript.CreateObject("WScript.Shell") 1>"C:\Users\ADMINI~1\AppData\Local\Temp\UnifyDate.vbs"

D:\test>echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ" 1>>"C:\Users\ADMINI~1\AppData\Local\Temp\UnifyDate.vbs"

D:\test>cscript /nologo "C:\Users\ADMINI~1\AppData\Local\Temp\UnifyDate.vbs"

D:\test>echo LastDate=date()-1 1>"C:\Users\ADMINI~1\AppData\Local\Temp\DstDate.vbs"

D:\test>echo FmtDate=right(year(LastDate),4) & right("0" & month(LastDate),2) & right("0" & day(LastDate),2) 1>>"C:\Users\ADMINI~1\AppData\Local\Temp\DstDate.vbs"

D:\test>echo wscript.echo FmtDate 1>>"C:\Users\ADMINI~1\AppData\Local\Temp\DstDate.vbs"

D:\test>for /F %a in ('cscript /nologo "C:\Users\ADMINI~1\AppData\Local\Temp\DstDate.vbs"') do (set "DstDate=%a" )

D:\test>(set "DstDate=20130217" )

D:\test>set DstDate=2013-02-17
命令语法不正确。
D:\test> if exist "%a\"
D:\test>

作者: manwxm 时间: 2013-2-18 15:24

搞定了。。 if exist "%%a\"
这个后面少了个 (

作者: yhcfsr 时间: 2017-11-28 02:49

本帖最后由 yhcfsr 于 2017-11-28 03:48 编辑

以前用过forfliles，又学习了

作者: wangxiaohe 时间: 2020-11-13 11:35

这个厉害了，终于找到删除文件夹的了。

作者: cctvhbo 时间: 2023-10-8 17:08

这个BAT不错

欢迎光临批处理之家 (http://bbs.bathome.net/)