批处理之家 - Powered by Discuz! Board

标题: [文本处理] 求助批处理在文本指定行添加内容 [打印本页]

作者: 木偶 时间: 2023-6-21 16:37 标题: 求助批处理在文本指定行添加内容

求助在文本指定行添加指定内容
在JLinkDevices3.xml文件的第2行开始添加JLinkDevices4.xml的全部内容
bat脚本和xml文件同目录，操作文件需要管理员权限，环境为windows10
由于附件一直上传失败，附件放在网盘了
https://www.123pan.com/s/cWIZVv-aWyr.html
感谢大佬来帮忙

作者: buyiyang 时间: 2023-6-21 19:10

本帖最后由 buyiyang 于 2023-6-21 19:11 编辑

%1powershell -c "Start -File '%~0' -Verb RunAs -arg ':'"&&exit
@echo off&cd /d "%~dp0"
call :ap "JLinkDevices3.xml" "JLinkDevices4.xml" 2
pause
:ap
(for /f "delims=" %%i in ('type %1') do (
    set "line=%%i"
    set /a n+=1
    setlocal enabledelayedexpansion
    if !n! equ %3 type %2
    echo,!line!
    endlocal
))>temp
move /y temp %1
复制代码

作者: wanghan519 时间: 2023-6-22 13:24

借宝地问一下，为啥sed如果不用-n，执行'1r b.txt'会忽略掉a.txt的最后一行

sed -n 'p;1r b.txt' a.txt
复制代码

awk则正常一点

awk '1;FNR==1{while(getline < "b.txt")print}' a.txt
复制代码

作者: 木偶 时间: 2023-6-22 16:36

本帖最后由木偶于 2023-6-22 17:03 编辑

回复 2# buyiyang

感谢大佬帮忙，不过还有个小问题就是，原有文件内的空行没有保留下来

作者: 77七 时间: 2023-6-22 22:24

@fltmc>nul||mshta vbscript:CreateObject("Shell.Application").ShellExecute("%~dpnx0","%*",,"runas",1)(window.close)&&exit
@echo off
cd /d "%~dp0"
>xml.xxx (
	findstr /n .* JLinkDevices3.xml |findstr /b "1:"
	findstr /n .* JLinkDevices4.xml
	findstr /n .* JLinkDevices3.xml |findstr /bv "1:"
)
(for /f "tokens=1* delims=:" %%a in ('type "xml.xxx"') do (
	echo=%%b
))>JLinkDevices3.xml
del xml.xxx
pause
复制代码

作者: 木偶 时间: 2023-6-23 13:10

回复 5# 77七

感谢大佬帮忙

欢迎光临批处理之家 (http://bbs.bathome.net/)