批处理之家 - Powered by Discuz! Board

标题: [数值计算] [已解决]批处理如何将连续的数字按指定格式进行合并，不连续的数字保持原样？ [打印本页]

作者: chouxia 时间: 2015-9-19 14:57 标题: [已解决]批处理如何将连续的数字按指定格式进行合并，不连续的数字保持原样？

本帖最后由 pcl_test 于 2016-7-6 18:10 编辑

变量现在的值为s=101,102,339,340,341,342,343,592,593,594,595
现在想把值换改成如下形式s=101-102,339-343,592-595
代码中应该如何实现？
我一点思路都没有

作者: 尘丶 时间: 2015-9-19 15:05

本帖最后由尘丶于 2015-9-19 15:54 编辑

好了你再自己修改下就可以了

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
set n=1
for %%a in (%s%) do (
	if !n!==1 (
	   set k=%%a&set /a n+=1
	) else (
	     if %%a==!j! (
	        set k=!k!-%%a
	     ) else (
	        set k=!k!,%%a
	     )
	)
	set /a j=%%a+1
)
for %%a in (!k!) do (
set l=%%a
set /p=!l:~,4!!l:~-3!,<nul
)
pause
复制代码

作者: 回家路上 时间: 2015-9-19 15:22

然而并不知道你每两个数字的对应关系是什么

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (%s%) do (
	set /a n+=1,m=n%%2
	if !m!==0 (set sp=-)else set sp=,
	set re=!re!!sp!%%i
)
set s=%re:~1%
echo;%s%
pause
复制代码

作者: chouxia 时间: 2015-9-19 15:31

本帖最后由 chouxia 于 2015-9-19 15:33 编辑

回复 3# 回家路上

说白了变量s被逗号隔开的数字。相邻的几个数字为连续值的时候取第一个数字和最后一个数字，中间用减号隔开，
举例中输出结果应该是101-102,339-343,592-595
101,102,连续数字，所以改为101-102
339,340,341,342,343,连续数字，改为339-343
592,593,594,595 连续数字，改为592-595
所以
s的值最终为：101-102,339-343,592-595

作者: 回家路上 时间: 2015-9-19 16:20

本帖最后由回家路上于 2015-9-19 16:39 编辑

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (%s%) do (
	if not defined end (
		set begin=%%i& set end=%%i
	) else (
		set /a flag=%%i-end-1
		if not !flag!==0 (
			set t=!t!,!begin!-!end!
			set begin=%%i& set end=%%i
		)else set end=%%i
	)
)
set t=%t%,%begin%-%end%
set s=%t:~1%

echo;%s%
pause
复制代码

再改一下O(∩_∩)O！

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (%s%,shenmegui) do (
	if not defined end (
		set s=& set begin=%%i& set end=%%i
	) else (
		set /a flag=%%i-end-1
		if not !flag!==0 (
			if defined s (
				set s=!s!,!begin!-!end!
			)else set s=!begin!-!end!
			set begin=%%i& set end=%%i
		)else set end=%%i
	)
)
echo;%s%
pause & exit /b
复制代码

作者: WHY 时间: 2015-9-19 21:15

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (1a %s% a) do (
    set /a "1/(%%i-a-1)" && set "str=!str!!a!,%%i-"
    set "a=%%i"
)2>nul
echo;!str:~3,-3!
pause
复制代码

作者: chouxia 时间: 2016-7-6 17:06

本帖最后由 pcl_test 于 2016-7-6 17:59 编辑

回复 6# WHY

当s等于如下值的时候str没有输出值（这个s的值有可能是任意数字）
set s=2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20
这代码没看懂，哪位能帮忙改一下？
哪位又可以帮忙指教一下？
拜谢拜谢！

作者: 回家路上 时间: 2016-7-6 22:47

只是赶巧了，如果你的s不是2开头，而是：

set s=3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20
复制代码

就能正确显示，原因？你猜O(∩_∩)O！

作者: 回家路上 时间: 2016-7-6 23:06

没看出前面的1a有什么特殊意义

C:>set b=1a

C:>set /a "2-b-1"
0
复制代码

删了吧

for %%i in (%s% a) do (
... ...
echo;!str:~1,-3!
复制代码

作者: chouxia 时间: 2016-7-7 08:11

回复 9# 回家路上

大哥，这段代码我是真不懂，能解释下吗？

欢迎光临批处理之家 (http://bbs.bathome.net/)