批处理之家 - Powered by Discuz! Board

标题: 批处理怎样更改图片的名称，从零开始命名？ [打印本页]

作者: z0x0d0 时间: 2018-6-4 13:14 标题: 批处理怎样更改图片的名称，从零开始命名？

求助各位大神：
文件夹里的图片是从PPT里导出的图片，原图片名是，幻灯片1-幻灯片2-幻灯片3-幻灯片4-幻灯片5-...幻灯片9-幻灯片10...幻灯片11.......
我想命名成这样子的（从0开始，幻灯片000-幻灯片001-幻灯片002-幻灯片003....幻灯片009-幻灯片010-幻灯片011......）
也就是从0开始呢！

多谢大家帮助！

作者: Batcher 时间: 2018-6-4 13:38

执行之前注意把原始图片做好备份
test.bat

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b 幻灯片*.jpg') do (
    set FileName=%%~ni
    set FileNum=1000!FileName:幻灯片=!
    set /a FileNum-=1
    set FileNum=!FileNum:~-3!
    ren %%i 幻灯片!FileNum!%%~xi
)
复制代码

作者: z0x0d0 时间: 2018-6-4 13:54

真的非常非常感谢

作者: z0x0d0 时间: 2018-6-4 14:16

回复 2# Batcher

大概有100多个文件夹，每个文件夹里是PPT图片，把bat文件，都放至每个文件夹里修改图片排序，等于我复制100多次BAT文件，还要点运行。老大，有没有在方便的方法，直接大范围的批处理一下！
在此，感谢了！

作者: 窄口牛 时间: 2018-6-4 14:36

描述清楚才行，不然他也不是神仙。-

作者: Batcher 时间: 2018-6-4 14:49

回复 4# z0x0d0

test.bat 放在 C:\100多个文件夹所在目录\ 这个目录下面

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s "C:\100多个文件夹所在目录\幻灯片*.jpg"') do (
    set FileName=%%~ni
    set FileNum=1000!FileName:幻灯片=!
    set /a FileNum-=1
    set FileNum=!FileNum:~-3!
    ren %%i 幻灯片!FileNum!%%~xi
)
复制代码

作者: z0x0d0 时间: 2018-6-4 16:26

回复 6# Batcher

bat,放在C盘，文件夹目录，代码3行也改成C盘的目录，双击一下bat怎么提示命令语法错误啊。

作者: yhcfsr 时间: 2018-6-4 16:49

本帖最后由 yhcfsr 于 2018-6-4 17:01 编辑

回复 7# z0x0d0

我看不下去了.
麻烦把改的代码发上来,把运行错误截图也发上来.

假设所有图片及其文件夹放在c:\ab123目录下,bat文件随便放哪

@echo off
set "dd=c:\ab123"
for /f "delims=" %%i in ('dir /a-d/b/s "%dd%\*.jpg"') do (
    set "FileName=%%~ni"
    setlocal enabledelayedexpansion
    set "FileNum=1000!FileName:幻灯片=!"
    set/a "FileNum-=1"
    set "FileNum=!FileNum:~-3!"
    ren "%%i" "幻灯片!FileNum!%%~xi"
    endlocal
)
pause
复制代码

作者: Batcher 时间: 2018-6-4 16:52

回复 7# z0x0d0

不要双击执行。打开CMD窗口，输入bat完整路径，回车执行，这样可以看到具体报错信息。

作者: 窄口牛 时间: 2018-6-4 16:52

就不告诉你，就不告诉你，就不告诉你

欢迎光临批处理之家 (http://bbs.bathome.net/)