批处理之家 - Powered by Discuz! Board

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓　　▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　▓▓▓　　　　　　　　　　▓▓
　　　　　　　　　　　　　　　　　　　▓▓▓　　　　　　　　　▓▓
　　　　　　　　　　　　　　　　　　　　▓▓▓　　　　　　　　▓▓▓▓▓▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓▓▓▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓　　　　　▓▓
　　　　　　　　　　　　　　　　　　　　　　▓　　　　　▓▓　　　　　▓▓▓
　　　　　　　　　　　　　　　　　　　　　　▓　　　　　▓▓　　　　　　▓▓▓
　　　　　　　　　　　　　　　　　　　　　▓　　　　　▓▓　▓　　　　　　▓▓
　　　　　　　　　　　　　　　　　　　　▓▓　　　　▓▓　　▓▓
　　　　　　　　　　　　　　　　　　　　▓　　　　▓▓　　　▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　▓▓　　　　　　　　　▓▓　　▓▓▓
　　　　　　　　　　　　　　　　　　▓▓▓　　　　　　　　▓▓　　　▓▓
　　　　　　　　　　　　　　　　　　▓▓　　　　　　　　▓▓▓　　　▓▓
　　　　　　　　　　　　　　　　▓▓▓▓　　　　　　　　▓▓▓▓　▓▓
　　　　　　　　　　　　　　　　　▓▓　　　　　　　　▓▓　　　▓▓▓
　　　　　　　　　　　　　　　　　▓▓　　　　　　　▓▓　　　　▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　▓▓　　　　　▓▓　▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　▓▓　　　　　▓▓　　　▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　▓　　　　　　▓▓　　　　　　▓▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　　　▓　　　　　　　　　▓▓▓▓▓▓▓▓
　　　　　　　　　　　　　　　　　　　　　　　　　　▓▓
比如上面的这个点阵字用 "点阵编码_生成器.bat" 转换后的代码为:
编码:
30 -3 / 31 -3 /# 3 31 -2 / 31 -2 2 -1 / 31 -6 / 28 -6 / 18 -3 10 -2 / 19 -3 9 -2 / 20 -3 8 -11 / 28 -10 / 24 -6 / 28 -1 5 -2 / 22 -1 5 -2 5 -3 / 22 -1 5 -2 6 -3 / 21 -1 5 -2 1 -1 6 -2 / 20 -2 4 -2 2 -2 / 20 -1 4 -2 3 -6 / 19 -2 9 -2 2 -3 / 18 -3 8 -2 3 -2 / 18 -2 8 -3 3 -2 / 16 -4 8 -4 1 -2 / 17 -2 8 -2 3 -3 / 17 -2 7 -2 4 -4 / 24 -2 5 -2 1 -3 / 23 -2 5 -2 3 -5 / 22 -1 6 -2 6 -7 / 28 -1 9 -8 / 26 -2 /

复制代码

@Echo off&color a
Title ☆Title 点阵编码生成器　-By 凌枫工作组 Q群:35962310-
setlocal EnableDelayedExpansion
set S=　　　　
Rem 设置 ↓
SET 换行符=/
SET 循环符=#
Rem 设置↑
:输入文档路径
If "%1" == "" (
FOR /L %%S IN (1,1,7) Do echo.
Echo %S%%S%请将你要转换的点阵字本文文档直接拖到本批处理上.
FOR /L %%S IN (1,1,5) Do echo.
Echo %S%%S%请在没有空格与特殊字符的路径下操作.
pause>nul&Exit
)
call :获取前背景 %1
:检测前背景
cls
FOR /L %%S IN (1,1,5) Do echo.
Echo %S%你的点阵字的前景为[%前景%],背景为[%背景%]
echo.
Echo %S%注意：文档中的前背景字符的全半角要一致。
FOR /L %%S IN (1,1,4) Do echo.
Echo %S%如果是请[直接回车],如果不是请按顺序输入你的前景与背景.
FOR /L %%S IN (1,1,3) Do echo.
SET /P 请输入=%S%请确认:
if /i Not "%请输入%" == "" (
set 前景=!请输入:~0,1!
set 背景=!请输入:~1,1!
Goto 检测前背景
)
Rem 检测前背景↑
Rem 主体开始↓
Set 循环次数=1
set 循环次数编码=1
cls
FOR /L %%S IN (1,1,11) Do echo.
Echo %S%%S%%S%正在转换请稍后.......
for /f "tokens=*" %%i in ('type "%1"') do (
set Line=%%i
if Not "!Line!" == "!BLine!" (
if Not "!需循环编码!" == "" call :替换需循环编码
call :获取当前行编码
) else (
If "!开始行数!" == "" Set 开始行数=!行数!
Set /a 循环次数=!循环次数!+1
set /a 循环次数编码=!循环次数编码!+1
if "!需循环编码!" == "" Call :获取需循环编码
)
set BLine=%%i
set /a 行数=!行数!+1
)
for %%I in (%1) do (
FOR /L %%S IN (1,1,2) Do echo.>>"%%~dI%%~pI%%~nI_点阵编码.txt"
echo %编码%>>"%%~dI%%~pI%%~nI_点阵编码.txt"
cls
FOR /L %%S IN (1,1,11) Do echo.
Echo %S%%S%%S%　　转换已顺利完成!
FOR /L %%S IN (1,1,5) Do echo.
echo %S%编码已存入 "%%~dI%%~pI%%~nI_点阵编码.txt" 按任意键退出...&pause>nul&Exit
)
Exit
Rem 主体结束↑
:获取前背景
for /f "tokens=*" %%i in ('type "%1"') do (
set "str=%%i"
if not defined 背景 set 背景=!str:~,1!
call,set 前景=%%str:!背景!=%%
if defined 前景 (set "前景=!前景:~,1!"&goto :eof)
)
goto :eof
:获取需循环编码
if "%已执行过一次%" == "Y" (Set /a 开始行数=%开始行数%-%循环次数%+2&set /a 循环次数编码=%循环次数编码%+1) Else (Set 已执行过一次=Y)
For /F "tokens=%开始行数% delims=%换行符%" %%c in ("%编码%") do Set 需循环编码=%%c
GOTO :EOF
:替换需循环编码
set 编码=!编码:%换行符%%需循环编码%%换行符%=!
set 编码=%编码%%换行符%%循环符% %循环次数编码%%需循环编码%%换行符%
set 开始行数=
set 需循环编码=
set 循环次数编码=
GOTO :EOF
:获取当前行编码
if Not "%本次负编码%" == "" set 编码=%编码%%本次正编码%
if Not "%本次正编码%" == "" set 编码=%编码%%本次负编码%
set 本次正编码=&set 本次负编码=
set 本次列数=0&set 下个列数=0
set 本次字符=&set 下个字符=
:继续获取
set 本次字符=!Line:~%本次列数%,1!
set /a 本次列数=%本次列数%+1
set 下个字符=!Line:~%本次列数%,1!
if Not "%本次字符%" == "%前景%" (
set /a 本次正编码=%本次正编码%+1
if not "%编码%" == "%编码%%本次负编码%" Set 编码=%编码%%本次负编码% &set 本次负编码=
) else (
if Not "%本次字符%" == "%背景%" (
set /a 本次负编码=%本次负编码%-1
if Not "%编码%" == "%编码%%本次正编码%" Set 编码=%编码%%本次正编码% &set 本次正编码=
)
)
if "%本次字符%" == "" (
set 编码=%编码%%换行符%&Goto :EOF
) else (
Goto 继续获取
)

复制代码

@echo off&setlocal enabledelayedexpansion
call :前背景 %1
echo --%前景%--%背景%--&pause&exit
:前背景
for /f "usebackq delims=" %%i in ("%~1") do (
set "str=%%i"
if not defined 背景 set 背景=!str:~,1!
call,set 前景=%%str:!背景!=%%
if defined 前景 (set "前景=!前景:~,1!"&goto :eof)
)
goto :eof

复制代码

@Echo off&color a&setlocal EnableDelayedExpansion
set echo=
if defined %1 echo;echo;&(FOR /L %%S IN (1,1,6) Do echo.
echo %echo% 生成器
Echo %echo%请将你要转换的点阵字本文文档直接拖到本批处理上.
FOR /L %%S IN (1,1,5) Do echo.
Echo %echo%请在没有空格与特殊字符的路径下操作.
pause>nul&Exit)
for /f "delims=" %%a in (%~1) do (
set str=%%a
if not defined 背景 set 背景=!str:~,1!
for %%b in ("!背景!") do (set str=!str:%%~b=!)
if defined str set 前景=!str:~,1!&goto :ok
)
:ok
set "asc=０1234567890ＡＢＣＤＥ'ＦＧＨＩ@#$.abcdefghijklmnopqrstuvwxyz"
for /l %%a in (0,1,50) do (set #!asc:~%%a,1!=%%a&set $%%a=!asc:~%%a,1!)
set dec=
for /f "delims=" %%a in (%~1) do (
set str=%%a
set str=!str:%背景%=0!
set str=!str:%前景%=1!
set str=!str:01=0 1!
set str=!str:10=1 0!
if "!str:~,1!" equ "1" (set dec=!dec! `) else (set dec=!dec! )
for %%b in (!str!) do (
set var=!asc!%%b
set /a vum=#!var:~-51,1!
for %%c in (!vum!) do (set dec=!dec!!$%%c!)
)
)
echo !背景!!前景!!dec!>%~dp1\bendec.txt
pause

复制代码

@Echo off&color a&setlocal EnableDelayedExpansion
set echo=
if defined %1 echo;echo;&(FOR /L %%S IN (1,1,7) Do echo.
echo %echo% 解释器
Echo %echo%请将你要转换的点阵字本文文档直接拖到本批处理上.
FOR /L %%S IN (1,1,5) Do echo.
Echo %echo%请在没有空格与特殊字符的路径下操作.
pause>nul&Exit)
set "asc=０1234567890ＡＢＣＤＥ'ＦＧＨＩ@#$.abcdefghijklmnopqrstuvwxyz"
for /l %%a in (0,1,50) do (set #!asc:~%%a,1!=%%a)
for /l %%a in (1,1,10) do (set spac=!spac! )
Mode con cols=127 lines=44
set #前景=背景&set #背景=前景
for /f "delims=" %%a in (%~1) do (
set str=%%a
for /f "tokens=1,2 delims=*" %%l in ("!str:~0,1!*!str:~1,1!") do (set 前景=!spac: =%%l!&set 背景=!spac: =%%m!)
set str=!str:~2!
for %%b in ("!str: =" "!") do (
set str=%%~b
if "!str:~,1!" equ "~" (set 当前=背景) else (set 当前=前景)
set num=!asc!!str!
set /a vum=#!num:~-50,1!
for /l %%c in (0,1,!vum!) do (
for %%d in ("!str:~%%c,1!") do (
for /f "tokens=1,2" %%e in ("!当前! !#%%~d!") do (
set /p=!%%e:~,%%f!<nul
set 当前=!#%%e!
)
)
)
echo;
)
)
pause

复制代码