批处理之家 - Powered by Discuz! Board

标题: [其他] 批处理如何显示大字体 [打印本页]

作者: rodck 时间: 2018-1-8 10:38 标题: 批处理如何显示大字体

本帖最后由 pcl_test 于 2018-1-8 11:26 编辑

求把显示IP的字变得很大，方便年纪多大的职员看IP
这个批处理如何让IP显示很大的字

@echo off
COLOR 0A
for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
echo, 本机IP: %ip%
pause

作者: yhcfsr 时间: 2018-1-8 13:19

本帖最后由 yhcfsr 于 2018-1-8 14:19 编辑

回复 1# rodck

办法有，但没有完美的。
运行一次，结束后不要按回车。再运行一次就会有效果，按回车会清除修改结果。
这是全局修改，所以运行别的BAT也会应用修改结果，就这样吧。没有什么好办法。

@echo off
COLOR 0A
if "%1"=="" goto :set_cmd
for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
echo, 本机IP: %ip%
set/p input=按回车恢复默认字体
if "%input%"=="" (reg delete "HKCU\Console\%%SystemRoot%%_system32_cmd.exe"  /f 2>nul) 
exit

:set_cmd
set reg_key="HKCU\Console\%%SystemRoot%%_system32_cmd.exe" 
reg delete %reg_key% /f 2>nul
reg add %reg_key% /v "WindowPosition" /t REG_DWORD /d 0x01f0064 /f>nul 
reg add %reg_key% /v "WindowSize" /t REG_DWORD /d 0x01190050 /f>nul 
reg add %reg_key% /v "ScreenBufferSize" /t REG_DWORD /d 0xf0190050 /f>nul 
reg add %reg_key% /v "FullScreen" /t REG_DWORD /d 0x00000001 /f>nul 
reg add %reg_key% /v "FontSize" /t REG_DWORD /d 0x00200008 /f>nul
call %~0 CmdSet &exit
复制代码

或者把设置语句单独写成一个脚本，实现这样的效果：运动脚本，如果检测到修改过显示，则恢复，否则修改显示效果。相当于开关，按下开，再按下就关。
而且，在这个设置脚本里调用ip.bat则运行一次就能应用显示效果。

作者: codegay 时间: 2018-1-9 03:52

PowerShell SetConsoleFont Module
https://gallery.technet.microsof ... e-89b7-cc43a860349e

作者: codegay 时间: 2018-1-9 04:01

本帖最后由 codegay 于 2018-1-9 04:03 编辑

SetCurrentConsoleFontEx windows 7支持这个API

https://docs.microsoft.com/en-us ... urrentconsolefontex

作者: hlzj88 时间: 2018-1-9 21:04

试用了二楼的代码，出现问题。

现在我的电脑win7所有的bat，双击bat后，隐藏运行。任务管理器里有，含建文件夹的会建，没有了交互的界面。

请问如何还原。

作者: bbaa 时间: 2018-1-9 21:40

回复 5# hlzj88

set reg_key="HKCU\Console\%%SystemRoot%%_system32_cmd.exe" 
reg delete %reg_key% /f 2>nul
复制代码

保存为bat运行就可以恢复

作者: bbaa 时间: 2018-1-9 21:53

本帖最后由 bbaa 于 2018-1-9 22:10 编辑

回复 5# hlzj88

@echo off
@if Not "%1"=="BigFont" (Goto :BigFont)
COLOR 0A
for /f tokens^=1^,2^ delims^=^"^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do (set "ip=%%b")
echo, 本机IP: %ip%
pause>nul&exit
:BigFont
reg query "HKCU/Console/BigFont">nul 2>nul&&(
	start "BigFont" %ComSpec% /c %~f0 BigFont&exit /b
)||(
	set ran=%random%
	more +16 %~f0>%temp%\%ran%BigFont.reg
	reg import "%temp%\%ran%BigFont.reg">nul 2>nul||(echo 注册表导入失败，请你确定允许导入注册表&pause>nul&exit)
	del /f /q "%temp%\%ran%BigFont.reg">nul 2>nul
	start "BigFont" %ComSpec% /c %~f0 BigFont&exit /b
)
Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Console\BigFont]
"FaceName"="新宋体"
"FontFamily"=dword:00000036
"FontSize"=dword:00180000
"FontWeight"=dword:00000190
"WindowSize"=dword:00020019
复制代码

代码共23行，如测试成功，请不要忘记给我加分
注：本代码只对当前bat有效

作者: zaqmlp 时间: 2018-1-9 23:44

本帖最后由 zaqmlp 于 2018-1-10 12:00 编辑

@echo off
setlocal enabledelayedexpansion
mode con cols=140 lines=10
color 0a
set "#0=  "
set "#1=■■■■"
set "#2=■    ■"
set "#3=■      "
set "#4=      ■"
set "#5=■"
set _#0=1,2,2,2,2,2,1
set _#1=5,5,5,5,5,5,5
set _#2=1,4,4,1,3,3,1
set _#3=1,4,4,1,4,4,1
set _#4=2,2,2,1,4,4,4
set _#5=1,3,3,1,4,4,1
set _#6=1,3,3,1,2,2,1
set _#7=1,4,4,4,4,4,4
set _#8=1,2,2,1,2,2,1
set _#9=1,2,2,1,4,4,1
set _#.=0,0,0,0,0,0,5
for /f tokens^=1^,2^ delims^=^" %%a in ('wmic nicconfig get IPAddress /value ^| findstr /i "IPAddress=[^]"') do set ip=%%b
set s=%ip%fedcba9876543210&set /a len=0x!s:~15,1!-1
echo;本机IP: %ip%
if defined ip (
    for /l %%a in (1 1 7) do (
        for /l %%b in (0 1 %len%) do (
            for %%c in (!ip:~%%b^,1!) do (
                set m=1
                for %%d in (!_#%%c!) do (
                    if !m! equ %%a set "##%%a=!##%%a!!#%%d!  "
                    set /a m+=1
                )
            )
        )
        set line=!##%%a!&echo;!line:~,-1!
    )
)
pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)