批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]特定文件、特定行替换如何进行批处理？ [打印本页]

作者: wwenyunkui 时间: 2009-8-4 14:29 标题: [已解决]特定文件、特定行替换如何进行批处理？

现有文件介绍1、系列文件1.txt~40.txt
文件1.txt内容如下

<?xml version="1.0" encoding="gb2312"?>
<root>
<PackTypeInfo PackType="188字节"/>
<IPInfo IP="192.168.0.1" IPMask="255.255.255.0" GateWay="192.168.0.1" MAC="00-00-01-01-00-04"/>
<DeModule Freq="714000000" SymbolRate="6875000"/>
<CodeInfo CodeAddress="224.1.0.1" CodePort="5001" AnalysisAddress="224.2.0.1" AnalysisPort="5000"/>
<CheckReset Reset="1"/>
</root>
复制代码

文件2.txt内容如下

<?xml version="1.0" encoding="gb2312"?>
<root>
<PackTypeInfo PackType="188字节"/>
<IPInfo IP="192.168.0.2" IPMask="255.255.255.0" GateWay="192.168.0.1" MAC="00-00-01-01-00-05"/>
<DeModule Freq="714000000" SymbolRate="6875000"/>
<CodeInfo CodeAddress="224.1.0.2" CodePort="5001" AnalysisAddress="224.2.0.2" AnalysisPort="5000"/>
<CheckReset Reset="1"/>
</root>
复制代码

以此类推

2、文件mac.txt内容：

00-01-00-00-00-01
00-01-00-00-00-02
00-01-00-00-00-03
00-01-00-00-00-04
00-01-00-00-00-05
00-01-00-00-00-06
00-01-00-00-00-07
00-01-00-00-00-08
00-01-00-00-00-09
00-01-00-00-00-0a
00-01-00-00-00-0b
00-01-00-00-00-0c
00-01-00-00-00-0d
00-01-00-00-00-0e
00-01-00-00-00-0f
00-01-00-00-00-10
00-01-00-00-00-11
00-01-00-00-00-12
00-01-00-00-00-13
00-01-00-00-00-14
00-01-00-00-00-15
00-01-00-00-00-16
00-01-00-00-00-17
00-01-00-00-00-18
00-01-00-00-00-19
00-01-00-00-00-1a
00-01-00-00-00-1b
00-01-00-00-00-1c
00-01-00-00-00-1d
00-01-00-00-00-1e
00-01-00-00-00-1f
00-01-00-00-00-20
00-01-00-00-00-21
00-01-00-00-00-22
00-01-00-00-00-23
00-01-00-00-00-24
00-01-00-00-00-25
00-01-00-00-00-26
00-01-00-00-00-27
00-01-00-00-00-28
复制代码

最终目的：
将1.txt中的MAC="00-00-01-01-00-04"中双引号内的内容替换为mac.txt的第一行
将2.txt中的MAC="00-00-01-01-00-05"中双引号内的内容替换为mac.txt的第二行
以此类推
请各位帮忙解决，谢谢
需求稍有变化，红色是变动部分

[ 本帖最后由 wwenyunkui 于 2009-8-5 11:23 编辑 ]

作者: terse 时间: 2009-8-4 16:02

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (mac.txt) do set /a n+=1&set _!n!=%%i
set "v=00-00-01-01-00-04"
    for /f "delims=" %%a in ('dir /b /a-d *.txt^|find /v "mac.txt"') do (
       set/a m+=1
       for %%b in (!m!) do set t=!_%%b!
      (for /f "usebackq delims=" %%i in ("%%a") do (
          set "str=%%i"
          for %%b in (!t!) do set str=!str:%v%=_%%b!
          echo !str!
          ))>~tem
          move /y ~tem "%%a"
    )
pause
复制代码

作者: wwenyunkui 时间: 2009-8-4 16:51

原帖由 terse 于 2009-8-4 16:02 发表
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (mac.txt) do set /a n+=1&set _!n!=%%i
set "v=00-00-01-01-00-04"
for /f "delims=" %%a in ('dir /b /a-d *.txt^|find /v "mac.txt"' ...

非常感谢您的解答，目标是达到了，不过有一点遗憾：
1、在'dir /b /a-d *.txt时并不是按照数字1~40的顺序进行遍历所有txt文件的，最终结果导致1.txt文件中的“00-00-01-01-00-04”被替换为“_00-01-00-00-00-01”，而2.txt中的“00-00-01-01-00-04”被替换为“_00-01-00-00-00-0c”
2、“_00-01-00-00-00-0c”前面多了一个下划线

作者: terse 时间: 2009-8-4 17:15

原帖由 wwenyunkui 于 2009-8-4 16:51 发表

非常感谢您的解答，目标是达到了，不过有一点遗憾：
1、在'dir /b /a-d *.txt时并不是按照数字1~40的顺序进行遍历所有txt文件的，最终结果导致1.txt文件中的“00-00-01-01-00-04”被替换为“_00-01-00-00-00-01” ...

确定文件名的话是否可以这样
_00 这里多余了_ 改str=!str:%v%=_%%b! 为 str=!str:%v%=%%b!

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (mac.txt) do set /a n+=1&set _!n!=%%i
set "v=00-00-01-01-00-04"
    for /l %%a in (1 1 40) do (
      (for /f "usebackq delims=" %%i in ("%%a.txt") do (
          set "str=%%i"
          for %%b in (!_%%a!) do set str=!str:%v%=%%b!
          echo !str!
          ))>~tem
          move /y ~tem "%%a.txt"
    )
pause
复制代码

[ 本帖最后由 terse 于 2009-8-4 17:16 编辑 ]

作者: wwenyunkui 时间: 2009-8-4 17:39

原帖由 terse 于 2009-8-4 17:15 发表

确定文件名的话是否可以这样
_00 这里多余了_ 改str=!str:%v%=_%%b! 为 str=!str:%v%=%%b!@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (mac.txt) do set /a n+=1&set _!n!=%%i
set ...

不过对应关系还是不正确

作者: terse 时间: 2009-8-4 18:20

原帖由 wwenyunkui 于 2009-8-4 17:39 发表
不过对应关系还是不正确

这个应该对应的啊
1-40.txt 就是对应 1-40行啊

作者: netbenton 时间: 2009-8-4 19:55

 
@echo off&setlocal enabledelayedexpansion
set asc=0123456789abcdef
set /a n=1,m=4
md temp

for /f "delims=" %%a in (mac.txt) do (
    set/p h2=m%%16,h1=m/16
    for /f "tokens=1,2" %%1 in ("!h1! !h2!") do (set h1=!asc:~%%1,1!&set h2=!asc:~%%2,1!)
    echo 处理文件!n!.txt
    (for /f "delims=" %%b in (!n!.txt) do (set str=%%b
        for %%k in (00-00-01-01-00-!h1!!h2!) do echo;!str:%%k=%%a!
    ))>>temp\!n!.txt
    set /a n+=1,m+=1
)
echo 更新文件存入temp目录
pause
复制代码

作者: zqz0012005 时间: 2009-8-4 21:01 标题: JavaScript

注意是不可逆操作，使用前请自行备份。

//&@cls&start wscript.exe -e:jscript "%~f0"&exit/b
fso = new ActiveXObject('Scripting.FileSystemObject');
omac = fso.OpenTextfile('mac.txt');
for (i=1;i<=40;i++) {
  s = fso.OpenTextfile(i+'.txt').ReadAll();
  fso.OpenTextfile(i+'.txt',2).Write ( 
    s.replace(/(MAC=")[\da-f-]{17}/gi, '$1'+omac.ReadLine()) );
}
复制代码

作者: wwenyunkui 时间: 2009-8-5 08:22 标题: 回复 7楼的帖子

感谢您的解答，不过结果和terse兄给的方法最终结果一样，不能按照既定顺序替换
即1.txt文件中的00-00-01-01-00-04被（mac.txt文件中的第一行）替换成00-01-00-00-00-01
2.txt文件中的00-00-01-01-00-05被（mac.txt文件中的第一行）替换成00-01-00-00-00-02

作者: wwenyunkui 时间: 2009-8-5 08:23

原帖由 zqz0012005 于 2009-8-4 21:01 发表
注意是不可逆操作，使用前请自行备份。//&@cls&start wscript.exe -e:jscript "%~f0"&exit/b
fso = new ActiveXObject('Scripting.FileSystemObject');
omac = fso.OpenTextfile('mac.txt');
for (i=1;i

多谢斑竹
只是不懂javascript如何实现？菜了些，勿怪

作者: Batcher 时间: 2009-8-5 08:52 标题: 回复 10楼的帖子

都是一些基本的操作，可以先到VBS专区找些教程看一看，就能明白代码的意思了。如果某个函数搞不懂，可以先看看帮助手册。

作者: wwenyunkui 时间: 2009-8-5 09:01

原帖由 Batcher 于 2009-8-5 08:52 发表
都是一些基本的操作，可以先到VBS专区找些教程看一看，就能明白代码的意思了。如果某个函数搞不懂，可以先看看帮助手册。

多谢管理员，呵呵

作者: terse 时间: 2009-8-5 09:42

原来的变量是固定的修改下
发现这里一个FOR可省

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (mac.txt) do set /a n+=1&set _!n!=%%i
    for /l %%a in (1 1 40) do (
      (for /f "usebackq tokens=*" %%i in ("%%a.txt") do (
          set "str=%%i"
          if "!str:~,11!"=="<IPInfo IP=" (
          for /f "tokens=5,7 delims==/" %%b in ("%%i/!_%%a!") do set str=!str:%%b=%%c!
          )
          echo !str!
          ))>~tem
         move /y ~tem "%%a.txt"
    )
pause
复制代码

[ 本帖最后由 terse 于 2009-8-5 10:39 编辑 ]

作者: wwenyunkui 时间: 2009-8-5 11:22

原帖由 terse 于 2009-8-5 09:42 发表
原来的变量是固定的修改下
发现这里一个FOR可省
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (mac.txt) do set /a n+=1&set _!n!=%%i
for /l %%a in (1 1 40) do (
(for /f ...

非常感谢，对应关系正确了，呵呵，只是对于set还是不怎么熟悉，自己慢慢学吧。

作者: Batcher 时间: 2009-8-5 13:44 标题: 回复 14楼的帖子

可以先看看set命令的帮助文档中关于字符串替换的讲解：

Environment variable substitution has been enhanced as follows:

%PATH:str1=str2%

would expand the PATH environment variable, substituting each occurrence
of "str1" in the expanded result with "str2". "str2" can be the empty
string to effectively delete all occurrences of "str1" from the expanded
output. "str1" can begin with an asterisk, in which case it will match
everything from the beginning of the expanded output to the first

作者: nopr 时间: 2009-8-5 14:24

这是什么意思啊?
"<IPInfo IP="

作者: wwenyunkui 时间: 2009-8-7 11:47

原帖由 nopr 于 2009-8-5 14:24 发表
这是什么意思啊?
"<IPInfo IP="

这个没有特别的意思，只是目标文件中的一句话。

欢迎光临批处理之家 (http://bbs.bathome.net/)