批处理之家 - Powered by Discuz! Board

标题: 20元红包奖励，请大神写命令复制当天生成的文件 [打印本页]

作者: fengzi1014 时间: 2018-10-13 16:06 标题: 20元红包奖励，请大神写命令复制当天生成的文件

要求：
1.批处理命令。
2.复制本地文件F:\beifen\OA中所生成的增量文件，每天会生成2-3个新文件。
3.粘贴到局域网内另一台电脑\\192.168.51.153\bf文件夹中用户名admin密码123，并且新建一个文件夹以日期年月日命名

作者: zaqmlp 时间: 2018-10-13 16:10

本帖最后由 zaqmlp 于 2018-10-13 16:12 编辑

@echo off
for /f %%a in ("%date%") do set day=%%a
set d=%day:/=-%
set d=%d:-=.%
set d=%d:.=%
cd /d "F:\beifen\OA"
for /f "delims=" %%a in ('dir /a-d /b') do (
    for /f %%b in ("%%~ta") do (
        echo;"%%b"  "%day%"
        if "%%b" equ "%day%" (
            if not exist "\\192.168.51.153\bf\%d%\" md "\\192.168.51.153\bf\%d%\"
            copy "%%a" "\\192.168.51.153\bf\%d%\"
            >>"F:\bfrz\result.log" echo;%%~ta "%%a"
        )
    )
)
pause
复制代码

作者: fengzi1014 时间: 2018-10-13 16:14

回复 2# zaqmlp

代码只能复制一个文件啊，如果产生两个文件，直接不复制啊

作者: Batcher 时间: 2018-10-13 16:24

回复 3# fengzi1014

echo "%%a" "%%b" "%day%"
第9行改成这样，把执行结果发出来看看是哪里出问题了。

作者: Batcher 时间: 2018-10-13 16:56

@echo off
for /f %%a in ("%date%") do set day=%%a
set d=%day:/=-%
set d=%d:-=.%
set d=%d:.=%
if not exist "\\192.168.51.153\bf\%d%\" md "\\192.168.51.153\bf\%d%\"
for /f "delims=" %%a in ('forfiles /p "F:\beifen\OA" /s /m *.* /d +0 /c "cmd /c echo @path"') do (
    copy "%%a" "\\192.168.51.153\bf\%d%\"
    >>"F:\bfrz\result.log" echo;%%~ta "%%a"
)
复制代码

作者: lifei259 时间: 2018-10-19 09:19

本帖最后由 lifei259 于 2018-10-19 09:38 编辑

@echo off
set d=%date:~0,4%%date:~5,2%%date:~8,2%
set dd=%date:~0,4%-%date:~8,2%-%date:~5,2%
set a=\\192.168.51.153\bf
net use %a% "123" /user:admin
xcopy /e /i /h /y /a /r /f /d:%dd%  "F:\beifen\OA\*.*" "%a%\%d%"
pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)