@echo off
rem 源目录
set "SrcDir=D:\test"

for /f  "delims=" %%a in ('dir /a-d/s/b "%SrcDir%\*.txt"') do (
	call :read_txt "%%a"
	if exist "%%a.log" move /y "%%a.log" "%%a"
)	
pause&exit

:read_txt
setlocal
set "file=%~1"
(for /f  "delims=" %%b in ('findstr /n ".*" "%file%"') do (
        set "var=%%b"
		setlocal enabledelayedexpansion
        set var=!var:*:=!
		echo;"!var!"|findstr "#">nul&&(endlocal&goto:eof)
		echo;!var!
		endlocal
))>"%file%.log"
endlocal
复制代码

@echo off
rem 源目录
set "SrcDir=D:\test"

for /f  "delims=" %%a in ('dir /a-d/s/b "%SrcDir%\*.txt"') do (
	set line=&set n=
	for /f "delims=[]" %%b in ('find /n "#" ^<"%%a"') do if not defined line set/a line=%%b
	if defined line (
		(for /f "delims=" %%b in ('findstr /n ".*" "%%a"') do (
			set/a n+=1&set "var=%%b"
			setlocal enabledelayedexpansion
			if !n! lss !line! set "var=!var:*:=!"&&echo;!var!
			endlocal
		))>"%%a.log"
		if exist "%%a.log" move /y "%%a.log" "%%a"
	)   
)
复制代码

@echo off
2>nul md "result\"
for /f "delims=" %%a in ('dir /a-d/b *.txt') do (
    echo;"%%a"
    >nul find "#" "%%a"&&(set "file=%%a"&call :loop)||copy "%%a" "result\"
)
pause&exit
:loop
>"result\%file%" (for /f "delims=" %%b in ('findstr /n .* "%file%"') do (
    set "line=%%b"
    setlocal enabledelayedexpansion
    if "!line:#=!" neq "!line!" (
        for /f "delims=#" %%d in ("!line!") do set "endline=%%d"
        echo;!endline:*:=!
        goto :eof
    ) else echo;!line:*:=!
    endlocal
))
复制代码

@echo off
md "result\" 2>nul
powershell "dir . *.txt|%%{$txt=(gc $_.FullName) -join \"`r`n\";$txt -replace '(?s)#.*$',''|out-file ('result\'+$_.Name) -enc default}"
pause
复制代码