批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理如何删除文件名中某字符前的内容？ [打印本页]

作者: cabat 时间: 2023-4-30 00:14 标题: 批处理如何删除文件名中某字符前的内容？

有比较多文件要进行重命名：
例如:
原文件：
1235_1.jpg
165_2.jpg
1 4.44_3.jpg（删除部分可能含有"空格"或"."）
12_665_4.jpg（要求删除第一个_前内容即可，因为可以通过多次处理得到4.jpg，但如果能一步到位更好）
......
经过一次处理后要求修改为：（包括子文件夹内文件）
1.jpg
2.jpg
3.jpg
665_4.jpg/4.jpg
.....
之前找了一些代码，有用但效果不好，例如有些对文件名含空格文件无效，有些对子文件无效，所以求助各位大神有没有啥好的解决办法。

bat或cmd /K命令均可。

作者: 77七 时间: 2023-4-30 00:49

本帖最后由 77七于 2023-4-30 00:54 编辑

@echo off
rem 最多支持文件名含10个"_"
for /f "delims=" %%i in ('dir /b /s /a-d *.jpg') do (
	set "newName=%%~nxi"
	set "oldName=%%~fi"
	setlocal enabledelayedexpansion
	for /l %%l in (1,1,10) do (
		set "newName=!newName:*_=!"
	)
	echo ren "!oldName!" "!newName!"
	ren "!oldName!" "!newName!"
	endlocal
)
pause
复制代码

作者: jyswjjgdwtdtj 时间: 2023-4-30 06:54

set shell=createobject("shell.application")
set folder=shell. namespace(replace(wscript.scriptfullname,wscript.scriptname,""))
set filecollection=folder. items(). filter(&h40)
for each file in filecollection
n=file. name
file. name=mid(n,instrrev(n,"_"))
next

作者: terse 时间: 2023-4-30 09:52

文件名格式不是很特殊的话也可以这样简单点处理

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d *_*.jpg') do (
        set "FileName=%%~nxi"
        for %%j in ("!FileName:_=\!") do echo ren "%%i"   "%%~nxj"
)
pause
复制代码

作者: 77七 时间: 2023-4-30 17:38

@echo off
rem 预期保留的文件名部分不含空格键、逗号、分号、等号、叹号
for /f "delims=" %%i in ('dir /b /s /a-d *.jpg') do (
	set "newName=%%~nxi"
	set "oldName=%%~fi"
	setlocal enabledelayedexpansion
	set "newName=!newName:_==!"
	for %%a in (!newName!) do (
		set "newName=%%a"
	)
	echo ren "!oldName!" "!newName!"
	ren "!oldName!" "!newName!"
	endlocal
)
pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)