批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理for嵌套循环中，如何实现满足指定条件后结束/退出当前子循环 [打印本页]

作者: ngd 时间: 2016-10-8 15:34 标题: 批处理for嵌套循环中，如何实现满足指定条件后结束/退出当前子循环

本帖最后由 pcl_test 于 2016-10-8 16:09 编辑

比如a.txt中内容如下
212
541
442
333
我想得到每行最大的一个数字

@echo off&setlocal enabledelayedexpansion
for /f %%a in (a.txt) do (
    set str=%%a
    echo !str!
    for /l %%i in (5,-1,0) do (        
        if "!str!" NEQ "!str:%%i=!" echo %%i
    )
)
pause
复制代码

运行结果为
212
2
1
541
5
4
1
442
4
2
333
3
而我想要的结果是
212
2
541
5
442
4
333
3
这样的如何实现，重要的是在这样的 for嵌套循环中如何满足条件后结束当前循环返回上一级

作者: pcl_test 时间: 2016-10-8 16:09

@echo off
for /f %%a in ('type "a.txt"') do (
    set str=%%a
    echo;%%a
    call :loop %%a
)
pause&exit
:loop
set num=%~1
setlocal enabledelayedexpansion
for /l %%i in (9,-1,0) do (        
    if "!num!" neq "!num:%%i=!" echo;%%i&goto :eof
)
复制代码

作者: pcl_test 时间: 2016-10-8 16:09

@echo off
for /f %%a in ('type "a.txt"') do (
    set str=%%a&set/p=%%a <nul
    setlocal enabledelayedexpansion
    for /l %%i in (0,1,10) do (rem 指定数字最大长度为10位数      
        if not defined max (
            set max=!str:~%%i,1!
        ) else if !str:~%%i^,1! geq !max! set max=!str:~%%i,1!
    )
    echo;!max!
    endlocal
)
pause
复制代码

作者: pcl_test 时间: 2016-10-8 16:14

win7以上系统

powershell -c "gc 'a.txt'|%%{$_+' '+($_ -split ''|sort)[-1]}"
pause
复制代码

作者: WHY 时间: 2016-10-9 10:45

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set "s=%%i" & set "max="
    for /l %%j in (0 1 9) do if "!s:%%j=!" NEQ "!s!" set "max=%%j"
    echo;!s!&echo;!max!
)
复制代码

作者: WHY 时间: 2016-10-9 10:46

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set "s=%%i" & set "max="
    for /l %%j in (9 -1 0) do if "!s:%%j=!" NEQ "!s!" if not defined max set "max=%%j"
    echo;!s!&echo;!max!
)
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)