╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
┋ BAT文件选择器，输入字母后请按下回车键  ┋
┋                                        ┋
┋(0)  1.bat                              ┋
┋(1)  2.bat                              ┋
┋                                        ┋
┋(x)  Exit                               ┋
╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
请输入：
复制代码

╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
┋ BAT文件选择器，输入字母后请按下回车键  ┋
┋                                        ┋
┋(0)  2.bat                              ┋
┋                                        ┋
┋(x)  Exit                               ┋
╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
请输入：
复制代码

@echo off
setlocal enabledelayedexpansion
cls>nul
set /a item=8
set "self=%0"
set "self=!self:~1,-1!"
for /r .\ %%c in (*.bat) do (
    set /a item+=1
)
mode con: cols=45 lines=%item%
if "%1"=="h" (
    for /r %%a in (*.bat) do (
        if NOT %%a==!self! echo %%~nxa
    )
    echo;
    exit
)
set "table=0123456789abcdefghijklmnopqrstuvwyz"
set "table2=!table!"&set /a z=35
for /r %%b in (*.bat) do (
    if NOT %%b==!self! (
        set /a count+=1
        if !count! EQU 36 goto make
        set ".!table2:~0,1!=%%b"&set "table2=!table2:~1!"
    )
)
:make
for /f "delims=" %%a in ('%0 h^|findstr /o .*') do (
    if !hh! EQU 35 goto loop
    for /f "delims=:" %%i in ("%%a") do set /a n=%%i-2-h,h=%%i
    if defined var (
        set /a jj=z-n,hh+=1&set "k="
        set "mm=!table:~0,1!"&set "table=!table:~1!"
        if !jj! GTR 0 (
            for /l %%i in (1 1 !jj!) do set "k= !k!"
        ) else (
            if !jj! LSS 0 (
                set "var=!var:~0,19!"&set "var=!var:*:=!"
                for /f "skip=1 delims=:" %%m in ('^(echo."!var!"^&echo.^)^|findstr /o .') do (
                    set /a Bytes=35-%%m+5
                )
                for /l %%n in (1 1 !Bytes!) do set "k= !k!"
            )
        )
        set #!hh!=┋^(!mm!^)  !var:*:=!!k!┋
    )
    set "var=%%a"
)
:loop
echo ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo ┋ BAT文件选择器，输入字母后请按下回车键  ┋
echo ┋                                        ┋
for /l %%a in (1 1 !hh!) do echo !#%%a!
echo ┋                                        ┋
echo ┋(x)  Exit                               ┋
echo ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
echo;&set num=&set /p num=请输入： &cls
if /i "%num%"=="x" exit
start "" "!.%num%!"
goto loop
复制代码