Board logo

标题: 老毛桃WinPE安装文件批处理的讲解,大家一起来研讨一下 [打印本页]
作者: tzz    时间: 2009-5-16 19:41     标题: 老毛桃WinPE安装文件批处理的讲解,大家一起来研讨一下

我把那个安装文件运行后在temp下找到了源文件，换成了.txt上传给大家研究
我感觉写的还不错
下载下来后把源文件配置文件改成"PESETUP.INI"再打开由源文件改成的.bat文件
链接: https://pan.baidu.com/s/1lBnbhG6L6YAhI02CYxzrHA 提取码: uy4n

源代码如下：
作者: tzz    时间: 2009-5-16 19:41

  1. @Echo Off

  2. COLOR 2F

  3. Set Prog=老毛桃制作的 WinPE 专用安装工具

  4. Set L1=　　　　　　╭══════════════════╮

  5. Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║

  6. Set L3=　　　╭══┤　%Prog%　 ├══╮

  7. Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║

  8. Set L5=　　　║　　╰══════════════════╯　　║

  9. Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║

  10. Set L7=　　　╟════════════════════════╢

  11. Set L8=　　　║　版权所有：老毛桃　　仅供网友们交流　翻版不究　║

  12. Set L9=　　　╰────────────────────────╯

  13. Title %Prog%

  14. 

  15. Set SetupINIFile=PESetup.INI

  16. Set PEFile=MiniPE\WinPE.IS_

  17. Set PEIni=MiniPE\WinPE.INI

  18. Set LogFile=PEInstall.log

  19. If Not Exist .\PESETUP.INI Goto Err0

  20. For /F "tokens=2 delims=^=" %%I In ('FIND /I ^"外置程序包^" .\%SetupINIFile%') DO Set OPFile=MiniPE\%%I

  21. 

  22. Set AddATTR=ATTRIB +S +H +R

  23. Set DelATTR=ATTRIB -S -H -R

  24. 

  25. :Start

  26. CLS

  27. Title %Prog%——安装

  28. Echo.

  29. Echo %L1%

  30. Echo %L2%

  31. Echo %L3%

  32. Echo %L4%

  33. Echo %L5%

  34. Echo %L6%

  35. Echo 　　　║ 　请选择安装方式：　　　　　　　　　　　　　　 ║

  36. Echo %L6%

  37. Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║

  38. Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║

  39. Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║

  40. Echo 　　　║　　[4] Grub安装/启动 (U 盘、移动硬盘安装)　　　║

  41. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║

  42. Echo %L6%

  43. Echo %L7%

  44. Echo 　　　║　注意: Aero 安装项只适合系统分区在(HD0,0)分区　║

  45. Echo %L7%

  46. Echo %L8%

  47. Echo %L9%

  48. Echo.

  49. Set Choice=

  50. Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/Q) ，然后按回车：

  51. If "%Choice%"=="" Goto Start

  52. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%

  53. If /I "%Choice%"=="1" Goto HD

  54. If /I "%Choice%"=="2" Goto HD

  55. If /I "%Choice%"=="3" Goto HD

  56. If /I "%Choice%"=="4" Goto UD

  57. If /I "%Choice%"=="Q" Exit

  58. Goto Start

  59. 

  60. :HD

  61. Set RP=

  62. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:

  63. If "%RP%"=="" Goto HDRPErr

  64. Set PEDIR=%RP%\MiniPE&&Set TargetP=硬盘&&Set TxtSp= 

  65. If Exist %PEDIR% Goto Err1

  66. FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL

  67. If "%Errorlevel%"=="0" Goto Err1

  68. FIND /I "C:\MiniPE" %RP%\BOOT.INI>NUL 2>NUL

  69. If "%Errorlevel%"=="0" Goto Err1

  70. If /I "%Choice%"=="1" Goto Install

  71. If /I "%Choice%"=="2" Goto GInstall

  72. If /I "%Choice%"=="3" Goto AInstall

  73. Goto HD

  74. 

  75. :UD

  76. CLS

  77. Title %Prog%——U 盘安装

  78. For /F "skip=2 tokens=*" %%I In ('MYINS\CHECKUSB.EXE') DO SET Us=%%I

  79. If "%Us%"=="当前可移动磁盘分区：" Goto NoUD

  80. Echo %Us%&&Echo.

  81. If "%NoUD%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、未格式化或不是 U 盘分区，请按任意键重新设定。&&Echo.

  82. Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：

  83. Echo.&&Echo.

  84. If "%RP%"=="" Goto UD

  85. If Not "%RP%"=="" Set RP=%RP:~0,1%:

  86. For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I

  87. If Not "%Err2%"=="1" Set NoUD=Yes&&Goto UD

  88. Set TestFile=%RP%\MiniPETest_%RANDOM%.MT

  89. Cd.>%TestFile%

  90. If Not Exist %TestFile% Set NoUD=Yes&&Goto UD

  91. Del %TestFile% /Q>NUL 2>NUL

  92. Set U=U&&Set PEDIR=%RP%\MiniPE&&Set TargetP= U 盘&&Set TxtSp=

  93. If Exist %RP%\MAOTAO Goto Err1

  94. If Exist %PEDIR% Goto Err1

  95. CLS

  96. Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导

  97. Echo.

  98. Echo 请严格按照相关工具软件界面中的提示操作，以防出错。请按任意键开始。。。

  99. PAUSE>NUL

  100. Start /Wait MYINS\HPUSBFW.EXE

  101. Start /Wait MYINS\GRUBGUI.EXE

  102. Echo.

  103. Echo 您的 U 盘已经成功格式化并写入了 Grub 引导，请按任意键继续。。。

  104. PAUSE>NUL

  105. Goto GInstall

  106. 

  107. :NoUD

  108. CLS

  109. Title %Prog%——U 盘安装

  110. Echo.

  111. Echo %L1%

  112. Echo %L2%

  113. Echo %L3%

  114. Echo %L4%

  115. Echo %L5%

  116. Echo %L6%

  117. Echo 　　　║ 您的计算机似乎没有安装 U 盘，您想怎么办？　　　║

  118. Echo %L6%

  119. Echo 　　　║　　 返回首页，重新选择安装选项。　　　　　　║

  120. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║

  121. Echo %L6%

  122. Echo %L7%

  123. Echo %L8%

  124. Echo %L9%

  125. Echo.

  126. Set Choice=

  127. Set /P Choice=　　　请选择要进行的操作 (B/Q) ，然后按回车：

  128. If "%Choice%"=="" Goto NoUD

  129. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%

  130. If /I "%Choice%"=="B" Goto Start

  131. If /I "%Choice%"=="Q" Exit

  132. Goto NoUD

  133. Exit

  134. 

  135. :Err0

  136. Echo 错误：安装配置文件丢失！&&Echo.

  137. Echo 请确认安装配置文件 %SetupINIFile% 存在或到本程序所在目录执行安装。&&Echo.

  138. Echo 请按任意键退出安装程序。。。

  139. PAUSE>NUL

  140. Exit

  141. 

  142. :Err1

  143. CLS

  144. Title %Prog%——卸载

  145. Echo.

  146. Echo %L1%

  147. Echo %L2%

  148. Echo %L3%

  149. Echo %L4%

  150. Echo %L5%

  151. Echo %L6%

  152. Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║

  153. Echo %L6%

  154. Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║

  155. Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║

  156. Echo 　　　║　　 返回首页，重新选择安装选项。　　　　　　║

  157. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║

  158. Echo %L6%

  159. Echo %L7%

  160. Echo %L8%

  161. Echo %L9%

  162. Echo.

  163. Set Choice=

  164. Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：

  165. If "%TargetP%"=="硬盘" Set U=

  166. If "%Choice%"=="" Goto Err1

  167. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%

  168. If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall

  169. If /I "%Choice%"=="2" Goto UnInstall

  170. If /I "%Choice%"=="B" Goto Start

  171. If /I "%Choice%"=="Q" Exit

  172. Goto Err1

  173. Exit

  174. 

  175. :UnInstall

  176. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL

  177. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL

  178. If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL

  179. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL

  180. If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPD=%%i

  181. If Not "%U%"=="" Set OPD=%RP%

  182. If Exist %OPD%\外置程序 RD %OPD%\外置程序 /S /Q>NUL 2>NUL

  183. If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL

  184. If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL

  185. If Exist %RP%\MiniPE RD %RP%\MiniPE /S /Q>NUL 2>NUL

  186. %DelATTR% %RP%\BOOT.INI>NUL 2>NUL

  187. Set TMPINIFile=BOOT_%RANDOM%.INI

  188. If Exist %RP%\BOOT.BAK (

  189. %DelATTR% %RP%\BOOT.BAK

  190. TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%

  191. TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI

  192. ) Else (

  193. If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.INI|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%

  194. If Exist %RP%\%TMPINIFile% TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI

  195. )

  196. If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL

  197. If Exist %RP%\%TMPINIFile% %DelATTR% %RP%\%TMPINIFile%&&Del %RP%\%TMPINIFile%>NUL 2>NUL

  198. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI

  199. Set RP=

  200. Title %Prog%——卸载完成

  201. If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)

  202. Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。

  203. PAUSE>NUL 2>NUL

  204. Exit

  205. 

  206. :Install

  207. Title %Prog%——普通安装

  208. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL

  209. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE

  210. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE

  211. Echo.&&Echo　　　　正在复制文件，请稍候 。。。

  212. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL

  213. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL

  214. Call :CopyAndSetFiles

  215. Goto SUCCESS

  216. 

  217. :GInstall

  218. If "%U%"=="" Title %Prog%——Grub安装

  219. CLS

  220. Set LDRP=MiniPE\

  221. Echo 请输入您要设定的密码

  222. Echo 注意：密码中不许有空格、"\"、引号等特殊字符

  223. Echo.

  224. Set /P Pass1=请输入：

  225. If "%Pass1%"=="" Goto GInstall

  226. Echo.&&Echo.

  227. Echo 请再一次输入您的密码

  228. Echo.

  229. Set /P Pass2=请再次输入：

  230. If "%Pass2%"=="" Goto GInstall

  231. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall

  232. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL

  233. >%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%

  234. MYINS\MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL

  235. For /f %%i In ('type %PEDIR%\md5r.txt') do SET MD5Pass=password --md5 %%i

  236. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL

  237. >>%RP%\MTLDR Echo %MD5Pass%

  238. >>%RP%\MTLDR Echo fontfile /minipe/muifont.gz

  239. >>%RP%\MTLDR Echo splashimage /minipe/bj2008.xpm.gz

  240. >>%RP%\MTLDR Echo.

  241. >>%RP%\MTLDR Echo title WinPE 迷你维护系统 ^(By: MAOTAO^)

  242. >>%RP%\MTLDR Echo %MD5Pass%

  243. >>%RP%\MTLDR Echo chainloader /minipe/ldrxpe

  244. >>%RP%\MTLDR Echo.

  245. >>%RP%\MTLDR Echo title Grub 命令行

  246. >>%RP%\MTLDR Echo %MD5Pass%

  247. >>%RP%\MTLDR Echo commandline

  248. >>%RP%\MTLDR Echo.

  249. >>%RP%\MTLDR Echo title 从第一硬盘第一分区启动

  250. >>%RP%\MTLDR Echo root ^(hd0,0^)

  251. >>%RP%\MTLDR Echo chainloader +1

  252. >>%RP%\MTLDR Echo.

  253. >>%RP%\MTLDR Echo title 从第二硬盘第一分区启动

  254. >>%RP%\MTLDR Echo root ^(hd1,0^)

  255. >>%RP%\MTLDR Echo chainloader ^(hd1,0^)+1

  256. >>%RP%\MTLDR Echo.

  257. >>%RP%\MTLDR Echo title 重新启动计算机

  258. >>%RP%\MTLDR Echo reboot

  259. >>%RP%\MTLDR Echo.

  260. >>%RP%\MTLDR Echo title 关闭计算机

  261. >>%RP%\MTLDR <nul Set/p=halt

  262. Del %PEDIR%\MD5?.* /Q>NUL 2>NUL

  263. Echo.

  264. Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。

  265. PAUSE>NUL 2>NUL

  266. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE

  267. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE

  268. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR

  269. Echo.

  270. Echo 正在复制文件，请稍候 。。。

  271. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y>NUL 2>NUL

  272. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y>NUL 2>NUL

  273. If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y>NUL 2>NUL

  274. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL

  275. If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin

  276. Call :CopyAndSetFiles

  277. Goto SUCCESS
复制代码

[ 本帖最后由 tzz 于 2009-5-16 21:34 编辑 ]
作者: tzz    时间: 2009-5-16 19:42

  1. :AInstall

  2. Title %Prog%——Aero安装

  3. CLS

  4. Echo 请输入您要设定的密码

  5. Echo 注意：密码中不许有空格、"\"、引号等特殊字符

  6. Echo.

  7. Set /P Pass1=请输入：

  8. If "%Pass1%"=="" Goto AInstall

  9. Echo.&&Echo.

  10. Echo 请再一次输入您的密码

  11. Echo.

  12. Set /P Pass2=请再次输入：

  13. If "%Pass2%"=="" Goto AInstall

  14. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall

  15. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL

  16. For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL

  17. Ren %PEDIR%\maotao.bin avldr.xpe

  18. Ren %PEDIR%\maotaoa.bin maotao.bin

  19. >%PEDIR%\airL.gz <nul Set/p=%Pass2%

  20. Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL

  21. MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL

  22. Echo.

  23. Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。

  24. PAUSE>NUL 2>NUL

  25. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE

  26. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE

  27. Echo.

  28. Echo 正在复制文件，请稍候 。。。

  29. MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL

  30. Call :CopyAndSetFiles

  31. Goto SUCCESS

  32. 

  33. :HDRPErr

  34. CLS

  35. Set RP=

  36. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BootMGR Set RP=%%I:&&Set PEDIR=%%I:\MiniPE

  37. If Not "%RP%"=="" (

  38.         TITLE %Prog%——检测到 Windows Vista 分区

  39.         Set OPT=Vista&&Set OPT0=存在 WinVista 分区&&Set OPT1= 将 WimPE 安装到 Windows Vista 分区。

  40. ) Else (

  41.         TITLE %Prog%——没有检测到系统分区

  42.         Set OPT=NewHD&&Set OPT0=没有安装过操作系统&&Set OPT1= 全新硬盘，将 WimPE 安装到活动分区。 

  43. )

  44. Echo.

  45. Echo %L1%

  46. Echo %L2%

  47. Echo %L3%

  48. Echo %L4%

  49. Echo %L5%

  50. Echo %L6%

  51. Echo 　　　║　好像您的机器中%OPT0%，您想怎么办？║

  52. Echo %L6%

  53. Echo 　　　║　　%OPT1%　　║

  54. Echo 　　　║　　 返回首页，重新选择安装选项。　　　　　　║

  55. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║

  56. Echo %L6%

  57. Echo 　　　║　注意: 为确保安全，此安装选项可能会卸载不干净！║

  58. Echo %L7%

  59. Echo %L8%

  60. Echo %L9%

  61. Echo.

  62. Set Choice=

  63. Set /P Choice=　　　请选择要进行的操作 (I/B/Q) ，然后按回车：

  64. If "%Choice%"=="" Goto HDRPErr

  65. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%

  66. If /I "%Choice%"=="I" If "%OPT%"=="Vista" Goto Vista

  67. If /I "%Choice%"=="I" If "%OPT%"=="NewHD" Goto NewHD

  68. If /I "%Choice%"=="B" Goto Start

  69. If /I "%Choice%"=="Q" Exit

  70. Goto HDRPErr

  71. Exit

  72. 

  73. :Vista

  74. Set PEDIR=%RP%\MiniPE

  75. If Exist %RP%\MAOTAO Goto Err1

  76. If Exist %PEDIR% Goto Err1

  77. Echo.&&Echo.

  78. Echo　　　　正在复制文件，请稍候 。。。

  79. If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK

  80. Set NoLDR=Yes

  81. If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL

  82. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL

  83. If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR

  84. Call :CopyAndSetFiles

  85. Goto SUCCESS

  86. 

  87. :NewHD

  88. CLS

  89. TITLE %Prog%——在全新硬盘中安装

  90. If "%NoNewErr%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、或未格式化，请按任意键重新设定。&&Echo.

  91. Echo 请设置您需要安装 WinPE 到哪个分区（注意一定要是活动分区）

  92. Echo.

  93. Set /P RP=请输入您需要安装 WinPE 的分区符（不需要冒号，例如 C），然后按回车：

  94. Echo.&&Echo.

  95. If "%RP%"=="" Goto NewHD

  96. If Not "%RP%"=="" Set RP=%RP:~0,1%:

  97. For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I

  98. If Not Exist %RP% Set NoNewErr=Yes&&Goto NewHD

  99. Set TestFile=%RP%\MiniPETest_%RANDOM%.MT

  100. Cd.>%TestFile%

  101. If Not Exist %TestFile% Set NoNewErr=Yes&&Goto NewHD

  102. Del %TestFile% /Q>NUL 2>NUL

  103. Set PEDIR=%RP%\MiniPE

  104. If Exist %RP%\MAOTAO Goto Err1

  105. If Exist %PEDIR% Goto Err1

  106. MyIns\NTBoot.exe %RP% >NUL

  107. Echo.

  108. Echo 正在复制文件，请稍候 。。。

  109. If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK

  110. Set NoLDR=Yes

  111. If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL

  112. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL

  113. If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR

  114. Call :CopyAndSetFiles

  115. Goto SUCCESS

  116. 

  117. :CopyAndSetFiles

  118. If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL

  119. If "%U%"=="" For /F %%i In ("%RP%\NTLDR") Do If %%~zi LSS 250000 Set SysVer=2K

  120. If "%NoLDR%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y>NUL 2>NUL

  121. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% NTCOM -r -y>NUL 2>NUL

  122. ::If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL

  123. Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL

  124. Copy ..\%OPFile% %PEDIR% /Y>NUL 2>NUL

  125. Copy ..\%PEIni% %PEDIR% /Y>NUL 2>NUL

  126. If "%U%"=="" If Exist %RP%\BOOT.INI %DelATTR% %RP%\BOOT.INI

  127. If "%U%"=="" If Exist %RP%\BOOT.INI If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK

  128. If "%U%"=="" If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL

  129. If "%U%"=="" If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI

  130. If "%U%"=="" If Exist %RP%\BOOT.INI Echo C:\MiniPE\MAOTAO.BIN="WinPE  By: 老毛桃">>%RP%\BOOT.INI

  131. If /I "%SysVer%"=="2K" (

  132.         %DelATTR% %RP%\NTLDR&&%DelATTR% %RP%\bootfont.bin

  133.         Ren %RP%\NTLDR NTLDR.2K&&Ren %RP%\bootfont.bin bootfont.bin.2K

  134.         MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL

  135.         MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% bootfont.bin -r -y>NUL 2>NUL

  136. )

  137. If Exist %RP%\%PEIni% %DelATTR% %RP%\%PEIni%

  138. TYPE ..\%PEIni%|FIND /I /V "PESetup.EXE">%RP%\%PEIni%

  139. %AddATTR% %RP%\MiniPE /S /D

  140. %AddATTR% %RP%\MiniPE\*.* /S /D

  141. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI

  142. If Exist %RP%\%LDRP%LDRXPE %AddATTR% %RP%\%LDRP%LDRXPE

  143. If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE

  144. If Exist %RP%\MTLDR %AddATTR% %RP%\MTLDR

  145. Goto :EOF

  146. 

  147. :SUCCESS

  148. Title %Prog%——安装完成

  149. CLS

  150. For %%i In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If /I "%RP%"=="%%i:" Set RP=%%i:

  151. Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。

  152. If "%U%"=="" (

  153. Echo.

  154. If Exist %RP%\Boot.INI Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。

  155. )

  156. Echo.&&Echo.

  157. Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。

  158. Echo.

  159. Echo 请按任意键退出 。。。

  160. PAUSE>NUL 2>NUL

  161. Exit
复制代码

[ 本帖最后由 tzz 于 2009-5-16 21:34 编辑 ]
作者: Batcher    时间: 2009-5-16 21:10

本版规则
1、求代码、寻求代码解释、探讨代码得失的帖子均可发在本版块，其余话题禁止在本版讨论；
2、求助时，务必在顶楼一次性把问题交代清楚；若文字难以表述，请配图说明，或是上传附件；但是，一切操作应从节约论坛资源的角度出发，能文字说明清楚的就无需再发图片，小图能说明问题的尽量不截全图，在不影响效果的前提下尽量压缩图片及附件；
3、所发代码若不止一行，请务必用code标记把代码部分首尾括起来，以便他人复制；


Q: 如何用code把代码扩起来？
A: http://bbs.bathome.net/thread-404-1-1.html
作者: wanxibing    时间: 2011-8-19 03:27

以上代码写的是没得话说，构思严谨结构紧凑，
  1. If Not Exist .\PESETUP.INI Goto Err0

  2. :Err0

  3. Echo 错误：安装配置文件丢失！&&Echo.

  4. Echo 请确认安装配置文件 %SetupINIFile% 存在或到本程序所在目录执行安装。&&Echo.

  5. Echo 请按任意键退出安装程序。。。
复制代码

****************************************
不知他的批处理是用什么软件打包的，解压到临时文件夹把变量设在J:\SETUP\PESETUP.EXE 这个目录的，试想下批处理已解压到临时文件夹再运行，运行到 If Not Exist .\PESETUP.INI Goto Err0
表示如果当前目录不存在PESETUP.INI这个文件就跳到Err0处，
作者: wanxibing    时间: 2011-8-19 21:02

  1. @echo off

  2. if exist C:\mtldr (

  3.        goto jc01

  4.        ) else (

  5.      set n1=C:\mtldr

  6.        goto err

  7.   )

  8. :err

  9. color 4f 

  10. 

  11. echo 错误 好像你的系统没有正确安装PE系统、

  12. echo.

  13. echo 缺失文件 %n1% %n2%请安装后再运行本程序 按任一键退出

  14. pause >nul

  15. exit

  16. 

  17. :jc01

  18. if exist C:\MiniPE\OP.WIM (

  19.        goto jc02

  20. 

  21.        ) else (

  22.       set n2=C:\MiniPE\OP.WIM

  23.        goto err

  24.     )

  25. 

  26. :jc02

  27. color 6f

  28. goto bigen

  29. 

  30. :bigen

  31. echo ok 可以安装 没有发现少了相应的文件

  32. pause
复制代码
作者: wolfwolf    时间: 2011-10-15 22:59

很厉害的人啊，楼主也英明
作者: LJY4.0    时间: 2022-6-5 21:30

回复 5# wanxibing
要把PESETUP.txt改为PESETUP.INI



欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2