批处理之家 - Powered by Discuz! Board

标题: [文本处理] 求助一个修改文件夹名称的批处理，求大佬帮忙 [打印本页]

作者: blueskyforme 时间: 2021-1-6 15:32 标题: 求助一个修改文件夹名称的批处理，求大佬帮忙

本帖最后由 blueskyforme 于 2021-1-6 15:33 编辑

1. 遍历当前路径下的所有目录

2. 对于每个目录，截取子目录文件名 (名称格式为[XXXXXXX] YYYY.MM.DD XXXXX) 中符号‘]’（后面有一个空格）后面的日期，格式为比如2021.01.05

3. 定义一个变量，赋值上面的日期，但格式为 YYYYMMDD，比如20210105

4. 重命名这个目录，加上前缀 20210105_<原目录名>

5. 处理下一个目录，直到重命名完所有当前路径下的目录

作者: Batcher 时间: 2021-1-6 22:37

回复 1# blueskyforme

请给出几个真实的目录名称，随意举的例子可能会导致代码无法处理你真实的文件夹。

作者: qixiaobin0715 时间: 2021-1-7 09:35

本帖最后由 qixiaobin0715 于 2021-1-7 22:32 编辑

我猜你所说的“子目录文件名”应当是“子文件夹名”，每个目录下只有一个子文件夹。

@echo off
for /f "delims=" %%a in ('dir /b /ad') do (
    for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%%a"') do ren "%%a" "%%i%%j%%k_%%a"
)
pause
复制代码

作者: blueskyforme 时间: 2021-1-7 15:07

回复 2# Batcher

比如在当前路径下，有多三个文件夹:  <AAA>, <BBB>, <CCC>
在这三个文件夹中各有一个子目录，比如 <AAA>的子目录名称叫<[子目录A] 2020.12.01 VOL.001 AAA>
                                                      <BBB>的子目录名称叫<[子目录B] 2020.12.02 VOL.001 BBB>
                                                      <CCC>的子目录名称叫<[子目录C] 2020.12.03 VOL.001 CCC>

我想有个批处理程序，能够把三个文件夹:  <AAA>, <BBB>, <CCC> 分别命名成 <20201201_AAA>, <20201202_BBB>, <20201203_CCC>

当然，前面可以加个判断，是否有子目录，或者是否有这个日期格式就更好。

作者: qixiaobin0715 时间: 2021-1-7 15:37

本帖最后由 qixiaobin0715 于 2021-1-7 22:34 编辑

加个判断，是否有日期格式：

@echo off
for /f "delims=" %%a in ('dir /b /ad') do (
    for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%%a"^|findstr /r "[0-9][0-9][0-9][0-9]\.[0-9][0-9]\.[0-9][0-9]"') do (
ren "%%a" "%%i%%j%%k_%%a"
)
)
pause
复制代码

作者: blueskyforme 时间: 2021-1-7 17:21

回复 5# qixiaobin0715

谢谢兄弟，我试着运行了一下。问题是，可能是for循环的问题，文件名修改后，日期重复了三次。。。，修改的目录变成了<20210105_20210105_20210105_AAA>

这个可以麻烦帮忙调整下么？另外是不是判断是不是有子目录，可以用if exist? 但我不知道语法该怎么写。。。

作者: qixiaobin0715 时间: 2021-1-7 19:47

回复 6# blueskyforme
是不是在AAA文件夹下有3个子文件夹啊，我这测试没问题。要不是运行了3次。

作者: Batcher 时间: 2021-1-7 20:00

回复 6# blueskyforme

@echo off
for /d %%a in (*) do (
    call :ExecRen "%%a"
)
goto :eof

:ExecRen
for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%~1"^|findstr /r "[0-9][0-9][0-9][0-9]\.[0-9][0-9]\.[0-9][0-9]"') do (
    ren "%~1" "%%i%%j%%k_%~1"
    goto :eof
)
复制代码

代码保存为 test.bat
不要用 ren.bat 等跟代码内命令重复的文件名

作者: qixiaobin0715 时间: 2021-1-7 22:38

回复 6# blueskyforme
3楼5楼均修改了第2行代码。for /d一直搞不懂运行机制，换成for /f试试

作者: lifei259 时间: 2021-1-7 23:06

回复 9# qixiaobin0715

for /d %%a in (*) do (和for /f " delims=" %%a in ('dir/b/ad') do (
是一样的作用

作者: qixiaobin0715 时间: 2021-1-7 23:18

本帖最后由 qixiaobin0715 于 2021-1-7 23:20 编辑

回复 10# lifei259
绝大部分情况下一样，本人遇到过不同的情况，修改文件夹名（特别是与子文件夹有关系的情形）和创建文件夹时就不一样，可惜当时未深究。for /d:比如改名后又会当做新文件夹搜索循环一次。

作者: qixiaobin0715 时间: 2021-1-8 09:38

回复 8# Batcher
老大，论坛里介绍dir的教程没大看见，感觉挺复杂的，好多细节不是太清楚。

作者: Batcher 时间: 2021-1-8 10:01

回复 11# qixiaobin0715

你说的可能是类似for命令教程第8页的问题吧
http://bbs.bathome.net/thread-31727-1-1.html

作者: Batcher 时间: 2021-1-8 10:07

回复 12# qixiaobin0715

我觉得 dir 命令用到比较多的参数是 /b /s /a /o /t
会找个机会总结一下常见的例子

作者: qixiaobin0715 时间: 2021-1-8 10:25

回复 14# Batcher
还有/l，以小写字母显示？

作者: Batcher 时间: 2021-1-8 10:53

回复 15# qixiaobin0715

可以参考ntcmds.chm里面dir命令的介绍
http://bbs.bathome.net/thread-3926-1-1.html

作者: qixiaobin0715 时间: 2021-1-8 14:03

回复 16# Batcher
受益匪浅！但有些不是太详细，没有典型的例子。等待老大的教程。谢谢！！！

作者: blueskyforme 时间: 2021-1-12 10:41

回复 8# Batcher

完美执行了，感谢。再麻烦请教一下，如何在修改文件名之前，加一个判断。如果文件夹是以数字 “20” 开头的文件夹，不做处理。否则才执行修改文件名的操作呢？

作者: Batcher 时间: 2021-1-12 11:10

回复 18# blueskyforme

@echo off
for /f "delims=" %%a in ('dir /b /ad ^| findstr /v "^20"') do (
    call :ExecRen "%%a"
)
goto :eof

:ExecRen
for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%~1"^|findstr /r "[0-9][0-9][0-9][0-9]\.[0-9][0-9]\.[0-9][0-9]"') do (
    ren "%~1" "%%i%%j%%k_%~1"
    goto :eof
)
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)