批处理之家 - Powered by Discuz! Board

@echo off&setlocal enabledelayedexpansion&(set PPPCFG=%windir%\PPPCFG.ini)
if not exist !PPPCFG! goto begin
if /i "%1" equ "hide" goto begin
if /i "%1" equ "show" goto begin
if /i "%1" equ "setAccount" (call :setAccount %1) && goto begin
mode con lines=4 cols=58&(set /p show=需要显示小窗口界面吗^(y/n^)[直接回车=不显示]:)
if /i "%show:~0,1%" equ "y" goto begin
rem mshta vbscript:createobject("wscript.shell").run("%~nx0 hide",0)(window.close)&&exit
(call :showWindow hide)
:begin
chcp 936 & cls & rem 后面的的判断全以中文代码页936输出为准
(set sLC=本地连接)&(set sPPP=宽带连接)&(set fn=%windir%\~netmp)
if not exist !PPPCFG! (call :setAccount %1)
cls & mode con lines=2 cols=58
:loop
(ipconfig/all>!fn!)
(set foundLC=false)&(set foundLCPA=false)&(set LCC=true)&(set LCPA=)&(set PPP_WAN=false)
for /f "delims=" %%i in (!fn!) do (
(set ln=%%i) & rem echo !ln!
(set ln=!ln: =!) & (set ln=!ln:*本地连接:=本地连接:!)
if "!ln:~0,5!" equ "!sLC!:" (
(set foundLCPA=false)&(set foundLC=true)
)
if /i "!ln:~0,10!" equ "MediaState" (
(set ln=!ln:*disconnected=disconnected!)
if /i "!ln:~0,12!" equ "disconnected" (
if /i "!foundLC!" equ "true" if /i "!foundLCPA!" equ "false" (set LCC=false)
)
)
if /i "!ln:~0,15!" equ "PhysicalAddress" (
if /i "!foundLC!" equ "true" if "!LCPA!" equ "" (
(set foundLCPA=true)&(set ln=!ln:*:=!)&(set LCPA=!ln:~0,17!)
)
)
if /i "!ln:~0,3!" equ "PPP" (set PPP_WAN=true)
(set ln=!ln:*:=!)
if /i "!ln:~0,3!" equ "WAN" (set PPP_WAN=true)
)
if /i "!foundLC!" equ "false" (set LCC=false)
cls
if !LCC! neq !LCC0! (set LCC0=!LCC!)&if /i "!LCC!" equ "false" (set /p=<nul) else (set /p=<nul)
if !PPP_WAN! neq !PPP_WAN0! (set PPP_WAN0=!PPP_WAN!)&if /i "!PPP_WAN!" equ "false" (set /p=<nul) else (set /p= <nul)
if /i "!PPP_WAN!" equ "true" (set sgn=╬═╬!sLC!和!sPPP!) else (set sgn=╩!sLC!)
if /i "!LCC!" equ "false" (
(color cf)&(title ╳!sLC!^(!LCPA!^)被断开) & echo ╳!sLC!^(!LCPA!^)被断开
if /i "!foundLC!" equ "false" (color 3f)&(title ？!sLC!^(!LCPA!^)不存在或停用) & echo ？!sLC!^(!LCPA!^)不存在或停用
(set PPP_WAN=false)
) else (
(title !sgn!^(!LCPA!^)已连接上) & (set /p=!sgn!^(!LCPA!^)已连接上<nul)
if /i "!PPP_WAN!" equ "true" (color 2f) else (color 9f)
if /i "!PPP_WAN!" equ "false" (
if not exist !PPPCFG! (call :setAccount %1) else (
(call :getRASAutoDialName PPP_Name)
for /f "eol=[ tokens=2,4,6 delims==|" %%a in (!PPPCFG!) do (
(rasdial.exe "!PPP_Name!" %%b %%c)>!fn!
)
for /f "delims=" %%i in (!fn!) do (
(set ln=%%i)
if "!ln:~0,3!" equ "已连接" (color 2f)&(set PPP_WAN=true)&(set /p=!sPPP!已重新连上<nul)
if "!ln:~0,6!" equ "远程访问错误" if /i "%1" equ "hide" (call :showWindow show)&exit
if "!ln:~0,10!" equ "远程访问错误 623" (
(msg %username% !sPPP! 未建立,或已删除或已改名,请检查后继续)&(start Control netconnections)&cls&pause
)
if "!ln:~0,10!" equ "远程访问错误 691" (msg %username% !sPPP!的用户名和/或密码错误,请重新输入)&(call :setAccount %1)
)
)
)
)
ping -n 2 127.1>nul
goto loop
exit /b &rem End of main program
:getRASAutoDialName
echo wscript.echo CreateObject("WScript.Shell").RegRead("HKLM\SOFTWARE\Microsoft\RAS AutoDial\Default\DefaultInternet")>%windir%\t~.vbs
for /f "delims=" %%a in ('cscript //nologo %windir%\t~.vbs') do set "%1=%%a"
exit /b
:setAccount
if /i "%1" equ "hide" (call :showWindow setAccount)&exit
cls&color 9f&mode con lines=4 cols=80
echo == 请输入!sPPP!配置信息并保存到文件 !PPPCFG! ==&echo.
(set /p PPP_Username= 用户名:)
(set /p PPP_password= 密码:)
(call :getRASAutoDialName PPP_Name)
echo [!sPPP!配置]>!PPPCFG!
echo !sPPP!名称=!PPP_Name!^|用户名=!PPP_Username!^|密码=!PPP_password!>>!PPPCFG!
echo ;请检查上面的信息是否正确, 否则请更正并保存^(注意分隔符^|不可删除或更改, 且不要加入任何多余的字符^)>>!PPPCFG!
(start notepad !PPPCFG!)&pause
mode con lines=2 cols=58
exit /b
:showWindow
if /i "%1" equ "hide" (set intWindowStyle=0) else (set intWindowStyle=5)
mshta vbscript:createobject("wscript.shell").run("%~nx0 %1",!intWindowStyle!)(window.close)&&exit
exit /b

复制代码