批处理之家 - Powered by Discuz! Board

标题: 30元求助（已解决） [打印本页]

作者: 2652boy 时间: 2023-5-18 11:03 标题: 30元求助（已解决）

本帖最后由 2652boy 于 2023-5-18 12:50 编辑

具体报酬：30元
支付方式：支付宝
联系方式：QQ2652993952
有效期限：2023年5月20日之前。
需要批量移动jpg图片到指定文件夹；存在大批数据，每个都需要对应
如：G:\1953\民事庭\2098 中的jpg图片移动到 G:\1953\民事庭\2098\正卷中
G:\1953\民事庭\2099 中的jpg图片移动到 G:\1953\民事庭\2099\正卷中

作者: buyiyang 时间: 2023-5-18 11:43

@echo off
rem 设置主目录，脚本保存为ansi编码
set "sd=G:\1953\民事庭"

cd "%sd%"
for /d %%i in (*) do robocopy "%%i" "%%i\正卷" *.jpg /mov
pause
复制代码

作者: zaqmlp 时间: 2023-5-18 12:09

bat需另存为ANSI/GB2312编码

@echo off&cd /d "%~dp0"&mode con lines=5000
for %%a in (
"G:\1953\民事庭|正卷"
"G:\1960\xxx|yyy"
) do (
    for /f "tokens=1* delims=|" %%b in ("%%~a") do (
        for /f "delims=" %%i in ('dir /ad-h/b "%%~b\" 2^>nul') do (
            if not exist "%%~b\%%~nxi\%%~c\" md "%%~b\%%~nxi\%%~c\"
            echo;"%%~b\%%~nxi\*.jpg" --^> "%%~b\%%~nxi\%%~c\"
            move /y "%%~b\%%~nxi\*.jpg" "%%~b\%%~nxi\%%~c\"
            echo;&echo;
        )
    )
)
pause
exit
复制代码

作者: 2652boy 时间: 2023-5-18 12:50

buyiyang 发表于 2023-5-18 11:43

已解决

作者: qixiaobin0715 时间: 2023-5-18 15:57

本帖最后由 qixiaobin0715 于 2023-5-18 17:12 编辑

@echo off
cd /d "G:\1953\民事庭"
for /f "delims=" %%i in ('dir /b /ad') do (
    if exist "%%i\*.jpg" move "%%i\*.jpg" "%%i\正卷\"
)
pause
复制代码

也可删除代码第2行，将批处理文件放在图片文件所在文件夹同一目录（在这里即是文件夹“民事庭”下）。

欢迎光临批处理之家 (http://bbs.bathome.net/)