批处理之家 - Powered by Discuz! Board

标题: [日期时间] 求助！批处理自动下载FTP远程目录文件目录为变量问题 [打印本页]

作者: zseed 时间: 2015-7-30 11:10 标题: 求助！批处理自动下载FTP远程目录文件目录为变量问题

关于自动下载FTP远程目录文件目录为变量问题。需要从远程目录子目录自动下载txt文件，但该目录的子目录1文件夹下每天以时间自动更新一个以时间命名的文件夹，例如当前时间为20150730，远程目录每天里会更新一个前天日期的文件夹，如20150729的文件夹，我需要从昨天的目录里自动下载txt文件。请问怎么写！

@echo off 

echo open 192.168.2.86>c:\ftp.txt
echo admin>>c:\ftp.txt
echo 123>>c:\ftp.txt
echo cd /1>>c:\ftp.txt
echo lcd D:\yzykt>>c:\ftp.txt
echo bin>>c:\ftp.txt
echo mget *.txt>>c:\ftp.txt
echo -----正在下载，请稍后...
echo quit>>c:\ftp.txt
Start ftp -v -i -s:"c:\ftp.txt"
复制代码

作者: DAIC 时间: 2015-7-30 11:13

打开CMD窗口，执行命令：
echo %date%

结果发出来看看

作者: zseed 时间: 2015-7-30 11:29

回复 2# DAIC

显示日期和星期

作者: zseed 时间: 2015-7-30 11:31

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1-3 delims=-:/ " %%a in ("%date%") do (set Y=%%a&set M=%%b&set D=%%c&if "!M:~0,1!"=="0" set M=!M:~1!
if "!D:~0,1!"=="0" set D=!D:~1!)
set/a D-=1&if !D! leq 0 (set/a M-=1&if !M!==0 set/a Y-=1,M=12
set/a "T=^!(M-2)","R=(^!(Y%%4)&^!^!(Y%%100))|^!(Y%%400)","C=^!(M-4)|^!(M-6)|^!(M-9)|^!(M-11)","D=T*(28+R)+C*30+(^!T&^!C)*31"+D)
set M=0%M%&set D=0%D%
set mydate=%Y%%M:~-2%%D:~-2%
echo %mydate%
pause

作者: zseed 时间: 2015-7-30 11:32

怎么写呢~远程目录是每天按日更新的~是变动的

作者: DAIC 时间: 2015-7-30 11:36

回复 3# zseed

结果发出来看看

作者: zseed 时间: 2015-7-30 15:05

回复 6# DAIC

作者: DAIC 时间: 2015-7-30 21:23

回复 7# zseed

@echo off
for /f %%i in ('PowerShell -Command "&{Get-Date (Get-Date).AddDays(-1) -uformat "%%Y%%m%%d"}"') do (
    set DstDate=%%i
)

>c:\ftp.txt  echo open 192.168.2.86
>>c:\ftp.txt echo admin
>>c:\ftp.txt echo 123
>>c:\ftp.txt echo cd %DstDate%
>>c:\ftp.txt echo lcd D:\yzykt
>>c:\ftp.txt echo bin
>>c:\ftp.txt echo mget *.txt
>>c:\ftp.txt echo quit

start ftp -v -i -s:"c:\ftp.txt"
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)