Board logo

标题: [日期时间] [已解决]批处理跨年份日期问题？ [打印本页]
作者: cbnuisve    时间: 2015-8-9 10:33     标题: [已解决]批处理跨年份日期问题？

本帖最后由 cbnuisve 于 2015-8-11 10:38 编辑

在跨年份的时间得出的结果会出错。
  1. @echo off

  2. setlocal enabledelayedexpansion

  3.  set DaysAgo=7

  4.  call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays

  5.  set /a PassDays-=%DaysAgo%

  6.  call :DaysToDate %PassDays% DstYear DstMonth DstDay

  7. 

  8.  set "yyyy=%DATE:~0,4%" 

  9. echo %yyyy%%DstMonth%%DstDay%\

  10. 

  11. 

  12.  :DateToDays %yy% %mm% %dd% days

  13.  setlocal ENABLEEXTENSIONS

  14.  set yy=%1&set mm=%2&set dd=%3

  15.  if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)

  16.  set /a dd=100%dd%%%100,mm=100%mm%%%100

  17.  set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

  18.  set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

  19.  endlocal&set %4=%j%&goto :EOF

  20. 

  21.  :DaysToDate %days% yy mm dd

  22.  setlocal ENABLEEXTENSIONS

  23.  set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

  24.  set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

  25.  set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

  26.  (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)

  27.  endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码
作者: Batcher    时间: 2015-8-10 11:25

请举例说明你的测试数据是什么，希望得到的结果是什么，实际得到的结果是什么？
作者: cbnuisve    时间: 2015-8-10 16:24

回复 2# Batcher


    假设把当前日期修改为2016年1月1日 ，计算出的当前日期七天前的日期是20161225 （echo %yyyy%%DstMonth%%DstDay%\）面不是20151225
作者: flyinnet9    时间: 2015-8-10 18:04

本帖最后由 flyinnet9 于 2015-8-12 09:54 编辑

改了以前写的程序，想前几天应该都可以（28天？？），测试后结果说一下
闰年判断有误，已改正
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. set daysago=7

  4. set year=%date:~0,4%

  5. set month=%date:~5,2%

  6. set day=%date:~8,2%

  7. if %day% gtr %daysago% goto normal

  8. if %month%==03 goto february

  9. if %month%==01 goto aty

  10. for %%i in (05 07 10 12) do if %month%==%%i goto abortion

  11. for %%i in (02 04 06 08 09 11 ) do if %month%==%%i goto monthly

  12. 

  13. :abortion

  14. set /a day=30+!day!

  15. if %month:~0,1%==0 set /a month=%month:~1%

  16. set /a month=!month!-1

  17. if !month! lss 10 set month=0!month!

  18. goto normal

  19. 

  20. :monthly

  21. set /a day=31+!day!

  22. if %month:~0,1%==0 set /a month=%month:~1%

  23. set /a month=!month!-1

  24. if !month! lss 10 set month=0!month!

  25. goto normal

  26. 

  27. :february

  28. set month=02

  29. if %year:~2,4%==00 (set /a yy=%year%%%400) else (set /a yy=%year%%%4)

  30. if %yy%==0 (set /a day=29+!day!) else (set /a day=28+!day!)

  31. goto normal

  32. 

  33. :aty

  34. set /a day=31+!day!

  35. set month=12

  36. set /a year=%year%-1

  37. goto normal

  38. 

  39. :normal

  40. set /a Yourday=!year!!month!!day!-%daysago%

  41. echo Today is %date:~0,4%%date:~5,2%%date:~8,2%

  42. echo Yourday is %Yourday%

  43. pause
复制代码
作者: DAIC    时间: 2015-8-10 20:08

怀疑是你的系统里面%date%格式有问题导致%date:~0,4% %date:~5,2% %date:~8,2%没有取到正确的值，把@echo off删掉重新执行一遍，完整的执行过程发出来看看。
作者: 回家路上    时间: 2015-8-11 08:01     标题: 标题

回复 1# cbnuisve
http://www.bathome.net/viewthread.php?tid=17079&highlight=%C7%B0%D2%BB%CC%EC
作者: cbnuisve    时间: 2015-8-11 09:20

本帖最后由 cbnuisve 于 2015-8-11 09:46 编辑

回复 4# flyinnet9
非常感谢你。你这批处理解决了我之前哪跨年的问题，但是又有个新问题，当日期是2016年3月1日时，获取前七天的日期会是20160251而不是正确的 20160223
作者: cbnuisve    时间: 2015-8-11 09:24

回复 5# DAIC 
  1. C:\Users\user\Desktop>setlocal enabledelayedexpansion

  2. 

  3. C:\Users\user\Desktop>set DaysAgo=7

  4. 

  5. C:\Users\user\Desktop>call :DateToDays 2016 01 01 PassDays

  6. 

  7. C:\Users\user\Desktop>setlocal ENABLEEXTENSIONS

  8. 

  9. C:\Users\user\Desktop>set yy=2016  & set mm=01  & set dd=01

  10. 

  11. C:\Users\user\Desktop>if 12016 LSS 200 if 12016 LSS 170 (set yy=202016 )  else (set yy=192016 )

  12. 

  13. C:\Users\user\Desktop>set /a dd=10001%100,mm=10001%100

  14. 

  15. C:\Users\user\Desktop>set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

  16. 

  17. C:\Users\user\Desktop>set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

  18. 

  19. C:\Users\user\Desktop>endlocal & set PassDays=16801  & goto :EOF

  20. 

  21. C:\Users\user\Desktop>set /a PassDays-=7

  22. 

  23. C:\Users\user\Desktop>call :DaysToDate 16794 DstYear DstMonth DstDay

  24. 

  25. C:\Users\user\Desktop>setlocal ENABLEEXTENSIONS

  26. 

  27. C:\Users\user\Desktop>set /a a=16794+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

  28. 

  29. C:\Users\user\Desktop>set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

  30. 

  31. C:\Users\user\Desktop>set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

  32. 

  33. C:\Users\user\Desktop>(if 12 LSS 10 set mm=012 )  & (if 25 LSS 10 set dd=025 )

  34. 

  35. C:\Users\user\Desktop>endlocal & set DstYear=2015  & set DstMonth=12  & set DstDay=25  & goto :EOF

  36. 

  37. C:\Users\user\Desktop>set "yyyy=2016"

  38. 

  39. C:\Users\user\Desktop>echo 20161225\

  40. 20161225\

  41. 

  42. C:\Users\user\Desktop>pause
复制代码
作者: cbnuisve    时间: 2015-8-11 09:42

本帖最后由 cbnuisve 于 2015-8-11 10:11 编辑

回复 6# 回家路上
谢谢，看了好久还是没看明白。能否解释一下它是怎么运行的吗？如果我要获取七天前的日期要怎么做修改呢？
  1. @echo off & setlocal enabledelayedexpansion

  2. 

  3. call :yesterday yesterday

  4. echo %yesterday%

  5. 

  6. 

  7. 

  8. :yesterday

  9. for /f "tokens=2*" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate^|find/i"sSh"') do (

  10.   >nul reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /d "yyyyMMdd" /f

  11.   set /a "y=!date:~0,4!,m=1!date:~4,2!-100,d=1!date:~-2!-101"

  12.   setlocal disabledelayedexpansion

  13.   set /a "m-=!d,y-=!m,d+=!d*(31-(!(m-4)|!(m-6)|!(m-9)|!(m-11))-!(m-2)*(3-(!(y%%4)&!!(y%%100)|!(y%%400)))),m+=!m*12"

  14.   set /a "m+=100,d+=100"

  15.   >nul reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /d "%%~b" /f

  16. )

  17. endlocal & set "%1=%y%%m:~-2%%d:~-2%" & exit /b
复制代码
作者: DAIC    时间: 2015-8-11 10:29

回复 8# cbnuisve


从第35行可以看到函数正确计算出了年月日 set DstYear=2015  & set DstMonth=12  & set DstDay=25
顶楼的代码错误在第9行 echo %yyyy%%DstMonth%%DstDay% 你不应该手工设置这个 yyyy
应该使用 echo %DstYear%%DstMonth%%DstDay%
作者: cbnuisve    时间: 2015-8-11 10:37

本帖最后由 cbnuisve 于 2015-8-11 10:42 编辑

回复 10# DAIC

谢谢，终于解决这问题了。
作者: 回家路上    时间: 2015-8-11 13:00

本帖最后由 回家路上 于 2015-8-11 13:33 编辑

改了一些，前N天的（还不能超过一个月）。
  1. @echo off

  2. :: 前n天

  3. set pre=3

  4. ::今天

  5. set td=%date%

  6. ::如果今天是2016-03-01

  7. set td=2016-03-01

  8. echo;%td%

  9. echo;==========================

  10. set /a "y=%td:~0,4%,m=1%td:~5,2%-100,d=1%td:~8,2%-100-%pre%"

  11. echo;%y%

  12. echo;%m%

  13. echo;%d%

  14. ::这之前就是能把 y m d 各种截取得正确，就ok了

  15. echo;==========================

  16. set /a "m-=!(%d:~1%+%d%),y-=!m,d+=!(%d:~1%+%d%)*(31-(!(m-4)|!(m-6)|!(m-9)|!(m-11))-!(m-2)*(3-(!(y%%4)&!!(y%%100)|!(y%%400)))),m+=!m*12"

  17. echo;%y%

  18. echo;%m%

  19. echo;%d%

  20. pause & exit /b
复制代码
超过一个月的话，你可以试试搞一下。O(∩_∩)O~


论坛里也有其他计算时间的地儿，可以看一下
http://bbs.bathome.net/viewthrea ... e%3D1&frombbs=1
作者: cbnuisve    时间: 2015-8-11 13:34

回复 12# 回家路上


    谢谢你，我的问题已经解决了。



欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2