批处理之家 - Powered by Discuz! Board

标题: [文件操作] 【已解决】求助批处理：批量合并某一目录下其子目录中的pdf [打印本页]

作者: 星风涯 时间: 2019-5-5 03:53 标题: 【已解决】求助批处理：批量合并某一目录下其子目录中的pdf

求助：子文件夹中的bat批量运行
需求：
某一文件目录下，有很多子文件夹，子文件夹中也有很多子文件夹，有一部分子文件夹中含有一个批处理的程序，怎么能运行该文件夹及所有子文件中的全部bat程序。
找了一些方法总是出现问题，麻烦各位大神能解决下，谢谢

作者: 星风涯 时间: 2019-5-5 04:17 标题: 求助：批量合并某一目录下其子目录中的pdf

需求：
某一目录下有很多嵌套的子文件夹，在最后一级的子文件夹中有1个或者多个pdf文件，需要将这些子目录下的pdf合并成一个新的PDF，并保存在其原目录下（合并后的pdf名称最好能以其上级文件夹的名称命名）。合并完pdf后，原pdf文件最好能进行删除，需注意只有一个pdf文件的可以生成新的合并pdf，或者保留原始pdf。

作者: Batcher 时间: 2019-5-5 12:37

回复 1# 星风涯

@echo off
for /f "delims=" %%i in ('dir /b /s /a-d "*.bat"') do (
    if "%%i" neq "%~f0" (
        echo %%i
        pushd "%%~dpi"
        call "%%i"
        popd
    )
)
复制代码

作者: 星风涯 时间: 2019-5-5 16:14

回复 3# Batcher

您写的代码可以批量运行子文件夹中的bat程序，非常感谢。您这边能看下2楼我写的提问么？其实我是想合并子文件夹下的pdf，因没有找到方法，才采取了这种复制bat到各个目录然后批量运行的。麻烦您再帮我看下，谢谢。

作者: zaqmlp 时间: 2019-5-5 18:20

本帖最后由 zaqmlp 于 2021-11-23 11:26 编辑

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
title %info%
cd /d "%~dp0"
for %%a in ("libiconv2.dll" "pdftk.exe") do (
    if not exist "%%~a" (echo;"%%~a" not found&pause&exit)
)
for /f "delims=" %%a in ('dir /ad/b/s') do (
    if exist "%%a\*.pdf" (
        echo;"%%a"
        pushd "%%a"
        set "f="
        "%~dp0pdftk.exe" *.pdf cat output "%%~nxa.tmp" 2>nul||(set f=1)
        if not defined f (
            del /a /f /q *.pdf
            ren "%%~nxa.tmp" "%%~nxa.pdf"
        )
        popd
    )
)
echo;%info%
pause
复制代码

作者: zaqmlp 时间: 2019-5-6 00:35

感谢还是赞助实际点

欢迎光临批处理之家 (http://bbs.bathome.net/)