批处理之家 - Powered by Discuz! Board

标题: [文件操作] [分享]批处理调用7-Zip压缩文件和文件夹 [打印本页]

作者: Batcher 时间: 2022-12-13 10:15 标题: [分享]批处理调用7-Zip压缩文件和文件夹

【问题描述】

某个目录下有多个文件夹，好比文件夹1/文件夹2/文件夹3，想对这些文件夹里的文件夹或者文件进行单独压缩，有没有可能实线，一个文件压缩完以后再执行下一个压缩文件，目的是想减少CPU和内存压力

作者: Batcher 时间: 2022-12-13 10:16

【解决方案】

test_1.bat 请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
REM 根据自己电脑实际情况设置 7-Zip 的路径
set "My7z=C:\Program Files\7-Zip\7z.exe"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    echo 正在处理文件夹 %%i
    "%My7z%" a "%%i.zip" "%%i"
)
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /v /x "%~nx0"') do (
    echo 正在处理文件 %%i
    "%My7z%" a "%%~ni.zip" "%%i"
)
复制代码

作者: 77七 时间: 2022-12-13 14:13

回复 2# Batcher
管理员大佬
第二个for把第一个for生成的zip文件也压缩了一遍，弹窗“没有文件被添加”，批处理本身也被压缩了

正在处理文件夹 1
正在处理文件夹 2
请按任意键继续. . .
正在处理文件 1.zip
正在处理文件 2.zip
正在处理文件 新建 Windows 批处理文件.bat
正在处理文件 新建文本文档3.txt
请按任意键继续. . .
复制代码

作者: Batcher 时间: 2022-12-13 14:25

回复 3# 77七

两个for对调位置试试

@echo off
REM 根据自己电脑实际情况设置 7-Zip 的路径
set "My7z=C:\Program Files\7-Zip\7z.exe"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /v /x "%~nx0"') do (
    echo 正在处理文件 %%i
    "%My7z%" a "%%~ni.zip" "%%i"
)
for /f "delims=" %%i in ('dir /b /ad') do (
    echo 正在处理文件夹 %%i
    "%My7z%" a "%%i.zip" "%%i"
)
复制代码

作者: 77七 时间: 2022-12-13 14:49

回复 4# Batcher
管理员大佬，为什么不一起写...

@echo off
REM 根据自己电脑实际情况设置 7-Zip 的路径
set "My7z=C:\Program Files\WinRAR\WinRAR.exe"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b') do (
    echo 正在处理文件 %%i
    "%My7z%" a "%%~ni.zip" "%%i"
)
复制代码

作者: Batcher 时间: 2022-12-13 15:25

回复 5# 77七

避免有个文件夹叫做 xxx.yyy

欢迎光临批处理之家 (http://bbs.bathome.net/)