批处理之家 - Powered by Discuz! Board

标题: [文件操作] [分享]批处理查找或删除二级文件夹下的空白文件夹 [打印本页]

作者: Batcher 时间: 2022-9-25 18:26 标题: [分享]批处理查找或删除二级文件夹下的空白文件夹

【问题描述】

有什么方法可以批量查找出二级文件夹下面是空白文件夹么？

├─1
│  ├─1-1
│  │    1-1.jpg
│  │
│  └─1-2
├─2
│  └─2-1
└─3
├─3-1
└─3-2
         3-2.jpg

作者: Batcher 时间: 2022-9-25 18:27

【解决方案】

查找二级文件夹下的空白文件夹_1.bat

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /ad') do (
    pushd "%%i"
    for /f "delims=" %%j in ('dir /b /ad') do (
        set "FolderEmpty="
        for /f "delims=" %%k in ('dir /a /b "%%j"') do (
            set "FolderEmpty=%%k"
        )
        if "x!FolderEmpty!" equ "x" (
            echo %~dp0%%i\%%j 是空文件夹
        )
    )
    popd
)
pause
复制代码

作者: Batcher 时间: 2022-9-25 18:34

删除二级文件夹下的空白文件夹_1.bat

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    pushd "%%i"
    for /f "delims=" %%j in ('dir /b /ad') do (
        rd "%~dp0%%i\%%j" 2>nul
    )
    popd
)
pause
复制代码

作者: WindCat 时间: 2022-9-25 22:20

if not "%1"=="" (
	cd /d "%1"
	if "%errorlevel%"=="0" (goto:inputparam_1_not_is_null)
	)
echo 当前执行文件夹为:"%~dp0"
set temp_userinput_var_a="%~dp0"
set /p temp_userinput_var_a=拖入文件夹:
cd /d "%temp_userinput_var_a%"
:inputparam_1_not_is_null
复制代码

提升点易用性？随便打的，不过加了这个要考虑管理员权限导致的路径变化就是了

欢迎光临批处理之家 (http://bbs.bathome.net/)