批处理之家 - Powered by Discuz! Board

标题: [文件操作] 如何在不知道文件名的情况下重命名文件 [打印本页]

作者: 5i365 时间: 2022-1-7 00:15 标题: 如何在不知道文件名的情况下重命名文件

批处理所在的文件夹下,有两个记事本文件:
一个文件名是光年之外1.txt
另一个文件名是 XXXX.txt 其中XXX表示未知

想做一个判断, 在存在两个txt文件的情况下, 如果存在光年之外1.txt, 则将另一个txt文件,命名为光年之外2.txt

作者: flashercs 时间: 2022-1-7 00:37

补集法重命名.
重命名前后两个集合的对比.

作者: flashercs 时间: 2022-1-7 00:49

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
REM 需要4个临时文件缓存文件名列表
set oldnames="%temp%\~%random%"
set newnames="%temp%\~%random%"
set oldexcept="%temp%\~%random%"
set newexcept="%temp%\~%random%"

>%oldnames% dir /a-d /b *.txt
>%newnames% (
echo 光年之外1.txt
echo 光年之外2.txt
)
>%oldexcept% findstr /ilxvg:%newnames% %oldnames%
>%newexcept% findstr /ilxvg:%oldnames% %newnames%
echo oldexcept:
type %oldexcept%
echo newexcept:
type %newexcept%
<%newexcept% (
  for /f "usebackq delims=" %%A in (%oldexcept%) do (
    set /p newname=
    echo ren "%%A" "!newname!"
    ren "%%A" "!newname!"
  )
)
del %oldnames% %newnames% %oldexcept% %newexcept%
endlocal
pause
exit /b
复制代码

作者: 5i365 时间: 2022-1-7 07:54

回复 3# flashercs

感谢, 有点看不懂, 总感谢用ps实现, 来的简单一些

作者: 5i365 时间: 2022-1-7 08:08

本帖最后由 5i365 于 2022-1-7 08:37 编辑

我试下面的两种代码不成功,对ps一直一知半解

ren ((dir *.txt).name -notmatch 光年之外1.txt) "光年之外2"

ren ((dir *.txt -Exclude "光年之外1").name) "光年之外2"

作者: 5i365 时间: 2022-1-7 08:39

本帖最后由 5i365 于 2022-1-7 08:41 编辑

回复 3# flashercs

瞎猫碰死耗子, 终于成功了, 但是没有加限定条件, 也不知道如何插入到CMD代码中

ren ((dir *.txt -Exclude "*1.txt").name) "光年之外2.txt"

作者: Nsqs 时间: 2022-1-7 08:46

本帖最后由 Nsqs 于 2022-1-7 08:50 编辑

回复 5# 5i365

$s='光年之外1.txt'
$r='AAA' #指定重命名
$file=dir *.txt
if ($file.count -eq 2 -and (Test-Path $s)){
    $file|%{
        if ($_.name -ne $s){
            ren  $_.FullName ($r+$_.Extension)
        }
    }
    }else{
    "不存在'$s',或当前文件夹内不足2个txt文件"
}
[System.Console]::ReadKey(0)
复制代码

作者: 5i365 时间: 2022-1-7 08:47

回复 7# Nsqs

终于大功告成了, 感觉还是ps简单一些, 瞎搞都能搞好了,

我的代码我试了几次是可以的

if ((dir *.txt -Exclude "*1.txt").count -eq 1)
{
ren ((dir *.txt -Exclude "*1.txt").name) "光年之外2.txt"
}

作者: 5i365 时间: 2022-1-7 08:48

回复 7# Nsqs

但是问题来了, 我的主代码是在CMD中, 怎样把这个ps代码, 插入到cmd中, 并使用cmd中的变量? 例如光年之外1.txt 是cmd中的变量

作者: Nsqs 时间: 2022-1-7 08:57

回复 9# 5i365

@echo off
set file=光年之外1.txt
set new_name=ABC
powershell "$s='%file%';$r='%new_name%';$file=dir *.txt;if ($file.count -eq 2 -and (Test-Path $s)){$file|%%{if ($_.name -ne $s){ren  $_.FullName ($r+$_.Extension)}}}else{"不存在 '$s',或当前文件夹内不足2个txt文件"}"
复制代码

作者: 5i365 时间: 2022-1-7 09:10

回复 10# Nsqs

多谢帮忙

作者: qixiaobin0715 时间: 2022-1-7 10:51

for %%a in (*.txt) do (
    set /a n+=1
    if not "%%a"=="光年之外1.txt" set "filename=%%a"
)
if exist "光年之外1.txt" if %n% equ 2 ren "%filename%" "光年之外2.txt"
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)