@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%A in ('dir /a-d /b /s *.txt') do (
	(for /f "tokens=1* delims=:" %%a in ('type "%%A"^|findstr /n .*') do (
		if %%a equ 2 (echo,%%~nA)
		echo,%%b
	))>"%%A.bak"
	del "%%A"
	ren "%%A.bak" "%%~nxA"
)
set /p =执行完毕!
复制代码

@echo off
::取决more的限制
for /f "delims=" %%a in ('dir /a-d /b *.txt') do (
    (
      set/pa=
      setlocal enabledelayedexpansion
      echo;!a!
      endlocal
      echo;%%~na
      more +1
    )<"%%a">$
    move $ "%%a"
)
pause
复制代码

@echo off
for /f "delims=" %%a in ('dir /a-d /b *.txt') do (
   gawk "FNR==2{print FILENAME};1" "%%a" >$
   ren $ "%%a"
)
复制代码

/*&cls
@echo off
::指定在第一行之后插入
set n=1
dir /a-d /b *.txt|cscript -nologo -e:jscript "%~f0" %n%
pause&exit
*/
var fso = new ActiveXObject('Scripting.FileSystemObject');
while(!WScript.StdIn.AtEndOfStream){
    var file = WScript.StdIn.ReadLine();
    var i = 0, s = '', f = fso.OpenTextFile(file, 1);
    while(!f.AtEndOfStream){
    if(i == WScript.Arguments(0))s += fso.GetFile(file).Name.replace(/\.[^\.]+$/, '') + '\r\n';
        var str = f.ReadLine();
        s += str + '\r\n';
        i++;
    }
    f.Close();
    var f = fso.OpenTextFile(file, 2);
    f.Write(s);
    f.Close();
}
复制代码

@echo off
for /f "delims=" %%a in ('dir /a-d /b *.txt') do (
    (
      setlocal enabledelayedexpansion
      set/pa=
      echo;!a!
      endlocal
      echo;%%~na
      find /v ""
    )<"%%a">$
    move $ "%%a"
)
pause
复制代码

mshta http://bathome.net/s/hta/ "var n=1; dir().files().grep(/\.txt$/i)._each(function(f){var a=type(f).split('\r\n');a.splice(n,0,f.replace(/\.[^.]+$/,''));save(a.join('\r\n'),f)})"
复制代码

@echo off
(
	echo 第一行
	echo 第二行
	echo 第三行
	echo 第四行
)>a.txt

(
	setlocal enabledelayedexpansion
	set /p line_1=
	echo;line_1=!line_1!
        rem 取得第一行缓冲区

	set /p line_2=
	echo;line_2=!line_2!
        rem 取得第二行缓冲区

	find /n /v ""
        rem more 和 find 等第三方居然能获取完整的重定向输入

	set /p line_null=
	echo;line_null=!line_null!
        rem 之后再用 set /p 就无法取得重定向输入了
)<a.txt
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /s/b/l/aa *.txt') do (
    for /f "delims=" %%a in (%%i) do (
        set/a n+=1
        if !n! equ 1 set "a1=%%a" 
        if !n! equ 2 set "a2=%%a"
    )
    set n=0
    for /f "skip=2 delims=" %%b in (%%i) do (
        set/a a+=1
        if !a! equ 1 (echo,!a1!
        echo,%%~ni
        echo,!a2!)>%temp%\%%~nxi
        echo,%%b >>%temp%\%%~nxi
    )
    set a=0&set a1=&set a2=
    move /y "%temp%\%%~nxi" "%%i"
)
pause
复制代码

"""
python文件名插入指定行.py
http://bbs.bathome.net/thread-39833-1-1.html
2016年4月3日 13:08:57 codegay
"""
fn="temp.txt"
with open(fn) as f:
    txt=f.readlines()
    txt.insert(3,fn+"\n")#文件名加上换行符号插入第四行

with open(fn,"w+") as f:
    f.writelines(txt)
复制代码