批处理之家 - Powered by Discuz! Board

标题: [文本处理] 请高人改一下批处理在文本头部增加内容 [打印本页]

作者: yjqrsyg 时间: 2018-12-12 12:41 标题: 请高人改一下批处理在文本头部增加内容

这个命令是本论坛上找到的,原本是为批量文本在尾部增加内容的,我想把它改成在文本头部增加内容,请高人改一下,本人小白,谢谢了!

大概意思如下:
大致是这样的，
有101个TXT文件，其中有一个all.txt里有1000行，其它100个1.txt, 2.txt,...,100.txt，每个里面都是一篇小短文。
现在我想
每次随机从all.txt这1000行里取10行，添加到其它100个TXT文件中的某一个，直到这100个TXT文件每个都被添加过一次。
（每次随机抽取的10行数据可以有重复的行）

下面的这个命令是增加在尾部的,我试过了,好用,现在想把内容增加在头部,请高人改一下,谢谢

@echo off&setlocal enabledelayedexpansion
set m=1000
for /f "delims=" %%i in (all.txt) do set /an+=1&set #!n!=%%i
for /f "delims=" %%i in ('dir /b /a-d *.txt ^| findstr /ivx "all\.txt"') do (
    (for /l %%a in (1 1 10) do (
        set /a n=!random!%%m+1
        for %%b in (!n!) do echo !#%%b!
    ))>>"%%i"
)
pause
复制代码

作者: flashercs 时间: 2018-12-12 13:12

本帖最后由 flashercs 于 2018-12-12 13:48 编辑

@echo off&setlocal enabledelayedexpansion
set m=1000
set "tmpFile=%temp%\$%random%.tmp"
for /f "delims=" %%i in (all.txt) do set /a n+=1&set #!n!=%%i
for /f "delims=" %%i in ('dir /b /a-d *.txt ^| findstr /ivx "all\.txt"') do (
    copy /y nul "%tmpFile%"
    (for /l %%a in (1 1 10) do (
        set /a n=!random!%%m+1
        for %%b in (!n!) do echo !#%%b!
    ))>>"%tmpFile%"
    copy /y /b "%tmpFile%"+"%%i" "%tmpFile%"
    copy /y "%tmpFile%" "%%i"
)
del /f /q "%tmpFile%"
pause
复制代码

作者: yjqrsyg 时间: 2018-12-12 13:27

回复 2# flashercs

谢谢,我刚才用了一下,出现一个问题:原文本中的内容全被删掉了,这个不是我想要的呀

作者: flashercs 时间: 2018-12-12 13:51

回复 3# yjqrsyg

改了

作者: yjqrsyg 时间: 2018-12-12 14:07

回复 4# flashercs

果然好用,谢谢,太感谢了,高人就是高人,

欢迎光临批处理之家 (http://bbs.bathome.net/)