批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理把文本文档拆分成若干份，前10位移动到拆分后的新文档后面 [打印本页]

作者: KkK 时间: 2020-10-13 10:33 标题: 批处理把文本文档拆分成若干份，前10位移动到拆分后的新文档后面

我想把一个文本文档内容拆分成若干份，每10行一个文本，源文档前面内容有10位数字及4个横岗- 想把这10个数字在拆分文档后放到文档的每行内容的后面，该数字后面的4个横岗放到该数字的前面一同移动到文档内容的每行最后面，，然后拆分文档分别命名为 1、2、3、4、5、6……这样，
内容举例为：原文档内容：9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl
                              9876543210----aakkeeppqqnneebbfnffkl

               拆分后文档内容：aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
                                    aakkeeppqqnneebbfnffkl----9876543210
实际原内容比较多简单举例，拆分后为10行一份文档。我自己绞尽脑汁也写不出来求各位大神帮帮忙叩谢

作者: Batcher 时间: 2020-10-13 11:24

回复 1# KkK

请参考Q-04和Q-05把bat文件和txt文件都保存为ANSI编码：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ
test1.bat

@echo off
setlocal enabledelayedexpansion
set "FileNum=1"
set "LineNum=1"
for /f "tokens=1,2 delims=-" %%i in ('type "原文档.txt"') do (
    if !LineNum! gtr 10 (
        set LineNum=1
        set /a FileNum+=1
    )
    >>"!FileNum!.txt" echo %%j----%%i
    set /a LineNum+=1
)
复制代码

test2.bat

@echo off
setlocal enabledelayedexpansion
set "FileNum=1"
set "LineNum=0"
for /f "tokens=1,2 delims=-" %%i in ('type "原文档.txt"') do (
    set /a LineNum+=1
    if !LineNum! leq 10 (
        >>"!FileNum!.txt" echo %%j----%%i
    ) else (
        set LineNum=1
        set /a FileNum+=1
        >>"!FileNum!.txt" echo %%j----%%i
    )
)
复制代码

作者: qixiaobin0715 时间: 2020-10-13 11:40

回复 2# Batcher

在这里如果文件名无空格的话：
for /f "tokens=1,2 delims=-" %%i in ('type "原文档.txt"') do ...
和
for /f "tokens=1,2 delims=-" %%i in (原文档.txt) do ...
作用是一样的吧？

作者: KkK 时间: 2020-10-13 12:59

回复 2# Batcher

谢谢大神帮忙！！叩谢！！！

作者: Batcher 时间: 2020-10-13 23:24

回复 4# KkK

2楼代码已更新，请再试试。

欢迎光临批处理之家 (http://bbs.bathome.net/)