Board logo

标题: [文件操作] [已解决]求助优化windows2003文件服务器的备份bat代码 [打印本页]
作者: cLeoLiuyin    时间: 2017-9-16 20:31     标题: [已解决]求助优化windows2003文件服务器的备份bat代码

本帖最后由 cLeoLiuyin 于 2017-9-16 22:19 编辑

新手第一次尝试自己编写bat实战文件服务器备份，已经测试初步达成目标，但是仍然存在缺陷。
缺陷1：如果需要增加需要备份的路径，则需要新增变量，并且新增代码段
缺陷2：如果目标服务器文件已经删除，不会自动删除备份中的历史文件

学习目的1：简单代码的使用，仅此一，无需二，意思是不希望通过准备一个配置txt文件存放需要备份的变量信息，然后运行一个bat来读，也不希望额外生成临时文件来存放变量信息，for来取变量值，用简单代码实现。
学习目的2：通过简单代码，重构类似数组，robocopy功能，毕竟windows 2003本身无该功能。

求教各位大仙，优化我的bat脚本，谢谢。

环境：windows 2003服务器
目标：备份另一台文件服务器上的共享文件夹内制定目录下的文件(通过计划任务定期周六晚上启动该脚本进行备份更新)
代码：
  1. @echo off

  2. 

  3. rem 设置变量backupfrom，需要备份文件的完整目标路径

  4. set s_bk_from=\\172.16.0.12

  5. rem 设置变量backupto存入备份文件的完整路径，例如：f:\itdata或者\\172.16.0.6

  6. set s_bk_to=g:\backup

  7. 

  8. rem 设置变量s_01至s_99需要备份的文件夹名称，增加一个变量，需要检查下面是否同步COPY了改变量的处理过程

  9. rem 如果路径名中包含特殊字符串，需要用转移字符标识，例如Print&Dye需要写为Print^&Dye

  10. set s_01=Account

  11. set s_02=Cwong

  12. set s_03=TimeCard

  13. set s_04=Sales

  14. set s_05=Print^&Dye

  15. set s_06=it-b\IKO-CLUB-WORK

  16. set s_07=it-b\IT工作

  17. set s_08=it-b\源文件

  18. set s_09=it-b\系统运行文件

  19. set s_10=it-b\系统

  20. set s_11=it-b\软件

  21. 

  22. rem 如果存放备份文件的路径不存在，则先创建用于存放备份文件的文件夹

  23. if not exist "%s_bk_to%" md "%s_bk_to%"

  24. rem 需要进入到存放备份文件的磁盘跟目录下，才可以对该盘进行读写操作

  25. %s_bk_to:~0,2%

  26. cd "%s_bk_to%"

  27. 

  28. rem 备份变量s_01目录文件

  29. if not exist "%s_01%" md "%s_01%"

  30. xcopy "%s_bk_from%\%s_01%" "%s_bk_to%\%s_01%" /s/e/d/y

  31. 

  32. rem 备份变量s_02目录文件

  33. if not exist "%s_02%" md "%s_02%"

  34. xcopy "%s_bk_from%\%s_02%" "%s_bk_to%\%s_02%" /s/e/d/y

  35. 

  36. rem 备份变量s_03目录文件

  37. if not exist "%s_03%" md "%s_03%"

  38. xcopy "%s_bk_from%\%s_03%" "%s_bk_to%\%s_03%" /s/e/d/y

  39. 

  40. rem 备份变量s_04目录文件

  41. if not exist "%s_04%" md "%s_04%"

  42. xcopy "%s_bk_from%\%s_04%" "%s_bk_to%\%s_04%" /s/e/d/y

  43. 

  44. rem 备份变量s_05目录文件

  45. if not exist "%s_05%" md "%s_05%"

  46. xcopy "%s_bk_from%\%s_05%" "%s_bk_to%\%s_05%" /s/e/d/y

  47. 

  48. rem 备份变量s_06目录文件

  49. if not exist "%s_06%" md "%s_06%"

  50. xcopy "%s_bk_from%\%s_06%" "%s_bk_to%\%s_06%" /s/e/d/y

  51. 

  52. rem 备份变量s_07目录文件

  53. if not exist "%s_07%" md "%s_07%"

  54. xcopy "%s_bk_from%\%s_07%" "%s_bk_to%\%s_07%" /s/e/d/y

  55. 

  56. rem 备份变量s_08目录文件

  57. if not exist "%s_08%" md "%s_08%"

  58. xcopy "%s_bk_from%\%s_08%" "%s_bk_to%\%s_08%" /s/e/d/y

  59. 

  60. rem 备份变量s_09目录文件

  61. if not exist "%s_09%" md "%s_09%"

  62. xcopy "%s_bk_from%\%s_09%" "%s_bk_to%\%s_09%" /s/e/d/y

  63. 

  64. rem 备份变量s_10目录文件

  65. if not exist "%s_10%" md "%s_10%"

  66. xcopy "%s_bk_from%\%s_10%" "%s_bk_to%\%s_10%" /s/e/d/y

  67. 

  68. rem 备份变量s_11目录文件

  69. if not exist "%s_11%" md "%s_11%"

  70. xcopy "%s_bk_from%\%s_11%" "%s_bk_to%\%s_11%" /s/e/d/y
复制代码
作者: bbaa    时间: 2017-9-16 21:12

本帖最后由 bbaa 于 2017-9-16 21:18 编辑

无法保证旧版本CMD是否能正常运行
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. rem 设置变量backupfrom，需要备份文件的完整目标路径

  4. set s_bk_from=\\172.16.0.12

  5. rem 设置变量backupto存入备份文件的完整路径，例如：f:\itdata或者\\172.16.0.6

  6. set s_bk_to=g:\backup

  7. 

  8. rem 设置变量s_01至s_99需要备份的文件夹名称，每增加一个变量，需要检查下面是否同步COPY了改变量的处理过程

  9. rem 如果路径名中包含特殊字符串，需要用转移字符标识，例如Print&Dye需要写为Print^&Dye

  10. for %%i in (

  11. 	"Account"

  12. 	"Cwong"

  13. 	"TimeCard"

  14. 	"Sales"

  15. 	"Print^&Dye"

  16. 	"it-b\IKO-CLUB-WORK"

  17. 	"it-b\IT工作"

  18. 	"it-b\源文件"

  19. 	"it-b\系统运行文件"

  20. 	"it-b\系统"

  21. 	"it-b\软件"

  22. ) do (

  23. 	set "s_!Count!=%%~i"

  24. 	set /a Count+=1

  25. )

  26. 

  27. rem 如果存放备份文件的路径不存在，则先创建用于存放备份文件的文件夹

  28. if not exist "%s_bk_to%" md "%s_bk_to%"

  29. rem 需要进入到存放备份文件的磁盘根目录下，才可以对该盘进行读写操作

  30. %s_bk_to:~0,2%

  31. cd /d "%s_bk_to%"

  32. 

  33. rem 备份文件

  34. for /f "delims== tokens=2" %%i in ('Set S_') do ( 

  35. 	md %%~i>nul 2>nul

  36. 	xcopy "%s_bk_from%\%%~i" "%s_bk_to%\%%~i" /s/e/d/y

  37. )
复制代码
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. rem 设置变量backupfrom，需要备份文件的完整目标路径

  4. set s_bk_from=\\172.16.0.12

  5. rem 设置变量backupto存入备份文件的完整路径，例如：f:\itdata或者\\172.16.0.6

  6. set s_bk_to=g:\backup

  7. 

  8. rem 如果路径名中包含特殊字符串，需要用转移字符标识，例如Print&Dye需要写为Print^&Dye

  9. rem 如果存放备份文件的路径不存在，则先创建用于存放备份文件的文件夹

  10. if not exist "%s_bk_to%" md "%s_bk_to%"

  11. rem 需要进入到存放备份文件的磁盘根目录下，才可以对该盘进行读写操作

  12. %s_bk_to:~0,2%

  13. cd /d "%s_bk_to%"

  14. rem 每增加一个变量，需要检查下面是否同步COPY了改变量的处理过程

  15. for %%i in (

  16. 	"Account"

  17. 	"Cwong"

  18. 	"TimeCard"

  19. 	"Sales"

  20. 	"Print^&Dye"

  21. 	"it-b\IKO-CLUB-WORK"

  22. 	"it-b\IT工作"

  23. 	"it-b\源文件"

  24. 	"it-b\系统运行文件"

  25. 	"it-b\系统"

  26. 	"it-b\软件"

  27. ) do (

  28. 	md %%~i>nul 2>nul

  29. 	xcopy "%s_bk_from%\%%~i" "%s_bk_to%\%%~i" /s/e/d/y

  30. )
复制代码
作者: cLeoLiuyin    时间: 2017-9-16 22:17

谢谢，测试可用，简单了许多，学习了。
  1. @echo off

  2. 

  3. rem 设置变量backupfrom，需要备份文件的完整目标路径

  4. set s_bk_from=\\172.16.0.12

  5. rem 设置变量backupto存入备份文件的完整路径，例如：f:\itdata或者\\172.16.0.6

  6. set s_bk_to=g:\backup

  7. 

  8. rem 需要进入到存放备份文件的磁盘跟目录下，才可以对该盘进行读写操作

  9. if not exist "%s_bk_to%" md "%s_bk_to%"

  10. %s_bk_to:~0,2%

  11. cd "%s_bk_to%"

  12. 

  13. rem 需要备份的文件夹，添加到for里，循环处理备份工作

  14. for %%i in (

  15. 	"Account"

  16. 	"Cwong"

  17. 	"TimeCard"

  18. 	"Sales"

  19. 	"Print&Dye"

  20. 	"it-b\IKO-CLUB-WORK"

  21. 	"it-b\IT工作"

  22. 	"it-b\源文件"

  23. 	"it-b\系统运行文件"

  24. 	"it-b\系统"

  25. 	"it-b\软件"

  26. ) do (

  27. 	md %%~i>nul 2>nul

  28. 	xcopy "%s_bk_from%\%%~i" "%s_bk_to%\%%~i" /s/e/d/y

  29. )
复制代码




欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2