标题: [文本处理] 请教批处理字符提取感叹号的方法 [打印本页]
作者: wxyeah 时间: 2021-5-29 21:05 标题: 请教批处理字符提取感叹号的方法
大神们,请教一下,如下第1行存的计算机名,第2行存的是密码,重复- pc-kd1
- ks!32
- pc-ls9
- ladfd4532
- pc-os2
- ;3\8k!
复制代码
需要将计算机名和密码弄到同一行,但是启用变量延缓后第2行和第6行里的感叹号在结果中消失了,请问有什么办法保留感叹号吗?谢谢!- @echo off
- cd.>d:\result.txt
- for /f "eol= delims=" %%i in (d:\test.txt) do (
- set "t=%%i"
- setlocal enabledelayedexpansion
- if /i "!t:~0,2!" equ "pc" (
- set c=%%i
- ) else (
- set p=!t!
- echo !c! !p!
- echo !c! !p!>>d:\result.txt
- )
- )
- notepad d:\result.txt
- pause >/null
复制代码
d:\test.txt的内容
作者: newswan 时间: 2021-5-29 22:11
- sed -n '{N;s/\n/\t/p}' q.txt
复制代码
gnu 命令
作者: newswan 时间: 2021-5-29 22:56
- @echo off
-
-
- set n=0
- for /f "eol= delims=" %%a in (a.txt) do (
- call :f "%%a"
- )
-
- goto :END
-
- :f
- set /a n+=1
- set /a r=%n% %% 2
- if %r%==1 (
- set line=%~1
- ) else (
- echo %line% %~1
- set line=
- )
- goto :eof
-
-
- :END
复制代码
作者: WHY 时间: 2021-5-30 11:39
- @echo off
- for /f "delims="eol^= %%i in (a.txt) do (
- set "t=%%i"
- setlocal enabledelayedexpansion
- if /i "!t:~0,2!" equ "pc" (
- endlocal
- set "c=%%i"
- ) else (
- echo;!c! !t!
- endlocal
- )
- )
- pause
复制代码
作者: wxyeah 时间: 2021-5-30 13:26
回复 2# newswan
谢谢大佬提供思路
作者: wxyeah 时间: 2021-5-30 13:35
回复 3# newswan
谢谢大佬,可用
作者: wxyeah 时间: 2021-5-30 13:52
回复 4# WHY
谢谢大佬,完美解决。
之前我以为取值和赋值都要关掉变量延迟才行,于是试了很多endlocal的位置都不好使,看了您的代码才明白取值的时候是不用关的。多谢!
再请教一下,您把"delims= eol=" 改为"delims="eol^= 了,请问有什么区别吗?谢谢
作者: WHY 时间: 2021-5-30 18:55
本帖最后由 WHY 于 2021-5-30 19:10 编辑
回复 7# wxyeah
for /f "eol= delims=" %%i ... 会忽略以空格开头的行,你试试。
如果你确定文本中不会出现以空格开头的行,两种办法没有区别。
欢迎光临 批处理之家 (http://bbs.bathome.net/) |
Powered by Discuz! 7.2 |