批处理之家 - Powered by Discuz! Board

GOTO :Eof
:Refresh
if Not Exist %TMP%\TMP.INF ((
Echo [Version]
Echo Signature=$Chicago$
Echo Provider=老刘
Echo [DefaultInstall])>%TMP%\TMP.INF)
RUNDLL32 SETUPAPI.DLL,InstallHinfSection ^
DefaultInstall 128 %TMP%\TMP.INF

复制代码

GOTO :Eof
:DeleteC
PUSHD %tmp%
IF Not Exist tmmp.inf (
>tmmp.inf (
echo [Version]
echo Signature=$Chicago$
echo Provider=老刘
echo [DefaultInstall]
echo delfiles=a
echo [a]))
set "aa=%~1"
for %%a in ("%aa%") do ^
if exist "c:%%~pnxa" ^
echo ..\..%%~pnxa,,,1>tmp.inf
(type tmmp.inf&type tmp.inf)>temp.inf
RunDll32.exe advpack.dll,LaunchINFSection .\temp.inf,DefaultInstall
POPD

复制代码

GOTO :Eof
:EditIni
@Echo off
Pushd %Tmp%
(For %%a in (
"[Version]"
"Signature=$Chicago$"
"[DefaultInstall]"
"UpdateInis=2333"
"[2333]"
) Do Echo %%~a)>.\inftmp.Inf
Echo "%~1","%~2",%~3 >>.\inftmp.Inf
RUNDLL32 SETUPAPI.DLL,InstallHinfSection ^
DefaultInstall 128 .\inftmp.INF
Popd

复制代码

使用方法： Call :Editini "ini-file" "ini-section" "[old-ini-entry], [new-ini-entry], [flags]"
.
.
ini-file
包含要更改条目的 .ini 绝对路径。

ini-section
包含要更改条目的节名。

old-ini-entry
可选。常用形式为 Key=Value。

new-ini-entry
可选。常用形式为 Key=Value。关键字或值都可以指定可替代字符串。

flags
可选操作标记。可以是下列值之一：
0 默认。如果在 .inf 文件条目中有 old-ini-entry 关键字，则用 new-ini-entry 替换该条目。注意 old-ini-entry 参数关键字与 .inf 文件条目必须匹配；每个条目的值都将忽略。
要无条件地将 new-ini-entry 添加到 .ini 文件中，请将 old-ini-entry 设置为 NULL。要无条件地从 .inf 文件中删除 old-ini-entry，请将 new-ini-entry 设置为 NULL。

1 如果 .inf 文件条目中有 old-ini-entry 的关键字和值，则用 new-ini-entry 替换该条目。请注意 old-ini-entry 参数和 .inf 文件条目的关键字和值必须匹配才能进行替换。作为对比，使用操作标志值为 0，只有关键字与它匹配才能进行替换。
2 如果在 .inf 文件中不存在 old-ini-entry 参数关键字，那么在 .ini 文件中不执行任何操作。
如果在 .inf 文件条目中存在 old-ini-entry 参数关键字以及 .ini 文件条目中存在 new-ini-entry 参数关键字，则会删除与 new-ini-entry 参数关键字匹配的 .inf 文件条目，并且按以下方法操作与 old-ini-entry 参数匹配的 .inf 文件条目：用 new-ini-entry 参数关键字替换 .inf 文件条目关键字。

如果在 .inf 文件中有 old-ini-entry 参数关键字，并且在 .ini 文件中没有 new-ini-entry 参数关键字，那么将条目添加到由 new-ini-entry 参数关键字和旧值组成的 .inf 文件中。

请注意 old-ini-entry 参数和 .ini 文件条目是否匹配取决基于关键字本身，而不是关键字和值。

3 除 old-ini-entry 参数和 .inf 文件中条目是否匹配取决基于关键字和值，而不但是关键字外，其他方面与上面列出的标志参数值 2 一样。
指定关键字和值时可以使用星号 (*) 通配符，系统能正确地解释此符号。

@echo off
Call :Editini "%~dp0Test.ini" Path ",SystemPath=%HOMEDRIVE%"
%Path节中添加键值%
Call :Editini "%~dp0Test.ini" Path "我是来凑数的～～～=我是随意字符串"
%Path节中删除键值%
Call :Editini "%~dp0Test.ini" Path "userPath=,userPath=%USERPROFILE%"
%强制更改Path节中的UserPath键值%
Call :Editini "%~dp0Test.ini" "Others Thing" "作者=不知道,作者=老刘～,2"
%嘿嘿，如果“不知道”作者，将“不知道”替换为"老刘～“，否则不执行操作%
Call :Editini "%~dp0Test.ini" "嘿嘿嘿" "s1="
%清除嘿嘿嘿节的注释，前提是被包裹在项和节之间%
Start %~dp0Test.ini
%——————————————————————————————%
GOTO :Eof
:EditIni
@Echo off
Pushd %Tmp%
(For %%a in (
"[Version]"
"Signature=$Chicago$"
"[DefaultInstall]"
"UpdateInis=2333"
"[2333]"
) Do Echo %%~a)>.\inftmp.Inf
Echo "%~1","%~2",%~3 >>.\inftmp.Inf
RUNDLL32 SETUPAPI.DLL,InstallHinfSection ^
DefaultInstall 128 .\inftmp.INF
Popd

复制代码

[Path]
winPath=C:\windows
userPath=sx
我是来凑数的～～～=2333
[Others Thing]
作者=不知道
[嘿嘿嘿]
;；‘我是注释1号～～～～～s～～～～～～～d～～～～～～～～～～～～～～～～～～s～～～～～
;；‘我是注释2号～～d～～～～～～～～～～～～～～～w～～～～～～～～～s～～～～～～～～～
;；‘我是注释3号～w～～～～～～～～～～～～～～～～～～～～～～～～～～z～～～s～～～～～
;；‘我是注释4号～～～～～～～～～a～～～～～～～～～～～～a～～～～～～z～～～～～～～～
;；‘我是注释5号～～～～～～～～～～～～～～～s～～～～～～～～～～w～～～z～～～～～～～
;；‘我是注释6号～～～～～～～～～～w～～～～～s～～～～～～～～～～～～～～～～～～s～～
;；‘我是注释7号～～～～～～x～～～～～～～～～～～～～～～～s～～～～～～～～～～～s～～
s1=

复制代码

[Version] 节中的语句 Signature="$CHICAGO$"表明这个 .INF 文件可以用于 windows 95 以后的所有平台上，目前来说就是 win98，winme，winnt4，win2k，winxp，win2k3，win7，win8，win10。这种 .INF 文件比较多见。如果[Version]节中的签名条目是 Signature="$Windows 95$"，表明这个 .INF 文件可以用于 windows 95 以后的 Win9x 平台上，如果[Version]节中的签名条目是 Signature="$WINDOWS NT$"，表明这个 .INF 文件可以用于 WindowsNT 系列的平台上，包括 winnt4，win2k，winxp，win2k3等系列的操作系统的 Setup API 将会拒绝执行这种类型的 .INF 文件。