批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理怎么进行复杂的批量替换？ [打印本页]

作者: Noble6 时间: 2023-5-14 23:04 标题: 批处理怎么进行复杂的批量替换？

88 2.25E+02 2.3E-02 -9.5E-03 1.0E+00 1.8E+00 1.0E+00

txt文件中有很多行上面格式的数据，第一个数字前面是有空格的

每行的1.00E+00出现位置和数量都是随机的，前两个数字肯定不会出现1.00E+00

现在想用bat实现

1.保留每行的前两个数

2.把每行第二个数往后的除去1.0E+00的所有数，替换为符号“-”，保持原有的空格不动

即变成
88 2.25E+02 ------- -------- 1.0E+00 ------- 1.0E+00

作者: 77七 时间: 2023-5-15 05:20

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1-2*" %%a in ('type "1.txt"') do (
	for %%d in (%%c) do (

		if "%%d" neq "1.0E+00" (
			set "str1=%%d"
			for /l %%l in (1,1,10) do (
				if defined str1 (
					set "str1=!str1:~1!"
					set "str2=!str2!-"
				)
			)
			set "str=!str! !str2!"
		) else (
			set "str=!str! 1.0E+00"
		)

		set str2=
	)
	rem "第一个数字前面是有空格的"，需要保留就在%%a前再加个空格
	echo %%a %%b!str!
	set str=
))>2.txt
pause
复制代码

作者: qixiaobin0715 时间: 2023-5-15 10:23

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1,2* delims= " %%i in (1.txt) do (
    set "str=%%k"
    set "str=!str:1.00E+00=`!"
    for %%a in (0 1 2 3 4 5 6 7 8 9 . E +) do set "str=!str:%%a=-!"
    echo,%%i %%j !str:`=1.00E+00!
))>2.txt
pause
复制代码

作者: hfxiang 时间: 2023-5-15 11:19

回复 1# Noble6

下载gawk（ http://bcn.bathome.net/tool/4.1.0/gawk.exe ）,执行：

gawk "NF>2{for(i=3;i<=NF;i++)if($i!=\"1.0E+00\")$i=gensub(/./,\"-\",\"g\",$i)}1" 1.txt>2.txt
复制代码

作者: chishingchan 时间: 2023-5-17 10:14

回复 4# hfxiang

详细帮助：https://wker.com/linux-command/gawk.html

欢迎光临批处理之家 (http://bbs.bathome.net/)