批处理之家 - Powered by Discuz! Board

标题: [文件操作] [分享]批处理依次进入指定路径下所有目录 [打印本页]

作者: Batcher 时间: 2019-11-5 19:08 标题: [分享]批处理依次进入指定路径下所有目录

【问题】
请教下各位前辈怎么可以依次进入指定路径下所有目录并进入这些目录

【代码】

@echo off
cd /d "E:\science\DOS"
for /f "delims=" %%i in ('dir /b /ad') do (
    echo 已经进入目录：%%i
    echo 执行其它命令
)
pause
复制代码

作者: Batcher 时间: 2019-11-5 19:42

【问题2】
请教下前辈我这样写为什么不能进入遍历出来的子目录呢

@echo off
set work_path=E:\science\DOS
cd %work_path%
for /R %%s in (.,*) do (
echo %%s
set inputdir="%%s"
::echo %inputdir%
cd %inputdir%
chdir
)
pause
复制代码

【代码2】
启用变量延迟扩展，参考：
http://bbs.bathome.net/thread-2899-1-1.html

@echo off
setlocal enabledelayedexpansion
set "work_path=E:\science\DOS"
cd /d "%work_path%"
for /r %%s in (.) do (
    echo %%s
    set "inputdir=%%s"
    cd "!inputdir!"
    echo 当前所在目录：!cd!
)
pause
复制代码

作者: Batcher 时间: 2019-11-6 12:37

【问题3】
为什么cd进不去目录呢
提示找不到指定路径

【代码3】

@echo off
cd /d "E:\science\DOS"
for /f "delims=" %%i in ('dir /b /ad') do (
    echo 正在处理目录：%%i
    echo --- 文件列表：
    dir /b "%%i"
    copy "%%i\*03.txt" "E:\science\DOS"
)
pause
复制代码

作者: 日久生尘 时间: 2019-11-6 14:31

请教下老师为什么我的代码cd进不去目录，提示找不到指定路径？
@echo off
cd /d "E:\science\DOS"
for /f "delims=" %%i in ('dir /s /b /ad') do (
echo 已经进入目录：%%i
cd /d "%%i\"
echo cd /d "%%i"

)
pause

作者: Batcher 时间: 2019-11-6 23:24

回复 4# 日久生尘

REM @echo off
cd /d "E:\science\DOS"
for /f "delims=" %%i in ('dir /s /b /ad') do (
    echo 已经进入目录：%%i
    cd /d "%%i\"
    echo cd /d "%%i"
    REM copy %%i\*03.txt E:\science\DOS
    REM echo 执行其它命令
)
pause
复制代码

for循环内部不要使用::把它改成REM

欢迎光临批处理之家 (http://bbs.bathome.net/)