批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】批处理逐行合并多个文件对于没有的行如何以空格占位？ [打印本页]

作者: 思想之翼 时间: 2015-12-13 20:16 标题: 【已解决】批处理逐行合并多个文件对于没有的行如何以空格占位？

本帖最后由思想之翼于 2015-12-14 16:56 编辑

@echo off
set filenum=3
for /l %%x in (10001,1,10001) do (
    set y=%%x
    setlocal enabledelayedexpansion
    for /l %%a in (1,1,%filenum%) do (
        for /f "delims=" %%i in (D:\数据\横并\!y:~1!\%%a.txt) do (
            set /a n+=1
            for %%a in (!n!) do set "#%%a=!#%%a! %%i"
        )
        set /a m=n,n=0
    )
    (for /l %%a in (1,1,!m!) do echo,!#%%a:~1!)>D:\数据\横并\!y:~1!.txt
    endlocal
)
复制代码

如果
D:\数据\横并\0001\1.txt有数据
1
1

D:\数据\横并\0001\2.txt有数据
2

D:\数据\横并\0001\3.txt有数据
3
3
3
3
那么上述代码将1.txt 2.txt 3.txt合并为
1 2 3
1 3
3
3

欲1.txt 2.txt 3.txt合并为
1 2 3
1 3
3
3
上述代码如何修改？

作者: WHY 时间: 2015-12-14 15:10

本帖最后由 WHY 于 2015-12-14 15:19 编辑

@echo off
set filenum=3
for /l %%x in (10001,1,10001) do (
    set /a y=%%x, max=0
    setlocal enabledelayedexpansion
    for /l %%a in (1,1,%filenum%) do (
        set n=0
        for /f "delims=" %%i in (D:\数据\横并\!y:~1!\%%a.txt) do (
            set /a n+=1
            set "%%a_!n!=%%i"
        )
        if !n! gtr !max! set max=!n!
    )

    (for /l %%a in (1 1 !max!) do (
        set "s="
        for /l %%b in (1 1 !filenum!) do set "s=!s!	!%%b_%%a!"
        echo;!s:~1!
    ))>D:\数据\横并\!y:~1!.txt
    endlocal
)
pause
复制代码

作者: codegay 时间: 2015-12-15 09:18

本帖最后由 pcl_test 于 2015-12-15 09:34 编辑

python 3个文件合并成3列
http://www.bathome.net/thread-38608-1-1.html

作者: WHY 时间: 2015-12-15 21:34

本帖最后由 WHY 于 2015-12-15 21:43 编辑

paste.exe
http://batch-cn.qiniudn.com/tool/2.1/paste.exe

@echo off & setlocal enabledelayedexpansion
set filenum=3
for /l %%a in (1,1,%filenum%) do set "f=!f! %%a.txt"

for /l %%x in (10001,1,10001) do (
    set y=%%x
    for %%i in (D:\数据\横并\!y:~1!) do paste !f: = %%i\!>%%i.txt
)
pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)