@echo off
setlocal enabledelayedexpansion
for /l %%i in (1 1 100) do set /a .%%i=0
for /l %%i in (1 1 99) do (
    for /l %%j in (1 1 100) do (
        set /a mod=%%j%%%%i
        if !mod! equ 0 set /a .%%j=~!.%%j!
    )
)
for /l %%i in (1 1 100) do (
    if not !.%%i! equ 0 set /a num+=1
) 
echo !num!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set /a m=100,r=100
for /l %%a in (1 2 !m!) do (
   set /a x=%%a+1
   set /a .m%%a=1,.m!x!=0
)
for /l %%a in (3 1 !r!) do (
   for /l %%b in (%%a %%a !m!) do set /a .m%%b="^!(!.m%%b!)"
)
for /f "tokens=1,2 delims=.m=" %%a in ('set .') do (
   if %%b equ 1 echo 开着的门编号为: %%a&set /a hj+=1
)
echo,&echo,共 !hj! 个
pause
复制代码

@echo off
setlocal enabledelayedexpansion
::第一个服务员打开所有窗户，打开为1，关上为0
for /l %%i in (1,1,100) do (
set /a _%%i=1
)

::第二人关编号为2的倍数之窗。第三人操作编号为3的倍数之窗，开的关，关的开...
for /l %%i in (2,1,100) do (
  set /a n=100 / %%i
  for /l %%j in (1,1,!n!) do (
  set /a c=%%i*%%j
  call set b=%%_!c!%%
  if !b! equ 1 (set /a _!c!=0) else set /a _!c!=1
  )
)
::符合条件输出
for /l %%i in (1,1,100) do (
if !_%%i! equ 1 (
set /a num+=1
echo %%i
)
)
echo !num!个窗打开的
pause>nul
复制代码

 
@echo off&setlocal enabledelayedexpansion
set /p m=输入一个数：
set /a L1=0,L0=1
for /l %%a in (1 1 !m!) do (set V%%a=1)
for /l %%a in (2 1 !m!) do (
    for /l %%b in (%%a,%%a,!m!) do (
        set/a V%%b=L!V%%b!
    )
)
set n=0
set /p= 开着的门编号为:<nul
for /l %%a in (1 1 !m!) do (
    if !V%%a! equ 1 (set/p=%%a <nul&set/a n+=1)
)
echo,&echo,共 !n! 个
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set /p m=输入一个数：
set tim=!time!
set 开=关
set 关=开
for /l %%a in (1 1 !m!) do (set v%%a=开)
for /l %%a in (2 1 !m!) do (
    for /l %%b in (%%a,%%a,!m!) do (
        for %%c in (!V%%b!) do set V%%b=!%%c!
    )
)
set n=0
echo 开着的门编号为:
for /l %%a in (1 1 !m!) do (
    if !V%%a! equ 开 (set str=!str! %%a<NUL&SET n+="1)
 )
echo !str!
echo 共 !n! 个
pause
复制代码