寒蝉凄13切，对长亭晚，13311111111骤雨初歇。
都门帐饮无绪，留恋处舟催发。执手相看[color=Red]1355555
7777[/color]泪眼，竟无语凝噎。念15去135去千里烟波，
暮霭沉1314沉楚天阔。  多情自古12580伤离别，
更那堪冷落清秋节。今宵酒醒何处?136杨柳岸晓风10010残月。
1372222此444去经年，应是良辰好景虚设。
便纵10086有千种风情，更与何人说? 13788889999
复制代码

$all = `type src.txt`;
$all =~ s/\r?\n//g;
while ($all=~s/[^\d]?(\d{11})[^\d]?//)
{
    print "$1\n";
}
复制代码

@echo off
echo on
setlocal enabledelayedexpansion
for %%a in (134 135 136 137 138 139 150 151 152 158 159 157 182 187 188 147  130 131 132 155 156  185 186   133 153  180 189) do (set 3a=%%a
for /f "delims=!3a! tokens=1*" %%b  in ('type a.txt^|find "!3a!"') do (
rem 我这个只能查到第一个出现数字的地方，这个delims和tokens要怎么写才能把每一行的所有数字都查到呢
set 8b=%%c
set "8b=!8b:~0,8!"
rem 这里判断变量8b是否全部是数字 if "!8b!"==(全部是数字) 
echo,!3a!!8b!>>phnum.txt
)
)
pause>nul
复制代码

'&wscript  -nologo -e:vbscript "%~0"
text=_
"寒蝉凄13切，对长亭晚，13311111111骤雨初歇。"&vbcrlf&_
"都门帐饮无绪，留恋处舟催发。执手相看[color=Red]1355555"&vbcrlf&_
"7777[/color]泪眼，竟无语凝噎。念15去135去千里烟波，"&vbcrlf&_
"暮霭沉1314沉楚天阔。  多情自古12580伤离别，"&vbcrlf&_
"更那堪冷落清秋节。今宵酒醒何处?136杨柳岸晓风10010残月。"&vbcrlf&_
"1372222此444去经年，应是良辰好景虚设。"&vbcrlf&_
"便纵10086有千种风情，更与何人说? 13788889999"

Function RegExpTest(patrn, strng)
   Dim regEx, Match, Matches   ' 建立变量。
   Set regEx = New RegExp   ' 建立正则表达式。
   regEx.Pattern = patrn   ' 设置模式。
   regEx.Global = True   ' 设置全局可用性。
   regEx.IgnoreCase = True   ' 设置是否区分字符大小写。
   Set Matches = regEx.Execute(strng)   ' 执行搜索。
   For Each Match in Matches   ' 遍历匹配集合。
      RetStr = RetStr & Match.Value& vbCRLF
   Next
   RegExpTest = RetStr
End Function
                        MsgBox(RegExpTest("1\d{10}", text))
复制代码

1>1/* :
(@cscript -nologo -e:jscript %0<0.txt)>1.txt&exit
*/
var c = WSH.StdIn.ReadAll().replace(/.\r\n/g).match(/1[34578]\d{9}/g);
WSH.ECHO(c);
复制代码

 @echo off

set fn=a.txt

setlocal enabledelayedexpansion
set PhoneNumbers=
set pn=
set /a nc=0
call :PhoneNumberReader "%fn%"
echo 文件中包含的全部手机号：
echo %PhoneNumbers%
pause
goto :EOF


:PhoneNumberReader
echo %~s1
for /f "delims=" %%a in (%~s1) do (
    call :CharReader %%a
)
call :CheckPhoneNumber
goto :EOF


:CharReader
set l=%*
:CheckNumber
set /a n=!l:~,1! 1>nul 2>&1
if "!n!" equ "!l:~,1!" (
    set pn=!pn!!n!
    set /a nc+=1 1>nul 2>&1
) else (
    call :CheckPhoneNumber *
)
set l=!l:~1!
if "!l!" neq "" goto :CheckNumber
goto :EOF


:CheckPhoneNumber
if !nc! equ 11 (
    for %%a in (134 135 136 137 138 139 150 151 152 158 159 157 182 187 188 147 130 131 132 155 156 185 186 133 153 180 189) do (
        if "%%a" equ "!pn:~,3!" (
            echo 找到一个手机号：!pn!
            set PhoneNumbers=!PhoneNumbers!!pn!%1
            goto :CheckPhoneNumberOver
        )
    )
)
:CheckPhoneNumberOver
set pn=
set /a nc=0 1>nul 2>&1
goto :EOF
复制代码

@echo off & setlocal enabledelayedexpansion
:: 逐个字符找【11位，以1[34578]开头】的数字

for /f "delims=" %%i in ('type 1.txt') do (
	call :split "%%i"
)

pause & exit /b

:: ------------------------------------------

:split [line]
if not defined line set line=%~1
set n=!line:~,1!
if not defined n goto :eof
if !n! leq 9 (
	if !n! geq 0 (
		set _num=1
	)
)
if defined _num (
	set "_num="
	set num=!num!!n!
) else set "num="
if "!num!" neq "" if "!num:~10!" neq "" (
	set _legal=
	if "!num:~,1!"=="1" (
		for %%i in (3,4,5,7,8) do (
			if not defined _legal (
				if "!num:~1,1!"=="%%i" set _legal=1
			)
		)
	)
	if defined _legal (
		echo;!num!& set "num="
	) else set num=!num:~1!
)
set line=!line:~1!
if "!line!" neq "" goto :split
goto :eof
复制代码

grep -Pow "\d{11}" "1.txt" > "2.txt"
复制代码

@set @n=0; /* & echo off & type 1.txt|cscript -nologo -e:jscript "%~f0" & pause & exit/b & rem */
WScript.StdIn.ReadAll()
	.replace(/\s/g, "")
	.replace(/(1[34578]\d{9})/g, function(a,b){
		WScript.Echo(b);
	});
复制代码

@echo off
set /an=Len=0
for /f "delims=" %%i in ('findstr /r "1[3-58][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]"^<1.txt') do (
    set "s=%%i"
    set "str=%%i"
    setlocal enabledelayedexpansion
    for %%j in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
        if "!s:~%%j!" neq "" set /a Len+=%%j & set "s=!s:~%%j!"
    )
    for /l %%j in (0,1,!len!) do (
        set t=!str:~%%j,1!
        if !t! leq 9 (
           if !t! geq 0 (
              set /a n+=1
              set num=!num!!t!
           ) else set num=&set "n=0"
        ) else set num=&set "n=0"
        if !n! equ 11 (
           echo;!num!
           set num=&set "n=0"
        )
    )
    endlocal
)
pause
复制代码

findstr /r "\<1[3-58][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\>"
复制代码