批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理如何将多个txt文本的内容打乱排序/随机排序 [打印本页]

作者: lyfwcn 时间: 2015-11-25 17:38 标题: 批处理如何将多个txt文本的内容打乱排序/随机排序

本帖最后由 pcl_test 于 2017-3-25 08:04 编辑

单个文本打乱排序我知道

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%i in (a.txt) do echo !random!!random!!random! %%i)>"%temp%\$"
sort /o "%temp%\#" "%temp%\$"
(for /f "usebackqtokens=1*" %%i in ("%temp%\#") do echo %%j)>b.txt
del "%temp%\#" "%temp%\$"
pause
复制代码

如何把本文件夹或名称叫abababa文件夹里的多个文本打乱排序啊？

作者: DAIC 时间: 2015-11-25 18:00

本帖最后由 DAIC 于 2015-11-25 18:07 编辑

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    (for /f "delims=" %%i in ('type "%%a"') do echo !random!!random!!random! %%i)>"%temp%\x"
    sort /o "%temp%\y" "%temp%\x"
    (for /f "tokens=1*" %%i in ('type "%temp%\y"') do echo,%%j)>"%temp%\z"
    move /y "%temp%\z" "%%a"
)
del /f /q "%temp%\y" "%temp%\x"
复制代码

作者: lyfwcn 时间: 2015-11-25 18:06

回复 2# DAIC
显示

系统找不到文件 'type "1.txt" .
系统找不到文件 'type "2.txt" .
系统找不到文件 'type "3.txt" .

作者: DAIC 时间: 2015-11-25 18:08

回复 3# lyfwcn

已更新，你再试试。

作者: lyfwcn 时间: 2015-11-25 18:11

谢谢DAIC，非常谢谢。

欢迎光临批处理之家 (http://bbs.bathome.net/)