批处理之家 - Powered by Discuz! Board

标题: [文本处理] 继续请教批处理删除txt文件里的多行内容 [打印本页]

作者: 开心畅享 时间: 2021-10-31 14:30 标题: 继续请教批处理删除txt文件里的多行内容

继续请教高手！我想删除txt文件里的第8、10、11、13、14、16行如何可以实现？

作者: 5i365 时间: 2021-10-31 15:24

powershell "$a=type 1.txt;$a[0..6+8+11+14+16..$a.length]|Out-File -Encoding default 2.txt"

作者: 开心畅享 时间: 2021-10-31 16:52

非常好，谢谢您！真厉害

作者: Batcher 时间: 2021-10-31 17:33

回复 1# 开心畅享

http://bcn.bathome.net/s/tool/index.html?key=sed

sed "8d;10,11d;13,14d;16d" 1.txt > 2.txt
复制代码

作者: Batcher 时间: 2021-10-31 17:43

回复 1# 开心畅享

假设文件不超过6万多行

@echo off
cd /d "%~dp0"
(for /f "tokens=1* delims=:" %%i in ('type "1.txt" ^| findstr /n .*') do (
    if %%i equ 17 (
        echo,%%j
        goto :next
    ) else if %%i neq 8 (
        if %%i neq 10 (
            if %%i neq 11 (
                if %%i neq 13 (
                    if %%i neq 14 (
                        if %%i neq 16 (
                            echo,%%j
                        )
                    )
                )
            )
        )
    )
))>2.txt

:next
more +17 1.txt >>2.txt
复制代码

作者: 5i365 时间: 2021-10-31 17:50

回复 4# Batcher

更简单啊, 牛X

能用这个外挂解决这个难题吗?

http://www.bathome.net/thread-60529-1-1.html

作者: qixiaobin0715 时间: 2021-10-31 21:04

回复 1# 开心畅享

@echo off
(for /f "tokens=1* delims=:" %%i in ('findstr /n ".*" 1.txt^|findstr /vr "^8: ^1[01346]:"') do echo,%%j)>2.txt
pause
复制代码

作者: qixiaobin0715 时间: 2021-11-1 09:33

回复 5# Batcher
这里为什么要限制“6万多行”呢？

作者: Batcher 时间: 2021-11-1 09:52

回复 8# qixiaobin0715

23行那个more命令的用法有这个限制

作者: Batcher 时间: 2021-11-1 09:53

回复 8# qixiaobin0715

参考：
http://bbs.bathome.net/thread-20377-1-1.html#pid121367
http://bbs.bathome.net/thread-30111-1-1.html#pid148245

作者: qixiaobin0715 时间: 2021-11-1 10:16

谢谢斑竹。以前很少去使用，又重新学习了more命令，虽然有一些局限性，在有些场合还是很有用处的。

作者: msdmck 时间: 2021-11-1 10:56

本帖最后由 msdmck 于 2021-11-11 17:59 编辑

大佬解得簡單直接，好厲害

迷你倉 (mini storage)又稱自助儲物空間（self storage），一般會租倉的對象有個人和中小企，而迷你倉價錢一般比儲存成本還要低，因而頗受歡迎。

作者: aloha20200628 时间: 2021-11-1 12:56

给另一个纯P版本...
@echo off
:: 本脚本删除测试文件中若干行，其行序号被如下变量 nList 定义。注》测试文件是简中编码且单行数据不超过8K。
set "nList=8,10,11,13,14,16"
set/p inF="从资源管理器拖入一个测试文本文件："
set "outF=%inF%.new"
setlocal EnableDelayedExpansion
set/a k=0
(for /f "usebackq delims=" %%s in (%inF%) do (
set/a k+=1, cn=0
for %%n in (%nList%) do (set/a dn=!k!-%%n &if !dn! equ 0 (set cn=1))
if !cn! equ 0 (echo,%%s)
))>%outF%
endlocal&exit

作者: aloha20200628 时间: 2021-11-1 14:13

再精简一步...
:: 本脚本删除测试文件中若干行，其行序号被如下变量 nList 定义。注》测试文件是简中编码且单行数据不超过8K。
set "nList=8,10,11,13,14,16"
set/p inF="从资源管理器拖入一个测试文本文件："
set "outF=%inF%.new"
setlocal EnableDelayedExpansion
set/a k=0
(for /f "usebackq delims=" %%s in (%inF%) do (
set/a k+=1, cn=0
for %%n in (%nList%) do (if !k! equ %%n (set cn=1))
if !cn! equ 0 (echo,%%s)
))>%outF%
endlocal&exit

作者: WHY 时间: 2021-11-1 19:19

gawk "NR!~/^(8|1[01346])$/" 1.txt > 2.txt
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)