批处理之家 - Powered by Discuz! Board

标题: 二十红包求改批处理递归查找所有png 复制到一个文件夹内有同名的递增重命名 [打印本页]

作者: Edwin_ 时间: 2021-5-4 16:30 标题: 二十红包求改批处理递归查找所有png 复制到一个文件夹内有同名的递增重命名

本帖最后由 Edwin_ 于 2021-5-4 16:37 编辑

pushd D:\phpstudy_pro\WWW\xdzmb
	for /r %%a in (*.png) do (
		IF EXIST D:\phpstudy_pro\WWW\fff\%%~nxa (
			COPY %%a%%^(1) "D:\phpstudy_pro\WWW\fff"
		) ELSE (
			COPY %%a "D:\phpstudy_pro\WWW\fff"
		)
	)
popd
pause
复制代码

就是递归查找所有png 复制到一个文件夹内有同名的递增重命名大概就是上面的意思来个大佬可怜可怜吧

作者: went 时间: 2021-5-4 18:20

@echo off & cd /d "%~dp0"
setlocal enabledelayedexpansion
set "src=D:\phpstudy_pro\WWW\xdzmb"
set "dest=D:\phpstudy_pro\WWW\fff"
for /r "%src%" %%i in (*.png) do (
	if exist "%dest%\%%~nxi" (
		set "n=1"
		call :getNext "%dest%\%%~nxi" 
		set "tag=%dest%\%%~ni(!n!)%%~xi"
	) else set "tag=%dest%\%%~nxi"
	echo %%i
	echo !tag!
	copy "%%i" "!tag!"
	echo --------------------
)
pause&exit
:getNext
if exist "%~dpn1(!n!)%~x1" set /a "n+=1" & goto :getNext "%dest%\%%~nxi" 
goto :eof
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)