批处理之家 - Powered by Discuz! Board

@echo off
title ！！不删！！点我批量在文件名前添加前缀.bat
color F0
echo 1、【原点印务】
echo 2、【百姓印务】
echo 3、【鑫金星：760】
echo 4、【鑫金星：1030】
echo 5、【雅美高】
echo 6、【华印汇彩】
echo 7、【华美丰：460】
echo 8、【华美丰：620】
echo 9、【华美丰：920】
echo 10、【添加自定义文字】
echo 00、【撤销添加的前缀】
echo,&set /p xz=请输入数字后回车：
if /i "%xz%"=="1" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "1030_790_原点印务__文件名："') do (
ren "%%i" "1030_790_原点印务__文件名：%%~nxi"
)
if /i "%xz%"=="2" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "1030_800_百姓印务__文件名："') do (
ren "%%i" "1030_800_百姓印务__文件名：%%~nxi"
)
if /i "%xz%"=="3" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "760_605_鑫金星__文件名："') do (
ren "%%i" "760_605_鑫金星__文件名：%%~nxi"
)
if /i "%xz%"=="4" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "1030_800_鑫金星__文件名："') do (
ren "%%i" "1030_800_鑫金星__文件名：%%~nxi"
)
if /i "%xz%"=="5" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "1030_790_雅美高__文件名："') do (
ren "%%i" "1030_790_雅美高__文件名：%%~nxi"
)
if /i "%xz%"=="6" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "910_665_华印汇彩__文件名："') do (
ren "%%i" "910_665_华印汇彩__文件名：%%~nxi"
)
if /i "%xz%"=="7" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "460_395_华美丰__文件名："') do (
ren "%%i" "460_395_华美丰__文件名：%%~nxi"
)
if /i "%xz%"=="8" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "620_485_华美丰__文件名："') do (
ren "%%i" "620_485_华美丰__文件名：%%~nxi"
)
if /i "%xz%"=="9" for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v "文件名" ^|find /v "920_760_华美丰__文件名："') do (
ren "%%i" "920_760_华美丰__文件名：%%~nxi"
)
if /i "%xz%"=="10" echo,&set /p targetDate=请输入自定义文字：
if /i "%xz%"=="10" for /f "delims=" %%f in ('dir/b/a-d *.pdf*') do (if not "%%~nxf"=="%0" ren "%%f" "%targetDate%%%~nxf")
if /i "%xz%"=="00" for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
set "newName=%%~nxi"
set "oldName=%%~fi"
setlocal enabledelayedexpansion
for /l %%l in (1,1,10) do (
set "newName=!newName:*：=!"
)
echo ren "!oldName!" "!newName!"
ren "!oldName!" "!newName!"
endlocal
)
exit

复制代码

@echo off
setlocal enabledelayedexpansion
set Pre=1030_790_原点印务 1030_800_百姓印务 760_605_鑫金星 1030_800_鑫金星 1030_790_雅美高 910_665_华印汇彩 460_395_华美丰 620_485_华美丰 920_760_华美丰
for %%a in (%Pre%) do (
set /a n+=1
set _!n!=%%a
echo,!n!、【%%a】
)
echo,10、【添加自定义文字】
echo,00、【撤销添加的前缀】
echo,&set /p xz=请输入数字后回车：
if %xz% equ 10 (
echo,
set /p targetDate=请输入自定义文字：
for /f "delims=" %%i in ('dir /b /a-d *.pdf') do ren "%%i" "!targetDate!%%i"
) else if "%xz%"=="00" (
for /f "delims=" %%i in ('dir /b /a-d *：*.pdf') do (
set "str=%%i"
set "str=!str:：=\!"
for %%j in ("!str!") do ren "%%i" "%%~nxj"
)
) else (
for /f "delims=" %%i in ('dir /b /a-d *.pdf^|find /v "文件名："') do ren "%%i" "!_%xz%!_文件名：%%i"
)
pause

复制代码

@if (0)==(0) echo off
rem 保存为ANSI编码
:start
cls
echo 1、【原点印务】
echo 2、【百姓印务】
echo 3、【鑫金星：760】
echo 4、【鑫金星：1030】
echo 5、【雅美高】
echo 6、【华印汇彩】
echo 7、【华美丰：460】
echo 8、【华美丰：620】
echo 9、【华美丰：920】
echo 10、【添加自定义文字】
echo 00、【撤销添加的前缀】
echo.
set/p p=请选择[1/2/3/4/5/6/7/8/9/10/00]:
echo.
if %p%==1 set "var1=1030_790_原点印务__文件名：" & goto to
if %p%==2 set "var1=1030_800_百姓印务__文件名：" & goto to
if %p%==3 set "var1=760_605_鑫金星__文件名：" & goto to
if %p%==4 set "var1=1030_800_鑫金星__文件名：" & goto to
if %p%==5 set "var1=1030_790_雅美高__文件名：" & goto to
if %p%==6 set "var1=910_665_华印汇彩__文件名：" & goto to
if %p%==7 set "var1=460_395_华美丰__文件名：" & goto to
if %p%==8 set "var1=620_485_华美丰__文件名：" & goto to
if %p%==9 set "var1=920_760_华美丰__文件名：" & goto to
if %p%==10 set /p "var1=添加自定义文字：" & goto to
if %p%==00 set /p "var2=撤销添加的前缀：" & goto to
goto start
:to
dir /b "*.pdf" | cscript //nologo //e:jscript "%~0" "%var1%" "%var2%"
pause & goto :EOF
@end
fso = new ActiveXObject("Scripting.FileSystemObject");
while(!WScript.StdIn.AtEndOfStream){
var name = WSH.StdIn.ReadLine();
if (WSH.Arguments(1) === '') {
str = name.match(WSH.Arguments(0))
if (str === null) {
Newname = WSH.Arguments(0) + name;//添加内容
if (!fso.FileExists(Newname)) {fso.MoveFile(name, Newname);}
WSH.echo('新文件名：' + Newname);
}
} else {
Newname = name.replace(WSH.Arguments(1), "");//删除内容
if (!fso.FileExists(Newname)) {fso.MoveFile(name, Newname);}
WSH.echo('新文件名：' + Newname);
}
}
WSH.echo("批量处理完成");

复制代码

'vbscript
Set shell = CreateObject("shell.application")
Set pdfs = shell.namespace(Replace(WScript.scriptfullname,WScript.scriptname,"")).items
pdfs.Filter 128,"*.pdf"
For Each pdf In pdfs
If InStr(pdf.name,"已处理") = -1 Then
pdf.name = "待处理" + pdf.name
End If
Next

复制代码

@if (0)==(0) echo off
dir /b "*.pdf" | cscript //nologo //e:jscript "%~0"
pause & goto :EOF
@end
fso = new ActiveXObject("Scripting.FileSystemObject");
while(!WScript.StdIn.AtEndOfStream){
var name = WSH.StdIn.ReadLine();
var str = name.match(/已处理/);
if (!str) {
Newname = "待处理 " + name.replace(/(待处理 *)+/g, '');
if (!fso.FileExists(Newname)) {
fso.MoveFile(name, Newname);
WSH.Echo(Newname);
}}
}

复制代码