批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】批处理如何在变量中引用变量？ [打印本页]

作者: sophiawang 时间: 2015-7-24 12:10 标题: 【已解决】批处理如何在变量中引用变量？

本帖最后由 sophiawang 于 2015-7-27 15:11 编辑

echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=;" %%i in (test.txt) do ( 
if "%%i"=="AppNumber" set APPNum=%%j && set num=1
if "%%i"=="APPName" set "APP!num!=%%j" && set /a num+=1     //set "APP!num!=%%j"  这个赋值对么？
echo APP!num!
echo !APP!num!!  // 怎么引用才对  目的显示 CNTNG150603151
)
pause
复制代码

test.txt的内容如下：
AppNumber;3
[APP1]
APPName;CNTNG150603151
[/APP1]
[APP2]
APPName;CNTNG150603152
[/APP2]
[APP3]
APPName;GDUMS150316353
[/APP3]

执行的结果：
E:\form>echo off
APP1
num
APP1
num
APP2
num
APP2
num
APP2
num
APP3
num
APP3
num
APP3
num
APP4
num
APP4
num
请按任意键继续. . .

作者: pcl_test 时间: 2015-7-24 12:38

本版规则
1、求助时，务必在顶楼一次性把问题交代清楚，建议给出完整有针对性的样本，样本过大可发网盘分享链接。勿发无意义的标题
2、使用 code 标记把代码部分括起来（单击回复框的 <> 按钮，复制粘贴代码进去），以便复制。问题解决后，请编辑顶楼帖子在标题前面注明[已解决]

作者: pcl_test 时间: 2015-7-24 12:45

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=;" %%i in (test.txt) do ( 
    if "%%i"=="AppNumber" set APPNum=%%j&set num=1
    if "%%i"=="APPName" (
        set "APP!num!=%%j"
        echo APP!num!
        for %%a in (!num!) do echo !APP%%a!
        ::另一种，call echo %%APP!num!%%
        set /a num+=1
    )
)
pause
复制代码

作者: sophiawang 时间: 2015-7-24 13:35

回复 2# pcl_test

OK，谢谢

作者: sophiawang 时间: 2015-7-24 13:50

pcl_test 发表于 2015-7-24 12:45

太厉害了，拜谢

:kiss: :kiss: :kiss:
有时间加为朋友聊聊呗

作者: flyinnet9 时间: 2015-7-24 16:05

本帖最后由 flyinnet9 于 2015-7-24 16:08 编辑

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=;" %%i in (test.txt) do ( 
if "%%i"=="AppNumber" set APPNum=%%j && set num=1
if "%%i"=="APPName" echo APP!num!=%%j>>%temp%\tmp && set /a num+=1
)
for /f "tokens=2 delims==" %%a in (%temp%\tmp) do echo %%a
del %temp%\tmp
复制代码

作者: sophiawang 时间: 2015-7-27 15:10

flyinnet9 发表于 2015-7-24 16:05

谢谢，都是高手

欢迎光临批处理之家 (http://bbs.bathome.net/)