批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理怎样把文件名从后往前删除4位，然后保留1位数，在删除3位数 [打印本页]

作者: 不坠轮回 时间: 2021-1-27 22:03 标题: [已解决]批处理怎样把文件名从后往前删除4位，然后保留1位数，在删除3位数

本帖最后由不坠轮回于 2021-1-27 22:28 编辑

现有一堆图片需要把文件名从后往前删除4位
然后保留1位数，在删除3位数
能一个BAT文件处理最好，不能的话两个也行
例如现有文件名如下
20210127214912-11_00117531.jpg
20210127214912-11_00123378.jpg
20210127215012-22_00112481.jpg
20210127215012-22_00125147.jpg
20210127215112-33_00115872.jpg
20210127215112-33_00123547.jpg
需要改成
20210127214912-11_1.jpg
20210127214912-11_2.jpg
20210127215012-22_1.jpg
20210127215012-22_2.jpg
20210127215112-33_1.jpg
20210127215112-33_2.jpg

作者: Batcher 时间: 2021-1-27 22:22

回复 1# 不坠轮回

test.bat

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.jpg') do (
    set "NewName=%%~ni"
    set "NewName=!NewName:~0,-4!"
    set "NewName=!NewName:~0,-4!!NewName:~-1!"
    ren "%%i" "!NewName!%%~xi"
)
复制代码

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

作者: 路过 时间: 2021-1-27 22:31

本帖最后由路过于 2021-1-27 22:33 编辑

把批处理放到jpg文件所在目录运行即可

@echo off
setlocal enabledelayedexpansion
pushd "%~sdp0"
for %%a in (*.jpg) do (
    set n=%%~na
    set n=!n:~0,-4!
    set m=!n:~0,-4!!n:~-1!
    ren "%%a" "!m!.jpg"
)
pause
exit
复制代码

作者: qixiaobin0715 时间: 2021-1-28 06:51

回复 2# Batcher
没想到第6行还能这样用

作者: qixiaobin0715 时间: 2021-1-28 10:43

回复 3# 路过
基本上是照着2楼的代码写的，没什么新意啊。

作者: qixiaobin0715 时间: 2021-1-28 11:03

邯郸学步：

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=_" %%a in ('dir /b /a-d *.jpg') do (
set str=%%~nb
set str=!str:~-5,1!
ren "%%a_%%b" "%%a_!str!.jpg"
)
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)