批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理如何截取字符串到另外一个文本？[已解决] [打印本页]

作者: 帝尊 时间: 2022-9-16 19:09 标题: 批处理如何截取字符串到另外一个文本？[已解决]

本帖最后由帝尊于 2022-9-17 09:25 编辑

这里有很多行
字符A----------------A
随机字符
字符B----------------B
随机字符
字符C----------------C
随机字符
这里有很多行
复制代码

如何截取

字符A----------------A
随机字符
字符B----------------B
随机字符
字符C----------------C
随机字符
复制代码

这一段到另外一个文本？
不想要powershell和第三方。

作者: 帝尊 时间: 2022-9-16 19:21

或者提取指定字符串与其下面一行的内容到另外一个文本。谢谢大佬。

作者: flashercs 时间: 2022-9-16 21:52

@echo off
cd /d "%~dp0"
set flag=
(
for /f "delims=" %%A in (1.txt) do (
  if not defined flag (
    if "%%~A"=="字符A----------------A" (
      set flag=1
    ) else if "%%~A"=="字符B----------------B" (
      set flag=1
    ) else if "%%~A"=="字符C----------------C" (
      set flag=1
    )
    if defined flag echo %%A
  ) else (
    echo %%A
    set flag=
  )
)
)>2.txt

pause
复制代码

作者: 帝尊 时间: 2022-9-17 09:25

回复 3# flashercs

非常感谢。

作者: qixiaobin0715 时间: 2022-9-17 09:50

本帖最后由 qixiaobin0715 于 2022-9-17 09:53 编辑

@echo off
set var="字符A----------------A" "字符B----------------B" "字符C----------------C"
setlocal enabledelayedexpansion
(for /f "delims=" %%a in (1.txt) do (
    for %%i in (%var%) do (
        if "!str!"==%%i (
            echo,%%~i
            echo,%%a
        )
    )
    set str=%%a
))>2.txt
pause
复制代码

作者: 帝尊 时间: 2022-9-19 11:14

回复 5# qixiaobin0715

感谢，很好用。这个可以不让他区分大小写吗？

作者: qixiaobin0715 时间: 2022-9-19 11:19

回复 6# 帝尊
第6行修改：if /i "!str!"==%%i (

作者: 帝尊 时间: 2022-9-19 11:39

回复 7# qixiaobin0715

为什么地址加上双引号就失效了呢？有的时候地址有空格不是需要加上双引号吗？

作者: qixiaobin0715 时间: 2022-9-19 11:41

你在哪里加上双引号了？

作者: 帝尊 时间: 2022-9-19 13:14

回复 9# qixiaobin0715

@echo off
set var="字符A----------------A" "字符B----------------B" "字符C----------------C"
setlocal enabledelayedexpansion
(for /f "delims=" %%a in ("UT IN/1.txt") do (
    for %%i in (%var%) do (
        if "!str!"==%%i (
            echo,%%~i
            echo,%%a
        )
    )
    set str=%%a
))>"UT IN/2.txt"
pause
复制代码

作者: qixiaobin0715 时间: 2022-9-19 13:44

你这样写代码，在第4行in后面的括号内，程序会以为这是一段字符串，当然会出错了。可在delims前加个usebackq，即"usebackq delims="。
请阅读论坛中关于for /f的教程。

作者: 帝尊 时间: 2022-9-19 13:54

回复 11# qixiaobin0715

好的。谢谢。非常感谢。我去看看。

欢迎光临批处理之家 (http://bbs.bathome.net/)