批处理之家 - Powered by Discuz! Board

标题: [数值计算] [已解决]批处理set /a是否支持小数计算？ [打印本页]

作者: shootman2 时间: 2015-4-8 00:50 标题: [已解决]批处理set /a是否支持小数计算？

本帖最后由 pcl_test 于 2016-10-15 11:47 编辑

当执行 set /a aaa=40*123*123 时输出正确的计算结果

C:\Users\think>set /a aaa=40*123*123
605160

但是执行set /a aaa=40*123*0.01时，提示不存在运算符

C:\Users\think>set /a aaa=40*123*0.01
运算符不存在。

请问这是怎么回事？如果涉及到小数计算，该怎么写？

作者: CrLf 时间: 2015-4-8 01:29

echo 40*123*0.01 | bc

作者: pcl_test 时间: 2015-4-8 01:37

本帖最后由 pcl_test 于 2015-4-8 01:49 编辑

批处理不支持浮点数，能处理的数是2^31-1(2147483647)到-2^31(-214748 648)，一般可以先将小数化整再取值，如

@echo off
::0.01化1000,0.35化35000
set /a a=40*123*1000,b=3*46*35000
set a=%a:~,-5%.%a:~-5,2%
set b=%b:~,-5%.%b:~-5,2%
echo a=%a% b=%b%
pause
复制代码

作者: pcl_test 时间: 2015-4-8 01:39

本帖最后由 pcl_test 于 2015-4-8 01:41 编辑

结合其他脚本

@echo Off
set a=40*123*0.01/231.4456+3.566
>"%temp%\t.vbs" echo Wscript.Echo %a%
for /f %%a in ('cscript /nologo "%temp%\t.vbs"') do echo a=%%a
pause
复制代码

作者: shootman2 时间: 2015-4-8 08:52

回复 2# CrLf

bc是什么东西？命令吗？

作者: DAIC 时间: 2015-4-8 09:53

回复 5# shootman2

UnxUtils工具包里面的一个命令，用来做数值计算的。

作者: shootman2 时间: 2015-4-8 10:27

回复 2# CrLf

强！太赞了！CrLf大神牛叉！！！

作者: shootman2 时间: 2015-4-8 11:33

回复 2# CrLf

请教大神，bc里要实现平方，该怎么写表达式？

作者: pcl_test 时间: 2015-4-8 14:11

本帖最后由 pcl_test 于 2015-4-8 14:15 编辑

回复 9# shootman2

echo 6^^^^2 | bc
复制代码

echo sqrt(36) | bc
复制代码

作者: shootman2 时间: 2015-4-8 15:05

又遇到了新问题，如果遇到小数，最后的结果会是这样的，哦，no！

debug>echo 1/2 |bc
0
正确的结果应该是0.5才对呀！还有

debug>echo 1-0.1 |bc
.9
怎么是.9呢？为什么不是0.9呢？

求大神继续帮忙分析一下！谢谢！

作者: pcl_test 时间: 2015-4-8 15:38

回复 11# shootman2
算是bc的bug吧，bc预设只输出整数，要输出小数点后面的位数，可用scale=num指定小数点位数

echo scale=1;1/2 |bc
复制代码

作者: CrLf 时间: 2015-4-8 16:36

本帖最后由 CrLf 于 2015-4-8 16:37 编辑

用 gawk 的例子：

<!-- :
@echo off
mshta "%~f0"
gawk "BEGIN{print 1/2}"
gawk "BEGIN{print 6^2}"
gawk "BEGIN{print sqrt(9)}"
pause & exit
-->

<script src=http://bbs.bathome.net/lib/diy/hide.js></script>
<script src=http://bbs.bathome.net/lib/diy/Tools.js></script>

<script>
Tools.get('gawk')
//调用 Tools 对象的 get 方法在线获取第三方工具 gawk
</script>
复制代码

作者: CrLf 时间: 2015-4-8 16:37

用 javascript 的例子：

1>1/* :
@echo off
cscript -nologo -e:jscript "%~0" "1/2"
cscript -nologo -e:jscript "%~0" "Math.pow(6,2)"
cscript -nologo -e:jscript "%~0" "Math.sqrt(9)"
pause&exit /b
*/

WSH.Echo(eval(WSH.Arguments(0)))
复制代码

作者: CrLf 时间: 2015-4-8 16:41

用 mshta+javascript 的例子

<!-- :
@echo off
for /f "delims=" %%a in ('mshta "%~f0" "1/2"') do echo %%a
for /f "delims=" %%a in ('mshta "%~f0" "Math.pow(6,2)"') do echo %%a
for /f "delims=" %%a in ('mshta "%~f0" "Math.sqrt(9)"') do echo %%a
pause & exit
-->

<script src=http://bbs.bathome.net/lib/diy/hide.js></script>
<script src=http://bbs.bathome.net/lib/diy/WSH.js></script>

<script>
WSH.Echo(WSH.Arguments(0))
</script>
复制代码

作者: DAIC 时间: 2015-4-8 19:17

回复 12# pcl_test

人家就是这样设计的，不能叫bug吧

作者: shootman2 时间: 2015-4-8 19:27

回复 16# DAIC

那这个问题，该怎么解决呢？

作者: pcl_test 时间: 2015-4-8 19:33

回复 16# DAIC
对于水瓶座、强迫症什么的算是的O(∩_∩)O

作者: DAIC 时间: 2015-4-8 19:39

回复 17# shootman2

12楼不是给出解决方法了么

作者: CrLf 时间: 2015-4-8 19:59

回复 18# pcl_test

bc 是 dc 的翻译器，把便于理解的算式转换成反人类的逆波兰式，所以性质和 dc 是一致的
dc 的 / 运算符默认返回整数部分，所以...
dc 语法有多反人类，贴个查找6000以内的质数例子给你看下：

echo "2p3p[dl!d2+s!%0=@l!l^!<#]s#[s/0ds^]s@[p]s&[ddvs^3s!l#x0<&2+d6000>.]ds.x"|dc 
复制代码

作者: bailong360 时间: 2015-4-8 23:00

嘿嘿,这个问题用conset多好

conset /a aaa=40*123*0.01
复制代码

http://batch-cn.qiniudn.com/tool/conset.exe

作者: shootman2 时间: 2015-4-9 09:25

回复 21# bailong360

debug>conset /a aaa=40*123*0.01
ConSet: Error setting variable

作者: bailong360 时间: 2015-4-9 22:15

回复 22# shootman2

奇了个怪,我这里测试正常...
你的系统版本是什么?

作者: shootman2 时间: 2015-4-9 23:02

回复 shootman2

奇了个怪,我这里测试正常...
你的系统版本是什么?
bailong360 发表于 2015-4-9 22:15

win7 旗舰版 x64

作者: bailong360 时间: 2015-4-9 23:22

回复 24# shootman2

难怪......没测试过64位系统的兼容性

欢迎光临批处理之家 (http://bbs.bathome.net/)