批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理如何统计修改时间相同的文件的数量？ [打印本页]

作者: sjbit 时间: 2015-12-30 16:33 标题: 批处理如何统计修改时间相同的文件的数量？

目前遇到一个问题，问题情况如下：
相机会拍摄很多照片，现在需要统计同一修改时间的照片数量有多少？即 2015/12/30 16:20 拍摄的照片一共有60张，目前只能靠手动统计，想做出自动统计，并能生成到execl中。
没接触过批处理，不知道怎么办的？大家给些思路。我在论坛里有看到用xcopy命令的但是感觉改改也只能统计一个时间的文件，每次都要重新命令，不知道大家有什么解决办法。谢了。

作者: flyinnet9 时间: 2015-12-30 17:37

笨办法

@echo off
setlocal ENABLEDELAYEDEXPANSION
for /f "tokens=1,2,4" %%a in ('dir /a-d *.jpg^|find "."') do (
  if not defined %%a%%b (
    for /f "tokens=1,2,4" %%d in ('dir /a-d *.jpg^|find "."') do (
      if "%%a%%b"=="%%d%%e" set /a n+=1
    )
    echo. %%a %%b共拍摄 !n! 张照片
    set n=
  )
  set %%a%%b=1
)
pause
复制代码

作者: pcl_test 时间: 2015-12-30 19:48

水一发

@echo off&setlocal enabledelayedexpansion
for %%a in (*.jpg) do (
    set "wd=%%~ta"
    set "wd=!wd:/=!"
    set "wd=!wd:-=!"
    set "wd=!wd: =@!"
    set /a #!wd!+=1
)
set #
pause
复制代码

作者: DAIC 时间: 2015-12-30 20:03

从相机里面导出的照片可以用 jhead.exe 获取到具体的拍摄时间，例如：
C:\>jhead 1.jpg | findstr "Date/Time"
Date/Time : 2012:08:09 22:33:45

批量获取到的信息导入Excel之后就方便你排序等其它操作了：

@echo off
(for /f "delims=" %%i in ('dir /b /a-d *.jpg') do (
    set /p =%%i,<nul
    jhead "%%i" | findstr "Date/Time"
))>"1.csv"
复制代码

作者: sjbit 时间: 2015-12-31 11:25

谢谢大家我先试试很有帮助。

欢迎光临批处理之家 (http://bbs.bathome.net/)