批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理如何判断文件属性中最后修改日期为当天/当日的指定文件是否存在？ [打印本页]

作者: 7016427 时间: 2016-8-20 19:40 标题: 批处理如何判断文件属性中最后修改日期为当天/当日的指定文件是否存在？

本帖最后由 7016427 于 2016-8-21 16:44 编辑

请教各位老师，bat按文件属性查询问题
我是xp系统，我想按文件属性修改日期为当日的"日报.xls"文件是否存在？d:\tyhj\日报.xls,bat能否实现？
主要是想检查“日报.xls"文件是否当天修改过。

作者: GNU 时间: 2016-8-22 16:22

test.bat

@echo off
powershell -c "if ((Get-Date((Get-ChildItem 'd:\tyhj\日报.xls').LastWriteTime) -uformat '%%Y-%%m-%%d') -eq (Get-Date -uformat '%%Y-%%m-%%d')) {'Yes'} else {'No'}"
pause
复制代码

作者: GNU 时间: 2016-8-22 16:43

@echo off
for /f "tokens=2 delims==" %%i in ('wmic datafile where "Name='D:\\tyhj\\日报.xls'" get LastModified /value ^| findstr "="') do (
    set "StrDate1=%%i"
)
set "FileDate=%StrDate1:~0,8%"

for /f "tokens=2 delims==" %%i in ('wmic path win32_operatingsystem get LocalDateTime /value ^| findstr "="') do (
    set "StrDate2=%%i"
)
set "SysDate=%StrDate2:~0,8%"

if "%FileDate%" equ "%SysDate%" (
    echo Yes
) else (
    echo No
)
pause
复制代码

作者: 7016427 时间: 2016-8-22 18:57 标题: 【已解决！】批处理如何判断文件属性中最后修改日期为当天/当日的指定文件是否存在？

GNU 发表于 2016-8-22 16:43

谢谢各位老师

作者: xxpinqz 时间: 2016-8-22 19:24

回复 4# 7016427

解决的问题，修改下标题，加上[已解决]

作者: 7016427 时间: 2016-8-22 19:28

[已解决]回复 5# xxpinqz

欢迎光临批处理之家 (http://bbs.bathome.net/)