批处理之家 - Powered by Discuz! Board

标题: [文件操作] 请教批处理FOR的循环嵌套如何把文件名小写字母改成大写字母？ [打印本页]

作者: xlqlin 时间: 2021-6-10 18:45 标题: 请教批处理FOR的循环嵌套如何把文件名小写字母改成大写字母？

我的目的是便利文件，把文件名小写字母改成大写字母，代码如下：

@echo off
setlocal enabledelayedexpansion
for %%i in (*.*) do (
	set a=%%i
	set c=%%~xi
	set b=%%~ni
	if !c! neq ^.bat ( 
	call :aa !b!
	
	)
)
pause
:aa
setlocal enabledelayedexpansion
for %%l in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (

	set d=!!b:%%l=%%l!!
	
)
echo !!d!!
复制代码

我的代码查看变量！！d！！没有变成大写字母，请问问题在哪里，求教？？

========================================================================
感谢二楼，经过修改成功解决了问题：代码如下：

@echo off
set "up=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
setlocal enabledelayedexpansion
for %%i in (*.*) do (
	set "b=%%~ni"
	set "a=%%~xi" 
	for %%a in (!up!) do (
		set "b=!b:%%a=%%a!"
	)
	if !a! neq ^.bat (
		ren %%i !b!!a!
	)
)
pause
复制代码

作者: qixiaobin0715 时间: 2021-6-10 19:33

本帖最后由 qixiaobin0715 于 2021-6-11 08:25 编辑

@echo off
set letters=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
setlocal enabledelayedexpansion
for %%i in (*.*) do (
    set "str=%%~ni"
    for %%a in (%letters%) do set "str=!str:%%a=%%a!"
    if not "%%i"=="%~nx0" ren "%%i" "!str!%%~xi"
)
pause
复制代码

未测试

作者: xlqlin 时间: 2021-6-10 20:01

回复 2# qixiaobin0715

谢谢给我提供了思路，解决了

欢迎光临批处理之家 (http://bbs.bathome.net/)