@echo off
cd.>script.txt
>>script.txt echo list disk
for /f %%i in ('diskpart /s script.txt^|find /c ^"联机^"') do Set HardDrivers=%%i
::del script.txt /q
echo 您的计算机上硬盘安装数量为：%HardDrivers%
pause
复制代码

X:\Users\Administrator>diskpart

Microsoft DiskPart 版本 10.0.19041.1

Copyright (C) Microsoft Corporation.
在计算机上: WinPE

DISKPART> list disk

  磁盘 ###  状态           大小     可用     Dyn  Gpt
  --------  -------------  -------  -------  ---  ---
  磁盘 0    联机              465 GB    50 GB        *
  磁盘 1    联机              465 GB    83 GB        *

DISKPART> select disk 0

磁盘 0 现在是所选磁盘。

DISKPART> detail disk

Samsung SSD 850 EVO 500GB
磁盘 ID: {5B30C043-F56D-11EB-8B35-F803154EB4DB}
类型   : SATA
状态 : 联机
路径   : 1
目标 : 0
LUN ID : 0
位置路径 : PCIROOT(0)#PCI(1C03)#PCI(0000)#ATA(C01T00L00)
当前只读状态: 否
只读: 否
启动磁盘: 否
页面文件磁盘: 否
休眠文件磁盘: 否
故障转储磁盘: 否
群集磁盘  : 否

  卷 ###      LTR  标签         FS     类型        大小     状态       信息
  ----------  ---  -----------  -----  ----------  -------  ---------  --------
  卷     0     G   nvme1          NTFS   磁盘分区          80 GB  正常
  卷     1     H   nvme2         NTFS   磁盘分区         284 GB  正常
  卷     2         EFI          FAT32  磁盘分区        1027 MB  正常         已隐藏

DISKPART> select disk 1

磁盘 1 现在是所选磁盘。

DISKPART> detail disk

KINGSTON SA2000M8500G
磁盘 ID: {33E8B399-451F-43F3-BB00-A1116C0B80AE}
类型   : NVMe
状态 : 联机
路径   : 0
目标 : 0
LUN ID : 0
位置路径 : PCIROOT(0)#PCI(0100)#PCI(0000)#NVME(P00T00L00)
当前只读状态: 否
只读: 否
启动磁盘: 否
页面文件磁盘: 否
休眠文件磁盘: 否
故障转储磁盘: 否
群集磁盘  : 否

  卷 ###      LTR  标签         FS     类型        大小     状态       信息
  ----------  ---  -----------  -----  ----------  -------  ---------  --------
  卷     3     C   ssd1          NTFS   磁盘分区          80 GB  正常
  卷     4     D   ssd2         NTFS   磁盘分区         264 GB  正常
  卷     5         EFI          FAT32  磁盘分区        1027 MB  正常         已隐藏

DISKPART>
复制代码

@echo off
setlocal ENABLEDELAYEDEXPANSION

set _label_=New Volume
for /f "usebackq tokens=2 delims==" %%a in (`
    wmic logicaldisk where ^(VolumeName^='%_label_%'^) get name /value
`) do (
    if not defined _letter_ (set _letter_=%%a)
)
echo %_letter_%

for /f "usebackq tokens=3 delims==" %%a in (`
    wmic path Win32_LogicalDiskToPartition.Dependent^='Win32_LogicalDisk.DeviceID^="%_letter_%"' get Antecedent /value
`) do (
    set _dp_=%%a
    set _dp_=!_dp_:""="%!
)
echo %_dp_%
复制代码

@echo off & cd /d "%~dp0"
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
set "diskNo=-1"
set "vol=Win10"
for /l %%i in (0,1,10) do (
	(
		echo select disk %%i 
		echo detail disk
	) | diskpart | findstr /i /C:" %vol% " >nul 2>nul && (
		set "diskNo=%%i"
		goto :next
	)
)
:next
echo %diskNo%
pause&exit
复制代码

@echo off & cd /d "%~dp0"
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
setlocal enabledelayedexpansion
set "labs=Win10|Backup"
set "num=1"
for /l %%i in (0,1,10) do (
	for /f "tokens=2,3,4,5,7,8" %%a in ('(echo select disk %%i ^& echo detail disk ^) ^| diskpart ^| findstr /i "%labs:|= %"') do (
		set "disk_!num!=%%i"
		set "part_!num!=%%a"
		set "letter_!num!=%%b"
		set "lab_!num!=%%c"
		set "fs_!num!=%%d"
		set "size_!num!=%%e%%f"
		set /a "num+=1"
	)
)
set /a "num-=1"
for /l %%i in (1,1,%num%) do (
	echo 硬盘号: !disk_%%i!	分区号: !part_%%i!	盘符: !letter_%%i! 卷标:!lab_%%i!	类型:!fs_%%i!	大小:!size_%%i!
)
pause&exit
复制代码

set "labs=Win10|Backup|Sortware|Games"
复制代码

@echo off & cd /d "%~dp0"
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
set "labs=Win10|Backup|Software|Games"
for /l %%i in (0,1,10) do (
	for /f "tokens=2,3,4,5,7,8" %%a in ('(echo select disk %%i ^& echo detail disk ^) ^| diskpart ^| findstr /i "%labs:|= %"') do (
		set "%%c_yph=%%i"
		set "%%c_fqh=%%a"
		set "%%c_pf=%%b"
		set "%%c_lab=%%c"
		set "%%c_fs=%%d"
		set "%%c_size=%%e%%f"
	)
)
REM 获取卷标为Win10的相关信息
echo 硬盘号: %Win10_yph%	分区号: %Win10_fqh%	盘符: %Win10_pf% 卷标:	%Win10_lab%	类型:%Win10_fs%	大小:%Win10_size%
REM 获取卷标为Backup的相关信息
echo 硬盘号: %Backup_yph%	分区号: %Backup_fqh%	盘符: %Backup_pf% 卷标:	%Backup_lab%	类型:%Backup_fs%	大小:%Backup_size%
pause&exit
复制代码