批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何把26张jpg,png图片重命名成26个大写英文字母 [打印本页]

作者: Monkey 时间: 2022-7-12 18:16 标题: [已解决]批处理如何把26张jpg,png图片重命名成26个大写英文字母

本帖最后由 Monkey 于 2022-7-16 16:09 编辑

也就是A，B，C，D，E,自动命名。类似于这样。

作者: idwma 时间: 2022-7-12 19:04

/*&cls
@echo off
for /f "delims=" %%a in ('dir /b *.jpg *.png^|cscript -nologo -e:jscript "%~f0"') do (
  ren "%%a" "%%a"
)
pause&exit
*/
var files = WScript.StdIn;
while (!files.AtEndOfStream) {
    WSH.echo(files.ReadLine().toUpperCase())
}
复制代码

作者: Monkey 时间: 2022-7-12 21:27

回复 2# idwma
大佬好我测试了貌似好像不对，只需要单个字母A B C D这样排下去或者是图片A 图片B 图片C这样的.

作者: idwma 时间: 2022-7-12 22:15

/*&cls
@echo off
for /f "delims=" %%a in ('dir /b *.jpg *.png^|cscript -nologo -e:jscript "%~f0"') do (
    ren %%a
)
pause&exit
*/
var i=0,files = WScript.StdIn;
s='ABCDEFGHIJKLMNOPQRSTUVWXYZ'
while (!files.AtEndOfStream) {
    f=files.ReadLine().toUpperCase()
    ff=f.replace(/^.+\./,'')
    WSH.echo('"'+f+'" '+s.substr(i++,1)+'.'+ff)
}
复制代码

回复 3# Monkey

作者: Monkey 时间: 2022-7-12 23:15

回复 4# idwma
非常感谢大佬的回复可以用了十分感谢
就是可否请大佬在给一个图片A 图片B 图片C这样的
就是A B C D 前面可以写中文名称非常感谢

作者: flashercs 时间: 2022-7-13 10:47

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set alpha=ABCDEFGHIJKLMNOPQRSTUVWXYZ
set n=0
for /f "delims=" %%A in ('dir /a-d /b *.png *.jpg') do (
  for %%B in (!n!) do (
    ren "%%A" "图片!alpha:~%%B,1!%%~xA"
  )
  set /a n+=1
)
endlocal
pause
复制代码

作者: Monkey 时间: 2022-7-13 22:26

回复 6# flashercs
你好这个我测试了一下会显示乱码

作者: flashercs 时间: 2022-7-14 11:32

回复 7# Monkey

批处理脚本保存成ANSI编码

作者: Monkey 时间: 2022-7-14 16:17

回复 8# flashercs

多谢多谢嘿嘿完美运行搞定

欢迎光临批处理之家 (http://bbs.bathome.net/)