@echo off&rem 判断变量长度 折半法
::@随风 @bbs.bathome.net @2009-04-18
for /f "delims=" %%a in (a.txt) do (
   set s=%%a&set /a sun+=1
   setlocal enabledelayedexpansion&set "var="
   set /a n=8189*2,max=1
   for /l %%a in (1 1 14) do (
      if defined var set /a n=var
      set /a n/=2
      for %%i in (!n!) do (
         if "!s:~%%i,1!"=="" (set /a var=n) else (
            set s=!s:~%%i!&set /a max+=%%i,var-=%%i
   )))  
   echo 第!sun! 行的字符数为： !max! 个
   endlocal
)
pause
复制代码

:loop 不能处理%号,变量字符数上限为8187个。
::@随风 @bbs.bathome.net @2009-04-18
set "s=%~1"&rem 判断变量长度（封装）折半法
setlocal enabledelayedexpansion
set /a n=8189*2,max=1&set "var="
for /l %%a in (1 1 14) do (
   if defined var set /a n=var
   set /a n/=2
   for %%i in (!n!) do (
      if "!s:~%%i,1!"=="" (set /a var=n) else (
         set s=!s:~%%i!&set /a max+=%%i,var-=%%i
)))  
endlocal&set %~2=%max%&goto :EOF
复制代码

set s=!s:~%%i!&set /a max+=%%i,var-=%%i
复制代码

@echo off&rem 利用折半法准确判断输入数
set /p input=请输入一个整数：
set /a min=1^<^<31,max=~min&rem max、min分别为cmd所能处理的最大、最小数
:loop
set /a pin=(max+min)/2&rem 折半
if %input% lss %pin% set /a max=pin
if %input% equ %pin% goto end
if %input% gtr %pin% set /a min=pin
set /a n+=1&goto loop
:end
cls&echo 循环了%n%次得出输入的数是%pin%
pause>nul     
复制代码

@echo off
set /p w=请输入一些文字：
setlocal EnableDelayedExpansion
for /l %%b in (0 1 8192) do (
if "!w:~%%b,1!"=="" (echo 你输入了%%b个字！&goto a))
:a
pause
复制代码

……无论变量的字符数是多少，（1-8189）for /L 都只需循环14次即可得到结果，……
复制代码

@echo off
rem 字符串长度上限;替换8为你想要的数值,但值必须是2的冪
set /a nem=8
rem 前面以2为底的冪的指数
set /a lop=3
setlocal enabledelayedexpansion

:test
cls
set /p "str=输入字符串:"
if not defined str echo.   输入为空...&goto test_end
set /a max=%nem%,min=0
echo max : min  :  length
echo ( x + y ) / 2 = z
echo.
for /l %%a in (1,1,%lop%) do (
   set /a "length=(max+min)/2"
   echo ^(!max!^) + ^(!min!^) ==^> ^(!length!^)
   for /f "delims=" %%b in ("!length!") do (
      if "!str:~%%b!" equ "" (
         echo 完成折半,提取完成,字串第^(!length!+1^)位^(为^)空,继续逼近,设置max^(!max!^)为length^(!length!^)
         set /a max=length
      ) else (
         echo 完成折半,提取完成,字串第^(!length!+1^)位^(非^)空,开始远离,设置min^(!min!^)为length^(!length!^)
         set /a min=length
   )  )
   echo ^(!max!^) ^| ^(!min!^) ^<== ^(!length!^)&echo.
)
rem 如果提取字串不为空则+1
if "!str:~%length%!" neq "" set /a length+=1&echo 不为空+1
echo.
rem 继续判断是否溢出
if "!str:~%length%!" neq "" (echo.   字符串str超过%nem%个字符) else echo.   经计算字符串str共有!length!个字符
:test_end
pause>nul
goto test
复制代码