批处理之家 - Powered by Discuz! Board

标题: [网络连接] 请教批处理for循环来批量ping怎么显示设备中文名字 [打印本页]

作者: 奔跑的蜗牛wkl 时间: 2021-5-27 20:45 标题: 请教批处理for循环来批量ping怎么显示设备中文名字

@echo off
echo 开始 PING.........
echo *********管理及网关检查********>>pinlog.txt
echo *********管理及网关检查********>pingresult1.txt
date /t>>pingresult1.txt
time /t>>pingresult1.txt
for /f %%i in (ipADDR1.txt) do ping %%i -n 2 -w 1000 > j.txt & type j.txt & type j.txt | find "丢失 = 0" >nul && echo %%i OK >>pingresult1.txt || echo %%i err >>pingresult1.txt
echo PING测试结束
echo.
type pingresult1.txt
pause
复制代码

实现功能是读取ipADDR1里面的地址进行ping，并记录结果
但是我想增加中文显示，就是ping完之后显示这个ip地址通或者不通的同时显示这个ip地址对应的设备中文名字，
ipADDR1.txt和for循环该怎么修改呢？

作者: hlzj88 时间: 2021-5-29 14:12

for /f "tokens=1,2 delims=|" %%i in (ip表.txt) do ping /n 1 %%i&&echo %%j 畅通 || echo %%j 不通
复制代码

ip表内容 ip|设备名多行

作者: Batcher 时间: 2021-5-29 22:13

回复 1# 奔跑的蜗牛wkl

@echo off
set "FileResult=pingresult1.txt"
echo 开始 PING.........
echo *********管理及网关检查********>>pinlog.txt
echo *********管理及网关检查********>"%FileResult%"
>>"%FileResult%" echo %date% %time%
for /f "tokens=1*" %%i in (ipADDR1.txt) do (
    ping %%i -n 2 -w 1000 > j.txt
    type j.txt
    type j.txt | find "丢失 = 0" >nul
    if errorlevel 1 (
        >>"%FileResult%" echo %%i %%j 失败
    ) else (
        >>"%FileResult%" echo %%i %%j 成功
    )
)
echo PING测试结束
echo.
type "%FileResult%"
pause
复制代码

作者: 奔跑的蜗牛wkl 时间: 2021-6-1 12:28

回复 3# Batcher

这个可以，谢谢

欢迎光临批处理之家 (http://bbs.bathome.net/)