批处理之家 - Powered by Discuz! Board

标题: [问题求助] [已解决]VBS如何利用正则表达式获取网页源代码中的内容输出到txt [打印本页]

作者: WindCat 时间: 2017-5-17 13:39 标题: [已解决]VBS如何利用正则表达式获取网页源代码中的内容输出到txt

本帖最后由 WindCat 于 2017-5-17 20:48 编辑

因为会不定期改动
所以我想做一个读取网页的中的地址然后修改系统pac的小工具
结合计划任务达到定期自动修改的目的
代码是从网上搜来改的

url="https://freepac.co/"
Set html = CreateObject("microsoft.xmlhttp")
html.open "GET",url,False
html.send
s=html.responseText
'MsgBox s

Set re=New RegExp
re.Global=True
re.Pattern="free.upac.pro/([0-9,a-z]*)"
re.IgnoreCase=True
Set matchs=re.Execute (s)
output=""
For Each m In matchs
    output=output & m.Submatches(0) & vbCrLf
Next
MsgBox output
复制代码

现在我遇到了一个蠢问题...
虽然知道输出是SaveToFile
但是不知如何修改才能让它输出Pattern的值到1.txt
然后用bat命令读取1.txt的值修改注册表以应用

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v AutoConfigURL /d "https://free.upac.pro/%%a" /f
复制代码

作者: yu2n 时间: 2017-5-17 19:10

Option Explicit

Dim wso, http, url, html, re, matchs, m, s
Set wso = CreateObject("WScript.Shell")
Set http = CreateObject("microsoft.xmlhttp")

'获取url网页内容
url = "https://freepac.co/"
http.open "GET", url, False
http.send
html = http.responseText

'提取网页中的字符串
Set re = New RegExp
re.Global = True
re.Pattern = "free.upac.pro/([0-9,a-z]*)"
re.IgnoreCase = True
Set matchs = re.Execute(html)
If matchs.Count > 0 Then
	s = matchs.Item(0).Submatches(0)	'提取第一个匹配项
	'写入注册表
	wso.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\AutoConfigURL", url & s, "REG_SZ"
End If

'打开IE代理设定界面
wso.Run "control inetcpl.cpl,,4", 1, False
wso.AppActivate "internet"
WScript.Sleep 500
wso.Sendkeys "%L"
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)

Powered by Discuz! 7.2